{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=T
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{5/12/92
Copied & modified: Fanuc 6M M001.81
For: Armco.
Machine: Giddings & Lewis Horizontal Machining Center
Control: G & L NumeriPath 8000B
Changes made per conversation with Bill Barber @ Armco, and manual.
Changed all occurances of Z address to W address in Form and Prog.
FORM Changes:
Use Absolute Arc Centers = T
Allow R-Format Arcs = F
Keep Subs in Front of Program = T
Z EndPoint Label = W
Rapid Z EndPoint Label = W
Sub Call Label =
Sub Repeat Label =
Program ID Label =
Optional Program ID Label =
Tool Length Offset Label = D
Call sub =
Return from Sub =
Tool Length Offset Enable =
Tool Length Offset Cancel =
First Work Fixture Offset = E1
Last Work Fixture Offset = E99
Drill from CP1 =
Drill from CP2 =
PROG Changes:
Changed FORMAT 6 for Dwell# from ####^##0 to ###.#;0.
Added FORMAT 7 ##.#####;0. for FeedTapIPR# used in Canned Tapping Cycle.
Added Address 'K' for this.
Added ClearancePlane1# and ClearancePlane2# to FORMAT 4 used in Canned Drilling Cycles
and based on RetractToCP1 Boolean, and replaces FromCP Command.
Added ArcZRads# to FORMAT 4 used for 3-Axis ArcFeat.
Added Repeats# to FORMAT 5.
Added TYPE II Conversational Codes:
PGM, Program Name
MSG, Operator Message
CLS, Call Subroutine
Changed all SeqC EndSub to EOR.
Modified FormatArc Sub to handle all Planes.
Unconditional h, v, I and J; d and K for Helical ArcFeat.
Added Flag('1') to bypass Helical ArcFeat for ZonlyRep Sub which uses SkipZ Command.
Changed Address G to Address E at WFOStuff Sub.
Added literal 'D0' to IncValue OfstOff.
Changed Address P to Address F for Canned Drilling Cycle Dwells.
Dwell for Canned Cycle is output as 'G4' Dwell.
Deleted FeedEnt from Canned Drilling Cycles.
I didn't see an example of FeedEnts being used in the manual, I assume it is defaulted.
DWB}

{7/1/92
Modified: G & L Numeripath 8000 M499.81
For: Armco.
Changes made per conversation with Bill Barber @ Armco.
Bill requested that the Tool Length Offset be output prior to any table motion. The D Address
controls both the Length AND Diameter Offset values.
Deleted CRCOffsetC 3 places at StdLine sub.
Deleted ResetCRCNum at ToolPath sub.
Added ToolOfst to block prior to StrtPos at FirstOperation, NewTool and 2 places at SameTool.
Changed OfstOn to ZCP1 at FirstOperation, NewTool and 2 places at SameTool.
DWB}

{10/7/94
Copied & modified: G & L Numeripath 8000 M499.81.1
For: CNCCS / Marshall Engineering
Changed to a no subs format per Fanuc 6M NoSubs M001.81.2
Added sequence numbers to all comments.
Changed Z address from W to Z
Added codes to saftey start blocks.
WFO's output by PostScript request only.
SpinOff on ZCP3.
Commented out OfstOff.
Added FeedEnt to DrillCycle.
Added move to machine home at end of program.
Jim Radcliffe}

{10/11/96,
Initial: G&L Numeripath 8000B M758.81.2
Created: G&L Num 8000B [RE] MXXX.81
For: Remmele Eng. Plant #40
Deleted SpinOff commands,
Changed label for Z moves in form to W. Customer wants to use W (table depth axis) for
milling ops and clearance planes, but use z axis for drill depths.
Changed G94 in saftey start block to G95, customer wants to program feed rates in IPR,
Put OpToolID and ToolChng on same line,
Put ToolOffset on line with OpToolID and ToolChng,
instead of calling ZCP3C at tool changes before tool changes and at the last op, post outputs
'Z0.W' TCZ#, TCZ it set in initalizations to 20,
deleted output of program number,
deleted literal 'G98X0.Y0.' at program end,
added literal 'Z0.' before ZCP1 calls (zeros the Z axis so W axis moves are correct,
moved Speed command in FirstOp and NewTool to same line with OpToolID,
Added literal 'G98Z0.' to line with SpinOn in FirstOp and NewTool,
deleted format #7, changed FeedTapIPR to format #4,
MPK}

{1/16/97
Initial: G & L Num 8000B [RE] MZ64.89
Created: G & L Num 8000B [RE] MZ64.89.1
ForUser: Remmele Plant 40
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: Modified per fax and conversation with Dave Lemire
Changed format of F to 4 decimal places.
Jim Radcliffe}

{*** NOTE ***}
{ Customer is typing in IPR feeds into the Virtual Feed dialog boxes! That is the way he wants it! }

{14 Oct98
Original: G & L Num 8000B [RE] MZ64.89.1
Created: G & L Num 8000H [GD] NDT14.15
For: General Dynamics
Changes made per: Pat Rosemellia
New Post First Draft
Added Post Header Comment at the top of Prog.
Added Format#8 at Prog Numeric Format Definitions and changed formatting for NewWFO# and PartNum#
Added ckCRC Sub
Added doTCZ Sub to handle Clearanceplanes
Adjusted FirstOperation, NewTool and SameTool per customers FAX and Conversation with Pat Rosemellia
Changes too numerous to list.

{*** NOTE ***}
Because the user is specifying the TCZ value, this may not always going to be safe
in NewTool or, in SameTool, where ProgStop OR NewToolOffset OR CSChanges are TRUE.
Virtual calculates the safe Clearance Plane for indexing: This post only outputs the TCZ value.
To ensure the Tool Clears the Part, the post will output TCZ or ZCP3, whichever is the greater,
and will output a warning telling the user the amount he needs to increase the TCZ, to be safe.

Updated to D_Style LongHand Advanced Mill Post per Fanuc 6M NoSubs D877.15.3
Charles Winston}

{26 Oct98
Created: G & L Num 8000H [GD] NDT14.15
Created: G & L Num 8000H [GD] NDT14.15.1
For: General Dynamics
Changes made per: Pat Rosemellia
Added a Boolean to suppress the CSComment$ when SubComment is FALSE
Added Utility Data Instructions at InitProg.
Split the StartPosition Line into two lines with
the the B-Axis index on a seperate line in FirstOparation, NewTool and SameTool
Rewrote the FormatArc Sub to handle Helical milling per customers CNC Manual.
Charles Winston}

{2Nov98
Created: G & L Num 8000H [GD] NDT14.15.1
Created: G & L Num 8000H [GD] NDT14.15.2
For: General Dynamics
Changes made per: Pat Rosemellia
Put Speed and SpinOn onto a seperate line, before the Index line in FirstOperation, NewTool and SameTool
Deleted 'Z' Zdepth# from drill cycles
Added Rapid 'G98' after the Drill cycle cancellation
Added Rapid or Feed and 'G98' to the TCZ line at the end of all milling operations ( Including Thread Milling )
Added a Boolean to return the Indexer to the ZERO INDEX position, in FinishLastOp.
Charles Winston}

{3Nov98
Created: G & L Num 8000H [GD] NDT14.15.2
Created: G & L Num 8000H [GD] NDT14.15.3
For: General Dynamics
Changes made per: Pat Rosemellia
Changes to Drill Cycles:
Changed W to Z for all Drill Cycles in MachSpec
Added ZDepth to Drill Cycle line at IF Drilling?
Added TrackZNO# FIRST SPZ# after the drill cycle. Cycle was not correctly tracking the Zdepth.
Moved Rapid 'B0' before SpinOff at end of Prog, per conversation with Pat Rosemellia.
Charles Winston}

{11Nov98
Original: G & L Num 8000H [GD] NDT14.15.3
Created: G & L 800 15HS [GD] NDT35.15
For: General Dynamics
Changes made per: Pat Rosemellia
Added Post Header Comment at the top of Prog.
Changed Formatting for FeedTapIPR# from FORMAT#4 to FORMAT#9 in Prog Numeric Format Definitions.
Commented out WFOStuff. Not supported
Added Support for OptCyc1 Postscript command in PSInit and PSStuff. Uses Flag('9')
Added user instructions, for the OptCyc1 in Utility data.
OptCyc1 switches the indexer output from 'B' to 'A'. ( Customers CNC has two indexers.)
Added support for Helical Milling in FormatArc
Added support for Longhand Drilling for PeckChipBreaker and FIFO.
Modified the use of TCZ.
All operations now call ZCP3 in OpGuts and TCZ where appropropriate in NewTool and SameTool.
Deleted 'G98' and added TrackZ# and 'H00' in FirstOperation, NewTool and SameTool
Added ToolOfst to the ZCP1 line in FirstOperation, NewTool and SameTool
Deleted 'G98' from ToolChangeAtHome in NewTool
Changed Rapid Plane CRCOff 'G70' DrillOff AbsOrInc 'G94G97' to Rapid Plane AbsOrInc in All Operations
Charles Winston}

{13Nov98
Original: G & L 800 15HS [GD] NDT35.15
Created: G & L 800 15HS [GD] NDT35.15.1
For: General Dynamics
Changes made per: Pat Rosemellia
Deleted SeqC, MSG and PGM from all Comment lines
Changed F from ####.## to ####.# in MachSpec
Charles Winston}

{16Nov98
Original: G & L 800 15HS [GD] NDT35.15
Created: G & L 800 15HS [GD] NDT35.15.2
For: General Dynamics
Changes made per: Pat Rosemellia
Added move to ZCP2 at the end of Longhand Drilling
Charles Winston}

{10Feb99
Original: G & L 800 15HS [GD] NDT35.15.2
Created: G & L 800 15HS [GD] NDT35.15.3
For: General Dynamics
Changes made per: Pat Rosemellia
Develop: Catalyst 5.03/ComPost2 1.7b15
Added booleans in CSAngleA and CSAngleB to suppress redundant rotations.
Deleted all use of TCZ# throughout the Prog. Post now uses ZCP1.
Moved doPostScript call before StartPos line in FirstOperation, NewTool and SameTool.
Customer needs to output X and Y moves as Literals entered in Utility Data.
Deleted the move tro ZCP1 before CoolOn in FirstOperation and NewTool and SameTool.
Adjusted SameTool to output SpeedC. It was suppressed unless there was a ChangeCS
Moved ToolOfst to ZCP2 at the Start of the Common Point.
Added ModCSOffsetB. Rotary table requires Positive, Absolute Index values.
Charles Winston}

{25Feb99
Original: G & L 800 15HS [GD] NDT35.15.3
Created: G & L 800 15HS [GD] NDT35.15.4
For: General Dynamics
Changes made per: Pat Rosemellia
Develop: Catalyst 5.05/ComPost2 1.7b15
Added OR NewTool? to the Boolean in CSAngleA and CSAngleB Subs.
Moved DoPostScript up above CSAngleB line in FirstOperation. OptCyc1 affects CSAngleB in FirstOp.
Added a Boolean in SameTool to Suppress the whole rotation line unless AChange? OR BChange? is TRUE.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0.'
#7 = '#;'
#8 = '#00'
#9 = '##.######;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(Recall#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ArcZRads#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(SUB#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Tag#,5)
FORMAT(EPZ#,4)
FORMAT(ZDepth#,4)
FORMAT(SPZ#,4)
FORMAT(TCZ#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Repeats#,5)
FORMAT(Dwell#,2)
FORMAT(RapidF#,7)
FORMAT(NewWFO#,8)
FORMAT(PartNum#,8)
FORMAT(FeedTapIPR#,9)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFO:
'E' PartNum#
RETURN

WFONum:
'E' NewWFO#
RETURN

WFOStuff:
{
IF MultipleParts? AND WorkFixtureOffsets?
WFO
ELSE
IF NewWFO?
WFONum
ELSE
IF NOT SameTool?
IF NeedWFO1?
WFONum
END
END
END
END
}
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
IF UseComments? AND SubComment?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
END
RETURN

CSComments:
IF FirstOperation? OR NewTool? OR ChangeCS?
DoCSComment
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
CSComments
RETURN

ModCSOffsetA:
IF AAxisAvail?
Save# Num#('50') DIV# CSOffsetA# Num#('360')
Save# Num#('50') SUB# Recall# Num#('50') TRUNC# Recall# Num#('50')
Save# Num#('50') MUL# Recall# Num#('50') Num#('360')
IF LTEqual? Recall# Num#('50') Num#('0')
Save# Num#('50') ABS# Recall# Num#('50')
ELSE
Save# Num#('50') SUB# Num#('360') Recall# Num#('50')
END
Recall# Num#('50')
END
RETURN

ModCSOffsetB:
IF BAxisAvail?
Save# Num#('50') DIV# CSOffsetB# Num#('360')
Save# Num#('50') SUB# Recall# Num#('50') TRUNC# Recall# Num#('50')
Save# Num#('50') MUL# Recall# Num#('50') Num#('360')
IF LTEqual? Recall# Num#('50') Num#('0')
Save# Num#('50') ABS# Recall# Num#('50')
ELSE
Save# Num#('50') SUB# Num#('360') Recall# Num#('50')
END
Recall# Num#('50')
END
RETURN

CSAngleA:
IF AAxisAvail?
IF FirstOperation? OR NewTool?
'A' ModCSOffsetA
ELSE
IF AChange?
'A' ModCSOffsetA
END
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
IF FirstOperation? OR NewTool?
IF Flag?('9')
'A' ModCSOffsetB
ELSE
'B' ModCSOffsetB
END
Save# Num#('9') CSOffsetB#
ELSE
IF BChange?
IF Flag?('9')
'A' ModCSOffsetB
ELSE
'B' ModCSOffsetB
END
Save# Num#('9') Recall# Num#('50')
END
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
IF FirstOperation?
SetFlagF('9') { used to test PostScript for OPTCYC1 }
END
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
IF FirstOperation?
IF OPTCYC1?
SetFlag('9')
END
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveXY ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveY MoveZ ArcIJ
END
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ not supported }
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqC FeedC StrtPosC EOL
ELSE
SeqC RapidC StrtPosC EOL
END
END
END
EntryMove
ToolPath2
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP2
END
ExitFeed EOL
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC CRCOffC AbsOrInc ExitType ZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

doPeck: { longDrillStuff }
IF GreaterThan? SUB# Recall# Num#('4') Peck# SPZ# { IF OldZ - Peck# > Depth }
Save# Num#('4') SUB# Recall# Num#('4') Peck# { Save New Peck Depth }
SeqC Feed 'Z' Recall# Num#('4') FeedEntC EOL { Move to New Peck Depth }
Rapid
IF PeckFullRetract?
SeqC ZCP2 EOL { Retract Tool Full Out }
END
FORMAT(ADD#,4)
SeqC 'Z' ADD# Recall# Num#('4') Retract# EOL { Move to Retract Position }
TrackZNO# ADD# Recall# Num#('4') Retract# { Update Status Register }
FORMAT(ADD#,5)
END
RETURN

drillFeature: { longDrillStuff }
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
IF Peck?
FORMAT(Recall#,4)
Save# Num#('4') ClearancePlane2#
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
FORMAT(Recall#,5)
END
SeqC FeedC MoveSZC FeedEntC EOL
IF Dwell?
SeqC 'G4F' Dwell# EOL
END
IF FIFO?
SeqC FeedC ZCP2C EOL
IF RetractToCP1?
SeqC RapidC ZCP1C EOL
END
ELSE
IF RetractToCP1?
SeqC RapidC ZCP1C EOL
ELSE
SeqC RapidC ZCP2C EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC
IF FIFO? AND NOT FirstFeat?
Rapid
END
MoveSXYC EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
IF PeckChipBreaker? OR FIFO?
drillFeature { longDrillStuff }
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

OutputTCZ:
SeqC ZCP1C 'H00' EOL
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') {done flag}
SetFlagF('2') {TCZ warning flag}
Save# Num#('1') Num#('0') {tools 1st op}
Save# Num#('2') Num#('0') {tools last op}
Save# Num#('3') Num#('0') {ncCAMs last op}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the multiple part work fixture offset option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' ' EOL
' Using the OPTCYC1 PostScript Command' EOL
' The OPTCYC1 command can be entered in the Utility Data At Op Start BOX.' EOL
' This will cause the Post to output all Rotation commands as A-axis instead of B-axis' EOL
' NOTE: The Command Works when used in The First Operation Utility Data BOX ONLY.' EOL
' ' EOL
END
EachOp
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
RestoreScale
END
NextOp
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
END
DoOpComments
SeqC WFOStuff EOL
ELSE
DoOpComments
Seq Rapid Plane AbsOrInc EOL
SeqC Rapid ZCP1 'H00' EOL
SeqC Rapid Home EOL
SeqC OpToolID ToolChng EOL
SeqC WFOStuff EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC AbsOrIncC Rapid CSAngleA CSAngleB EOL
SeqC AbsOrIncC Rapid StrtPos EOL
ELSE
SeqC Speed SpinOn EOL
DoPostScript
SeqC AbsOrIncC Rapid CSAngleA CSAngleB EOL
SeqC AbsOrIncC Rapid StrtPos
IF NOT LastTool?
PreTool
END
EOL
SeqC CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
SeqC CoolOff EOL
OutputTCZ
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrIncC Rapid Home EOL
END
SeqC SpinOff EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
END
DoOpComments
SeqC WFOStuff EOL
ELSE
DoOpComments
Seq Rapid Plane AbsOrInc EOL
SeqC OpToolID ToolChng EOL
SeqC WFOStuff EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC AbsOrIncC Rapid CSAngleA CSAngleB EOL
SeqC AbsOrIncC Rapid StrtPos SpinOn
ELSE
SeqC Speed SpinOn EOL
SeqC AbsOrIncC Rapid CSAngleA CSAngleB EOL
DoPostScript
SeqC AbsOrIncC Rapid StrtPos
IF NOT LastTool?
PreTool
END
EOL
SeqC CoolOn EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop?
SeqC CoolOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF LAST ProgStop? OR NewToolOffset? OR ChangeCS?
OutputTCZ
END
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC 'M0' EOL
END

{Start new Operation}

DoOpComments
SeqC WFOStuff EOL
IF LAST ProgStop?
SeqC Speed SpinOn EOL
ELSE
SeqC SpeedC EOL
END
CheckPass
IF AChange? OR BChange?
SeqC PlaneC AbsOrIncC Rapid CSAngleA CSAngleB EOL
END
DoPostScript
SeqC PlaneC AbsOrIncC Rapid StrtPos EOL
IF LAST ProgStop?
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}
RapidF# {forces the output of a conditional feedrate for each operation}

SeqC ZCP2
IF NOT SameTool?
ToolOfst
ELSE
IF LAST ProgStop? OR NewToolOffset? OR ChangeCS?
ToolOfst
END
END
EOL
IF Milling?
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
ExitType 'Z' TrackZ# ADD# CSOffsetZ# PRIME ClearancePlane2#
END
ExitFeed EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC CRCOffC
IF FIFO?
FeedC
ELSE
RapidC
END
ZCP3C ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
END
SeqC DrillCP EOL
GetCycle
IF PeckChipBreaker? OR FIFO?
SeqC StrtPosC EOL
ToolPath
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC RapidC ZCP3C EOL
END
ELSE
SeqC Cycle StrtPos ZDepth RLevel
IF RetractToCP1? {.81}
'K' ClearancePlane1# { FromCP }
ELSE
'K' ClearancePlane2# { FromCP }
END
Peck
{
IF Dwell?
'G4' Dwell
END
}
IF Tap?
'E' FeedTapIPR#('1')
ELSE
FeedEnt
END
EOL
TrackZNO# FIRST SPZ# {.81.2}
{ TrackZNO# ZDepth# } {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
SeqC Rapid ZCP3 EOL
END
IF Repeats?
NEXTRep
END
END
END
Save# Num#('5') ClearancePlane3# { Stores ZCP3 to check it against TCZ# }
RETURN

FinishLastOp:
SeqC CoolOff EOL
OutputTCZ
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrIncC Rapid Home EOL
END
IF NOT Equal? Recall# Num#('9') Num#('0') { If not at 0 deg, return to Zero }
SeqC Rapid
IF Flag?('9')
'A0'
ELSE
'B0'
END
EOL
END
SeqC SpinOff EOL
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
ELSE
SeqC EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp � op � ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
DoToolsOps
IncWFO
NextWFO
ELSE
EachPart
TagInc
DoToolsOps
NextPart
END
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
EachOp
DoOp
NextOp
FinishLastOp
IncWFO
NextWFO
ELSE
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
END
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close