{
MILL=T
LATHE=F
SIMPLE_ROT_POS=T
ROTARY_MILL=T
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{1/20/98,
Initial : CNCVIS2 M611.89
Created: CNCVIS2 M611.89.1
Customer: Fadal Post - Changes made per Regal Machine

Changes to "Prog":

1. Added FORMAT (4.4) to TrackZNO# (to eliminate G91Z0. blocks in drilling).
JHE}

{6/15/98,
Initial : CNCVIS1 M611.89.1
Created: CNCVIS1 M611.89.2
Customer: Gibbs & Associates

Changes to "Prog":

1. Added G20 (inch output) block to be the first block in the main program.
2. Added header comment.
JHE}

{08/17/98,
Initial: CNCVIS2 M611.89.2
Created: CNCVIS2 M611.89.3

Changes to Prog:
1) Common Point/Drilling - Corrected bad Tapping output.

** For future reference: All Fadal Format 2 posts need to have an S word in the
cycle definition lines for Compression and Rigid Tapping. The S word in the
cycle definition line and the Speed command need to be identical. The S word
does not necessarily need to have a decimal point. A .2 for high range
is not necessary but often used. **
CDH}

{9/22/98,
Initial : CNCVIS2 M611.89.3
Created: CNCVIS2 M611.89.4
Customer: Gibbs & Associates

Changes to "Prog":

1. Added SetMaxFeed of 12700 MMPM.
JHE}

{14Dec98
Original: CNCVIS2 M611.89.3
Created: CNCVIS2 PM611.17
For: Wellite Ind. Inc
Added Post Header Comment at the top of Prog.
Updated to Simple Positioning, Rotary MIll Post, per Fanuc 6M PM001.17.1
Charles Winston}

{12/23/98
Updated & Modified: CNCVIS2 PM611.17
Created: CNCVIS2 PM611.17.3
For: Wellite Ind. Inc
Versions: Virtual 5.03/ComPost2 1.7b11
Updated for Catalyst v5.03 per Fanuc 6M PM001.17.2 Format.
Deleted FIRST modifier at two places doSepSubContour.
Deleted FIRST modifier at setSepSubZ.
Deleted FIRST modifier at drillingOp.
Deleted Rotations? condition at doSepSubSPMove.
Deleted ZCP3 at doSepSubExit.
Modified for non-AutoCycle.
Deleted NOT Rotations? condition at zonlyRepAutoCycle.
Moved resetSepSubSR at zonlyRepAutoCycle.
Deleted FeedConnect? AND Rotations? condition at zonlyRepAutoCycle.
Also Rapid ZCP3.
Moved resetSepSubSR at zonlyRep.
Added ELSE condition for TrackZNO# ClearancePlane3# at zonlyRep.
Deleted LastRotation at end of rotaryReps.
Added Tracking at end of rotaryReps.
Exchanged FORMATs #7 and #8 at Prog Numeric Format Definitions.
Changed TRUNC# from FORMAT#7 to #8 at Prog Numeric Format Definitions.
Changed CallMasterNum# from FORMAT#7 to #8 at Prog Numeric Format Definitions.
Changed Program2# from FORMAT#7 to #5 at Prog Numeric Format Definitions.
Added reFORMATting of Recall# at stdSub and openMP.
Rewrote handling of CutterRadiusCompensation.
Rewrote ckCRC procedure.
Rewrote handling of CRCOffC.
Deleted at finishSub1, tpArcFeat autoCycCutSub2 and 2 times at millingOp.
Added at end of toolPath.
Changed CRCOffsetC to ckCRCNum at tpArcFeat.
Rewrote handling of 'G8' corner rounding mode.
Deleted at tpLineFeat and tpArcFeat.
Added at toolPath.
Rewrote handling of Speed SpinOn.
Added GetSpeedAndSpinOn procedure.
Used to output Speed with SpinOn or G84.2.
Considers all possibilities.
Called from firstOp2, newToolOp4 and sameToolOp3.
Deleted SubCall at tpPointFeat and rotaryReps.
Changed 'L' to CallLabB for CallMasterOp at rotaryReps.
Added G84.1 Rigid Tap Cycle at rotaryReps.
Changed StrtPos to doStartPos at drillingOp.
Changed 'G80' to DrillOff at drillingOp.
Changed ProgID1 to SeqLab 'O' Program# at initOp.
Rewrote sameToolOp3.
Changed Reseq to Retag at end3.
DWB}

