{6/22/88}
{original: BP Boss5-6 [G75] M042.53}
{changed beginning and ending of program, and Comments}
{changed F format}
{Jim Radcliffe}
{added sep repeats, WFG 7/4/88}
{force XY in arcs, G17 only possible, 7/27/89, WFG}
{added FEED to .N10 first line, 7/30/89, WFG}
{9/22/89, suppress subwarning comments if not use comments, JR}

{10/9/89,
Modified: BP Series 1 (R2E4) M128.59.
Fixed SetMaxSeparateSubCalls (50) command.
Corrected Sep sub problem if 1st cut <> Z step, requires ncPost 3.19Åš5.
Added PostScript & other update stuff.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{6/16/92
Modified: BP Series 1 (R2E4) M128.62
Updated to Version 4.0 per BP Boss 5-6 [G75] M042.79.
KLM}

#1 = '#.00'
#2 = '###^#0'
#3 = '###0'
#4 = '###.#;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(Program#,3)
FORMAT(FeedEntry#,4)

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

DoSubComment:
IF UseComments? AND SubComment?
ASCII ('39') 'SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
ASCII ('39') 'OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
ASCII ('39') OperationComment$ EOL
END
IF WorkGroupComment?
ASCII ('39') WorkGroupComment$ EOL
END
IF ToolTypeComment?
ASCII ('39') 'TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
ASCII ('39') ToolComment$ EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

StartSub:
OpenSub
'#' Program# EOL
DoSubComment
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
ASCII ('39') EOL
ASCII ('39') ' WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
ASCII ('39') EOL
END
END
END
RETURN

StdSub:
SubWarning
TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab RepCycs EOL
IF CutterRadiusCompensation? AND NOT AutoCycle?
SeqLab AbsOrInc Connect BPCRCStartPos EOL
ELSE
SeqLab AbsOrInc Connect StrtPos EOL
END
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
IF CutterRadiusCompensation? AND NOT AutoCycle?
SeqLab RapidC CRCOff BPCRCEndPos ZCP3C EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
ELSE
IF CutterRadiusCompensation? AND NOT AutoCycle?
SeqLab FeedC CRCOff BPCRCEndPos EOL
END
END
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftRC EOL
RETURN

OpenMP:
NewProg TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab Parts EOL
DoSubComment
SeqLab StrtPos EOL
RETURN

CloseMP:
SeqLab Preset ShiftPC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftPC EOL
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqLab MoveSXYC EOL
IF AutoCycle?
'=#' Program# EOL
END
ELSE
IF RapidFeat?
SeqLab RapidC MoveXYZC EOL
ELSE
IF LineFeat?
IF CutterRadiusCompensation? AND FirstFeat? AND NEXT LineFeat?
{ avoid 2 co-linear lines by skipping extra ncCAM line}
ELSE
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLab FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLab FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
IF NOT XYPlane?
SeqLab Plane EOL
END
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
SeqLab StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLab AbsOrInc EOL {.69 removed RapidC}
ELSE
SeqLab AbsOrInc RapidC ZCP2 EOL
END
'$' EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
IF CutterRadiusCompensation?
SeqLab Feed CRCOn StrtPos FeedRate EOL
END
EntryMove
ToolPath
END
RETURN

G92Sub:
StdSub
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
SetPass1 {for correct Z's}
EachCycle
IF FeedConnect?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'=#' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLab Rapid ZCP2 EOL {.69}
END {.69}
'$' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF CutterRadiusCompensation?
SeqLab BPCRCStartPos EOL
ELSE
SeqLab StrtPos EOL
END
END
IF CutterRadiusCompensation?
SeqLab Feed CRCOn StrtPos FeedRate EOL
END
IF FeedConnect?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab Rapid ZCP2PlusIncC EOL {can't call for cycle =1}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
'=#' Program# EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
'$' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SetStartPosition:
IF CutterRadiusCompensation? AND NOT AutoCycle?
AbsOrInc Rapid BPCRCStartPos ZCP1
ELSE
AbsOrInc Rapid StrtPos ZCP1
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseYZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
'.N10' Plane AbsValue 'G75F' FeedEntry# EOL
IF UseComments?
IF ProgramNameComment?
ASCII ('39') 'PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
ASCII ('39') ProgramComment$ EOL
END
IF FormatNameComment?
ASCII ('39') 'FORMAT: ' FormatName$ EOL
END
IF TimeComment?
ASCII ('39') Date$ ' AT ' Time$ EOL
END
IF MovesComment?
ASCII ('39') 'OUTPUT IN ' MoveType$ EOL
END
IF PartsComment?
ASCII ('39') 'PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
ASCII ('39') 'FIRST TOOL NOT IN SPINDLE ' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Rapid Home OpToolID ToolChng EOL
DoOpComments
DoPostScript
SeqLab Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab SetStartPosition EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END

{Start new Operation}

SeqLab AbsOrInc Rapid Home OpToolID ToolChng EOL
DoOpComments
SeqLab Speed EOL
SeqLab Plane AbsValue 'G75' EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab SetStartPosition EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab 'M00' EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
SeqLab PlaneC SetStartPosition Speed EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
IF CutterRadiusCompensation? AND NOT AutoCycle?
SeqLab RapidC CRCOff BPCRCEndPos ZCP3C EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
SeqLab RapidC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
NewProg TagUp TagInc
SeqLab CallLabB '²' Tag# RepLab RepCycs EOL
SeqLab AbsOrInc Rapid StrtPos EOL
END
SeqLab ZCP2C EOL
GetCycle
IF Dwell?
SeqLab 'G04/' Dwell# EOL
END
SeqLab Cycle StrtPos ZDepthAbs Peck Retract FeedEnt EOL
ToolPath
SeqLab 'G80' EOL
IF Repeats?
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
SeqLab Preset UnshftRC EOL
END
SeqLab ZCP3C EOL
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab AbsOrInc Rapid
IF ToolChangeAtHome?
FirstHome
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
EOL
CloseMP
SeqLab
END
EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
ASCII ('39') 'FILE LENGTH: ' FileBytes# ' CHARACTERS ' EOL
END
IF FileFeetComment?
ASCII ('39') 'FILE LENGTH: ' FileFeet# ' FEET ' EOL
END
IF FileMetersComment?
ASCII ('39') 'FILE LENGTH: ' FileMeters# ' METERS ' EOL
END
Close
END