{1/24/89
Update BP Boss 5-6 M042.53
Deleted: IF cutterRadiusCompensation? AND FirstFeat? AND NEXT LineFeat?
{ avoid 2 co-linear lines by skipping extra ncCAM line}
from ToolPath.
Jim Radcliffe}
{add feed to 1st line and move %, 7/30/89, WFG}

{10/9/89
Modified: BP Boss 5-6 [G75] M042.56
Added SepSubs same as "BP Series 1 (R2E4) M128.60"
Added missing "DoOpComments" commands.
Added "SpeedC" to SameTool.
Added PostScript & other update stuff.
Jim Radcliffe}

{11/1/89
Copied & modified: BP Boss 5-6 [G75] M042.57
For: Accutool
Machine: Bridgeport Series 1
Control: Boss 5
Minor format changes per customer request.
Change colons ":" in comments to a dash "-".
Supress tool comments for same tool operation comments.
PostScript & SepSubs commented out.
Jim Radcliffe}

{4/03/91
Modified: BP Series 1 Boss 5 M266.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

#1 = '#.00'
#2 = '###^#0'
#3 = '00^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(FeedEntry#,3}

DoPostScript:
{EachPS
SeqLab PostScript EOL
NextPS}
RETURN

DoEndOpPS:
{EachEOPS
SeqLab EndOpPS EOL
NextPS}
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER- ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# '- ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# '- ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
END
IF NOT Metric?
{do nothing, CAM is English}
ELSE
SetScale('.03937007874') {convert metric CAM to English}
END
END
RETURN

StartSub:
OpenSub
'#' Program# EOL
DoSubComment
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
END
RETURN

StdSub:
SubWarning
TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab RepCycs EOL
IF CutterRadiusCompensation?
SeqLab CRCOn AbsOrInc Connect BPCRCStartPos EOL
SeqLab Feed StrtPos EOL
ELSE
SeqLab AbsOrInc Connect StrtPos EOL
END
RETURN

OpenMP:
NewProg TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab Parts EOL
DoSubComment
SeqLab StrtPos EOL
RETURN

CloseMP:
SeqLab Preset ShiftPC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftPC EOL
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqLab MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLab RapidC MoveXYZC EOL
ELSE
IF LineFeat?
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLab FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLab FeedC MoveXYZC FeedRateC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

InitProg
ReverseYZArcs
{UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END}
EachOp
IF FirstOperation?
'%' EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM- ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT- ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED- ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
IF NOT Metric?
{do nothing, CAM is English}
ELSE
SetScale('.03937007874') {convert metric CAM to English}
END
SeqLab EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Rapid Plane 'G75' AbsValue Home Speed OpToolID ToolChng EOL
DoOpComments
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
IF CutterRadiusCompensation?
IF Repeats?
SeqLab RapidC BPCRCStartPos ZCP1 EOL
ELSE
SeqLab CRCOn RapidC BPCRCStartPos ZCP1 EOL
END
ELSE
SeqLab RapidC StrtPos ZCP1 EOL
END
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
ASCII('13') EOL
SeqLab Rapid Plane 'G75' AbsValue Home Speed OpToolID ToolChng EOL
DoOpComments
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
IF CutterRadiusCompensation?
IF Repeats?
SeqLab AbsOrInc Rapid BPCRCStartPos ZCP1 EOL
ELSE
SeqLab CRCOn AbsOrInc Rapid BPCRCStartPos ZCP1 EOL
END
ELSE
SeqLab AbsOrInc Rapid StrtPos ZCP1 EOL
END
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
DoEndOpPS
DoOpComments
IF CutterRadiusCompensation?
IF Repeats?
SeqLab PlaneC AbsOrInc Rapid BPCRCStartPos ZCP1 SpeedC EOL
ELSE
SeqLab CRCOn PlaneC AbsOrInc Rapid BPCRCStartPos ZCP1 SpeedC EOL
END
ELSE
SeqLab PlaneC AbsOrInc Rapid StrtPos ZCP1 SpeedC EOL
END
DoPostScript
END
END
END
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls? AND ZshiftOnly?
FindAnyZMoves
IF NoZMoves?
EachCycle
IF CutterRadiusCompensation?
SeqLab CRCOn BPCRCStartPos EOL
SeqLab Feed StrtPos EOL
ELSE
SeqLab StrtPos EOL
END
IF FeedConnect?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC ZCP2PlusIncC EOL {can't call for cycle =1}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab ZInPlusInc EOL
END
END
'=#' Program# EOL
NextCycle
StartSub
SkipZ
ELSE
StdSub
EntryMove
END
ELSE
StdSub
EntryMove
END
ELSE {no repeats}
IF CutterRadiusCompensation?
SeqLab Feed StrtPos EOL
END
EntryMove
END
ToolPath
IF Repeats?
UnSkipZ
IF NOT FeedConnect?
IF CutterRadiusCompensation?
SeqLab RapidC CRCOff BPCRCEndPos ZCP3C EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
ELSE
IF CutterRadiusCompensation?
SeqLab FeedC CRCOff BPCRCEndPos EOL
END
END
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls? AND ZshiftOnly? AND NoZMoves?
'$' EOL
CloseSub
ELSE
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftRC EOL
END
SeqLab RapidC ZCP3C EOL
NewProg
ELSE
IF CutterRadiusCompensation?
SeqLab RapidC CRCOff BPCRCEndPos ZCP3C EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab RepCycs EOL
SeqLab AbsOrInc Rapid StrtPos EOL
END
SeqLab ZCP2C EOL
GetCycle
IF Dwell?
SeqLab 'G04/' Dwell# EOL
END
SeqLab Cycle StrtPos ZDepthAbs Peck Retract FeedEnt EOL
ToolPath
SeqLab 'G80' EOL
IF Repeats?
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftRC EOL
END
SeqLab ZCP3C EOL
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqLab AbsOrInc Rapid
IF ToolChangeAtHome?
FirstHome
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
EOL
CloseMP
SeqLab
END
EOP EOL
'E' EOL
Post
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH- ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH- ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH- ' FileMeters# ' METERS )' EOL
END
Close
END