{1/14/99
Updated: CNCVIS2 PM611.17.3
Created: CNCVIS2 PM611.17.4
For: Gibbs & Associates
Versions: Virtual 5.04.05/ComPost2 1.7b15
Changes made per Pete Jackson.
Updated for Catalyst v5 per Fanuc 6M PM001.17.3 Format.
DWB}

{1/14/99
Updated: CNCVIS2 PM611.17.4
Created: CNCVIS2 RM611.17.4
For: Gibbs & Associates
Versions: Virtual 5.04.05/ComPost2 1.7b15
Changes made per Pete Jackson.
Updated for Catalyst v5 per Fanuc 6M RM001.17.4 Format.
DWB}

{1/20/99
Copied: CNCVIS2 RM611.17.4
Created: CNCVIS2 RM611.17.5
For: Gibbs & Associates
Versions: Virtual 5.05.04/ComPost2 1.7b15
Added missing EACHFadalSegment/NEXTFadalSegment loop at tpRapidFeat and tpLineFeat.
Added OR Rapid? at toolPath
Changed SetArcSegmentAccuracy to be .0005 for English and .0127 for Metric at progStart.
DWB}

{02/02/99,
Initial: CNCVIS2 RM611.17.5
Created: CNCVIS2 RM611.17.6
For: Gibbs & Assoc.

Changes to Prog:
1) Pulse? - This boolean is no longer true when the user selects Positive Approach
in any Drilling dialogue. This was changed in version 5.0. This boolean has been
replaced with PosApproach? which still works correctly.
CDH}

{2/15/99,
Initial : CNCVIS2 RM611.17.6
Created: Fadal Format 2 [AC] RM807.17.5
Customer: ALL Carbide, Chuck 609/882-3541
ComPost2: v1.7b15
MDD:

Changes to "Form":

. Under General Info, changed
. Under Default Formats, changed
. Under Origins and Values, changed
. Under Arcs, changed
. Under Polar Coordinates, changed
. Under Movement, changed
. Under Work Planes, changed
. Under Subs, changed
. Under Comments, changed
. Under Tool Offsets, changed
. Under Spindle and Coolant, changed
. Under Program Stops, changed
. Under Drill Cycles, changed

Changes to "Prog":

1. Changed ckCRC and ckCRCNum subs.
2. Moved wfostuff from StartPos block to before getSpeed.
3. Added G8M49 block before Tapping.
4. .
5. .
6. .
7.
8.
JHE}

{Prog Numeric Format Definitions *****************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '00'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(UnitAngle#,2)
FORMAT(TrackCNO#,2)
FORMAT(TrackC#,2)
FORMAT(MoveC#,2)
FORMAT(Dwell#,2)
FORMAT(Recall#,4)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackX#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(TRUNC#,6)
FORMAT(Program2#,6)
FORMAT(CallMasterNum#,6)
FORMAT(RapidF#,7)

{Added Subroutines *********************************}

spReset: {update to the correct StartPos}
TrackXNO# SPX#
TrackYNO# SPY#
TrackCNO# MoveC#
IF AutoCycle? AND NOT PointFeat?
Save# Num#('5') MoveC# { cOpEP }
END
RETURN

resetSP: {update to the correct StartPos}
IF Rotations? OR Repeats? OR AutoCycle?
CalcSCAng
IF AbsValue?
spReset
ELSE
SetAbs
spReset
SetInc
END
END
RETURN

saveEP: {save the correct EndPos}
IF PointFeat?
IF AutoCycle?
SetACSPCompF
Save# Num#('1') ADD# Recall# Num#('1') SPX# { xOpEP }
Save# Num#('2') ADD# Recall# Num#('2') SPY# { yOpEP }
SetACSPComp
ELSE
Save# Num#('1') SPX# { xOpEP }
Save# Num#('2') SPY# { yOpEP }
END
ELSE
Save# Num#('1') EPX# { xOpEP }
Save# Num#('2') EPY# { yOpEP }
END
Save# Num#('4') MoveC# { cOpEP }
IF AutoCycle? AND NOT PointFeat?
Save# Num#('5') SUB# MoveC# Recall# Num#('5') { cOpEP }
END
RETURN

getEP: {save the correct EndPos}
IF Rotations? OR Repeats? OR AutoCycle?
IF AbsValue?
saveEP
ELSE
SetAbs
saveEP
SetInc
END
END
RETURN

setSRXYtoACEP:
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackCNO# ADD# Recall# Num#('4') Recall# Num#('5') { cOpEP }
RETURN

{Prog Subroutines ****}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

wfo:
'E' NewWFO#
RETURN

wfoStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
wfo
END
ELSE
IF Flag?('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
wfo
END
ELSE
wfo
END
END
END
END
SetFlagF('2') { Do not output WFO second time wfoStuff is called for MP-WFO-OTAP-ECP }
RETURN

doSubComment:
IF UseComments? AND SubComment?
SeqLab '* SUB NUMBER: ' Program# EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
SeqLab '* OPERATION ' Operation#
IF OperationIDComment?
': ' OperationType$
END
EOL
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
SeqLab '* TOOL ' Tool#
IF ToolTypeComment?
': ' ToolDiameter# ' ' ToolType$
END
EOL
IF ToolComment?
SeqLab '* ' ToolComment$ EOL
END
restoreScale
END
RETURN

psInit:
NewWFOF
FourthCWF
FourthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

psStuff:
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
psInit
EachPS
SeqLab PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqLab EndOpPS EOL
psStuff
NextPS
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

setAngleUnder360: {sets status register and machine to current rotary position between -360 and 360 deg}
{Fanuc yes, Fadal no.}
RETURN

doStartPos:
IF RotaryMill?
'X' TrackX# StartPosX# 'Y0.' TrackYNO# StartPosY#
ELSE
StrtPos
END
IF AAxisAvail?
CalcSCAng FadalMoveC
ELSE
TrackCNO# Num#('0')
END
RETURN

entryMove:
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedEnt/FeedRate }
ELSE
IF LAST Rotations? OR LAST Repeats?
RapidF# { Forces FeedEnt/FeedRate }
END
END
IF FeedEntry?
SeqLab Feed ZIn FeedEntC EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

startSub:
OpenSub
SeqLab SubIDF EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

stdSub:
FORMAT(Recall#,6)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLab CallLab Recall# Num#('10') EOL
startSub
FORMAT(Recall#,4)
RETURN

finishSub1: {part 1}
IF NOT FeedConnect?
SeqLab RapidC ZCP3C EOL
END
RETURN

finishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqLab Rapid doStartPos SetWFO EOL
END
SeqLab CallLab OnePart EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
startSub
ELSE
FORMAT(Recall#,6)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLab CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
startSub
FORMAT(Recall#,4)
END
RETURN

closeMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
RETURN

doAbsOrInc:
IF Rotations? AND RotaryMill?
incValueC
ELSE
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
END
RETURN

doACAbsOrInc:
IF Rotations? AND CMove?
incValueC
ELSE
absOrIncC
END
RETURN

doDrillAbsOrInc:
IF Rotations? AND RotaryMill?
incValueC
ELSE
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
END
RETURN

restoreAbsOrInc:
IF Rotations? AND RotaryMill? AND NOT AutoCycle?
SeqLab absOrIncC EOL
ELSE
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqLab absOrIncC EOL
END
END
RETURN

ckCRC:
IF LastFeat?
IF NOT ArcFeat?
CRCOffC
END
ELSE
{IF NOT ZMove?} {Removed - JHE 2/15}
CRCOnC
{END}
END
RETURN

ckCRCNum:
{*IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END*}
IF CutterRadiusCompensation?
IF FirstFeat?
'D' Tool# {Changed to - JHE 2/15}
END
END
RETURN

tpPointFeat:
IF AutoCycle?
IF RotaryMill?
CalcSCAng
SeqLab doACAbsOrInc MoveSXC FadalMoveCC EOL
SetAbsOrInc
TrackCNO# ADD# Recall# Num#('5') MoveC# EOL {calc MoveC position after sub call}
ELSE
SeqLab MoveSXYC EOL
END
IF Repeats? AND ZshiftOnly?
SeqLab CallLabB TRUNC# SUB# Program# Num#('1') '01' EOL
ELSE
SeqLab CallLab '01' EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat?
SetFlagF('9') { For valid Drill Rotation Sub }
IF Rotations?
IF NOT LastFeat?
IF NOT MasterOp?
SetFlag('9') { valid Drill Rotation Sub }
NewProg
StartSub
END
END
END
ELSE
IF RotaryMill?
CalcSCAng
SeqLab doDrillAbsOrInc MoveSXC MoveSZC FadalMoveCC EOL
ELSE
SeqLab doDrillAbsOrInc MoveSXYZC EOL
END
END
IF LastFeat?
IF Flag?('9') { valid Drill Rotation Sub }
restoreAbsOrInc
IF NOT MasterOp?
SeqLab EndSub EOL
CloseSub
END
END
END
END
RETURN

tpRapidFeat:
IF RotaryMill?
CalcCAng
IF XMove? OR ZMove? OR CMove?
EACHFadalSegment
CalcCAng
SeqLab doAbsOrInc ckCRC RapidC MoveXC MoveZC FadalMoveCC ckCRCNum EOL
NEXTFadalSegment
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
END
RETURN

tpLineFeat:
IF RotaryMill?
CalcCAng
IF XMove? OR ZMove? OR CMove?
EACHFadalSegment
CalcCAng
SeqLab doAbsOrInc ckCRC FeedC MoveXC MoveZC FadalMoveCC AngleFeedC ckCRCNum EOL
NEXTFadalSegment
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
RETURN

tpArcFeat:
IF RotaryMill?
EachArcSegment
CalcCAng
SeqLab doAbsOrInc ckCRC FeedC MoveXC MoveZC FadalMoveCC AngleFeedC ckCRCNum EOL
NextArcSegment
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqLab doAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
ArcFeedC ckCRCNum EOL
NEXTQuadrant
END
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF FirstFeat?
resetSP
END
IF PointFeat?
tpPointFeat
ELSE
IF RapidFeat?
tpRapidFeat
ELSE
IF FirstFeat? OR Rapid?
SeqLab 'G8' EOL
END
IF LineFeat?
tpLineFeat
ELSE
IF ArcFeat?
tpArcFeat
END
END
END
END
IF LastFeat?
getEP
END
NEXTFeat
SeqLab CRCOffC EOL
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqLab incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqLab absOrIncC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
RapidC ZCP2
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqLab absOrIncC Connect doStartPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubContour:
SetPass1
TrackZNO# SPZ#
startSub
RapidF#
IF AutoCycle?
NewProg
autoCycCutSub1 {build element sub}
TrackZNO# SPZ#
autoCycCutSub2
ELSE
toolPath
finishSub1
SeqLab EndSub EOL
CloseSub
END
SetPass1
SetStatusRapid
RapidF#
SetSRXYtoEP
TrackZNO# ClearancePlane2#
TrackCNO# Recall# Num#('4') { cOpEP }
RETURN

doSepSubFeedConnect:
IF FeedConnect?
IF CMove?
AngleFeedC
ELSE
FeedEntC
END
END
RETURN

doSepSubSPMove:
SetStatusOff
IF RotaryMill?
CalcSCAng
IF SPXMove? OR CMove?
IF Rotations? OR AutoCycle?
incValueC
END
SeqLab Connect MoveSXC FadalMoveCC doSepSubFeedConnect EOL
absOrIncC
ELSE
Connect
END
ELSE
IF SPXMove? OR SPYMove?
IF AutoCycle?
incValueC
END
SeqLab Connect StrtPosC doSepSubFeedConnect EOL
absOrIncC
ELSE
Connect
END
END
SetStatusOn
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusInc EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqLab RapidC ZInPlusInc EOL
END
END
SeqLab CallLab '01' EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqLab ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
SetAbs
TrackZNO# ADD# SPZ# MUL# RepsLess1# RepeatZ#
SetInc
RETURN

doSepSubExit:
IF NOT AbsValue?
setSepSubZ
END
IF AutoCycle?
SeqLab Rapid ZCP2 EOL
ELSE
Rapid { Will be output at millingOp ZCP3 }
END
RETURN

resetSepSubSR:
SetPass1
SetStatusRapid
RapidF#
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackCNO# Recall# Num#('4') { cOpEP }
RETURN

zonlyRepAutoCycle:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
IF FeedConnect?
doSepSubExit
END
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
autoCycPat {write pattern moves and main calls}
resetSepSubSR
TrackZNO# ClearancePlane2#
RETURN

zonlyRep:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
resetSepSubSR
IF FeedConnect?
doSepSubExit
ELSE
TrackZNO# ClearancePlane3#
END
RETURN

millingOp:
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
setSRXYtoACEP
ELSE
SeqLab RapidC ZCP3C EOL
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
CalcSCAng
TrackCNO# MoveC#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

drillingOp:
IF NOT Rotations?
IF PosApproach? { Positive Approach On }
SeqLab 'M46' EOL
END
END
SeqLab DrillCP EOL
GetCycle
IF Tap?
SeqLab 'G8M49' EOL {Added this line - JHE 2/15}
END
IF RigidTap?
SeqLab 'G84.1'
ELSE
SeqLab Cycle
END
FromCP doStartPos ZDepth RLevel Dwell Peck Retract FeedEnt
IF RigidTap?
Speed
END
EOL
IF CallMasterOp?
SeqLab CallLabB CallMasterNum# '01' EOL
skipToLastFeat
ELSE
TrackZNO# SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqLab CallLab '01' EOL
startSub
toolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
toolPath
END
END
setDrillEndOpZ
IF NOT Rotations?
IF PosApproach? { Positive Approach Off }
SeqLab 'M47' EOL
END
SeqLab DrillOff Rapid ZCP3 EOL
END
RETURN

getSpeed:
IF Drilling?
GetCycle
END
IF Drilling? AND RigidTap?
IF FirstOperation? OR NewTool?
SeqLab Speed EOL
END
SeqLab SpeedC EOL
SeqLab 'G84.2' EOL
ELSE
IF FirstOperation? OR NewTool?
SeqLab Speed SpinOn EOL
ELSE { SameTool }
IF LAST ProgStop?
SeqLab SpeedC SpinOn EOL
ELSE
SeqLab SpeedC EOL
END
END
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

rotateStartPosC:
TrackXNO# Recall# Num#('1') { xOpEP }
MoveSXC
IF NOT RotaryMill?
TrackYNO# Recall# Num#('2') { yOpEP }
MoveSYC
END
CalcSCAng FadalMoveC
RETURN

rotaryReps: {use the correct EndPos}
EachRotation
IF Milling?
IF FirstRotation?
NewProg
SaveProgNum2
StartSub
millingOp
SeqLab EndSub EOL
CloseSub
checkPass
ELSE
SeqLab rotateStartPosC EOL
END
SeqLab CallLabB Program2# '01' EOL
ELSE
IF Drilling?
IF FirstRotation?
IF PosApproach? { Positive Approach On }
SeqLab 'M46' EOL
END
drillingOp
checkPass
ELSE
IF RetractToCP1? AND Equal? ClearancePlane1# ClearancePlane3#
SeqLab rotateStartPosC EOL
ELSE
IF NOT RetractToCP1? AND Equal? ClearancePlane2# ClearancePlane3#
SeqLab rotateStartPosC EOL
ELSE { Need to cancel Drill Cycle between Rotations }
SeqLab DrillOff Rapid ZCP3 EOL
SeqLab rotateStartPosC EOL
SeqLab DrillCP EOL
IF Tap?
SeqLab 'G8M49' EOL {Added this line - JHE 2/15}
END
IF RigidTap?
SeqLab 'G84.1'
ELSE
SeqLab Cycle
END
FromCP rotateStartPosC ZDepth RLevel Dwell Peck Retract FeedEnt
IF RigidTap?
Speed
END
EOL
END
END
END
IF CallMasterOp?
IF NOT FirstRotation?
SeqLab CallLabB CallMasterNum# '01' EOL
END
ELSE
IF MasterOp?
IF NOT FirstRotation?
SeqLab CallLab '01' EOL
END
ELSE
IF Flag?('9') { valid Drill Rotation Sub }
SeqLab CallLab '01' EOL
END
END
END
IF LastRotation?
IF PosApproach? { Positive Approach Off }
SeqLab 'M47' EOL
END
SeqLab DrillOff Rapid ZCP3 EOL
END
END
END
IF LastRotation?
EachFeat
IF LastFeat?
IF PointFeat?
CalcSCAng
ELSE
CalcCAng
END
TrackCNO# MoveC# EOL
END
NextFeat
END
NextRotation
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackZNO# ClearancePlane3#
RETURN

opGuts:
IF Rotations?
rotaryReps
ELSE
IF Milling?
millingOp
ELSE
IF Drilling?
drillingOp
END
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('12700')
SetArcSegmentAccuracy('.0127')
ELSE
SetMaxFeed('500')
SetArcSegmentAccuracy('.0005')
END
SetFadalSegAngleLimit('359.95')
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('4') Num#('0') { Status Register Variable for C Axis }
Save# Num#('5') Num#('0') { AutoCycle SetPass1 C Axis Travel }
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlagF('9') { For valid Drill Rotation Sub }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
EOR EOL
SeqLab ProgID1
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
SetProgNum('0')
IF UseComments?
IF ProgramComment?
SeqLab '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
SeqLab '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLab '* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
IF Metric?
SeqLab 'G21' EOL
ELSE
SeqLab 'G20' EOL
END
SeqLab OpToolID ToolChng EOL
doOpComments
doPostScript
RETURN

firstOp2:
SeqLab wfoStuff EOL {Moved to here - JHE 2/15}
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid doStartPos EOL
RETURN

firstOp3:
SeqLab OfstOn CoolOn EOL
RETURN

newToolOp1:
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0.' EOL { OfstOff }
setAngleUnder360
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab 'G53' Home EOL
END
IF LAST ProgStop?
SeqLab 'M0' EOL
ELSE
SeqLab ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng EOL
doOpComments
doPostScript
RETURN

newToolOp4:
SeqLab wfoStuff EOL {Moved to here - JHE 2/15}
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid doStartPos EOL
RETURN

newToolOp5:
SeqLab OfstOn CoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0.' EOL { OfstOff }
SeqLab 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset?
SeqLab 'G53Z0.' EOL { OfstOff }
END
END
setAngleUnder360
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
SeqLab wfoStuff EOL {Moved to here - JHE 2/15}
getSpeed
SeqLab PlaneC AbsOrInc Rapid doStartPos EOL
IF LAST ProgStop?
SeqLab OfstOn CoolOn EOL
ELSE
SeqLab
IF NewToolOffset?
OfstOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

end1:
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0.' EOL { OfstOff }
setAngleUnder360
IF NotEqual? UnitAngle# Num#('0')
SeqLab absOrIncC RapidC 'A'
IF GreaterThan? UnitAngle# Num#('180') {Added - JHE}
'-'
END
TrackC# Num#('0') EOL
END
RETURN

end2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab absOrIncC Rapid FirstHome EOL
END
IF ProgStop?
SeqLab 'M0' EOL
END
RETURN

end3:
SeqLab 'X0.Y0.Z0.E0H0' EOL
SeqLab EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
SeqLab '* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
SeqLab '* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
SeqLab '* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END
Retag
RETURN

mpAllTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mpAllTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END