{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{added CRCOffC to rapid up and repeats, same as all other Fadal posts, 9/26/88 WFG}
{Changed max rpm from 10000 to 15000 JR 6/5/89}

{1/26/90, Updated: Fadal M003.58, to .69 format, JR}
{2/90/90, Updated: Fadal M003.69, to .70 format, JR}
{3/23/90, 15000 max RPM, JR}

{4/6/90
Added '01' literal for looping once on CallLab line at ZonlyRepAutoCycle & ZonlyRep subs.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/10/90, Updated: Fadal M003.71 to .74 format, JR}

{8/10/90
Copied & modified: Fadal M003.74
For: Admiral
Add CRCOffsetC & ResetCRCNum.
Change to First Tool Not In Spindle.
OpToolID & ToolChng on same line.
WFO's output for MultipleParts & NewWFO only.
Added 'Z0H0' for offset cancel (full up) with CoolOff on same line.
Remove StrtPos from drill cycle line.
CoolOn on same line as OfstOn.
Combine M codes on 1 line.
Jim Radcliffe}

{4/03/91
Modified: Fadal (AEM) M332.74
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/2/92
Copied & modified from Fadal (AEM) M332.79
New designation Fadal Format 1 (Amcraft) M---.--
For Amcraft
Add WFO to move to StrtPos.
Add StrtPos to WFO's at multi parts.
Change 'Z0H0' to 'G0G49Z0' for offset cancel and remove CoolOff except at end.
Add 'X0Y10.E0' to bring table to operator for loading. Works with VMC 4020 only. Y value would differ
for other models. Not ideal way to handle but consistent with customers current method.
Add 'M0' before 'M2' at end of program so that table stops at modified E0 position.
Add StrtPos to drill cycle line.
Move Rapid StrtPos lines ahead of IF Multiparts? lines.
KC}

{8/19/92
Added "SetProgNum" to reset subroutine numbers to one "1" regardless of program number
KC}

{2/11/93
Created from Fadal Format 1 [AC] M509.81.2
For: Fadal
By: [cwh]
Changed 'X0Y10.E0' at end to 'X0Y0Z0E0'.
}
{2/16/93
For: Fadal
By: [cwh]
Changed EOP from M2 to M30.
Changed 'G0G49Z0M5M9' at end to 'M5M9' & 'G0G90Z0H0'.
Removed the trailing comments.
Added a 'G8' on a line by itself before the first G1, G2, G3 following a G0.
}
{2/22/93
For: Fadal
By: [cwh]
Changed all 'G0G49Z0' to 'G0H0Z0'.
}
{3/8/93
For: Fadal
By: [cwh]
Modified the tap cycle section to test for OptCyc1. ( rigid tap, set
in the post via a PS command. )
Modified the drilling cycle to check for Pulse coolant for use as
a Positive Approach flag. ( set in the post via a PS command. )
}
{5/5/93
For: Gibbs
By: [cwh]
Changed all CRCOffsetC to "'D' Tool#". Also made use of flag('1') to
determine when to output. This was done to counter act a change made
in the Catalyst post code that now adds 50 to the tool number to derive
the CRC Offset value.
}
{5/13/93
For: Fadal
By: [cwh]
Modified the WFOStuff routine to handle work fixture offsets better
with multiple parts by checking the NeedWFO1 boolean.
}
{6/17/93
For: Fadal
By: [cwh]
Modified the second and consequent tool changes from
G0 H0 Z0 M9
T# M6
to
M5 M9
T# M6
Changed the ending sequence to
G0 G90 M5 M9
G53 Z0
X0 Y0 Z0 E0 H0
M30
Changed the spindle on line for Rigid Tap cycles to
S####
G84.2
}
{6/23/93
For: Fadal
By: [cwh]
Modified the second and consequent tool changes to output a
'M5 M9' regardless of the ToolChangeAtHome? result.
}
{12/23/93
For: Fadal
By: [cwh]
Modified to output CRC on leadin arc moves. Also CRC cancelation is on a line by itself.
Modified to limit the maximum number of repeats per sub call to 99.
}

{6/10/94
Modified: CNCVIS1 M610.PST
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.21
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Reorganized Prog Formats.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added RestoreScale Sub per 4-Axis Post Processor.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added Move Checker at StdLine.
Deleted StrtPosC at AutoCycCutSub1
Moved SetPass1 from ZonlyRepAutoCycle to AutoCycPat
Made necessary corrections.
Added FORMAT#7 '00' for Recall# to output leading zeros for Repeat Loops value.
Modified OperationIDComment at DoOpComments.
Modified ToolTypeComment at DoOpComments.
Moved CheckPass call to before StrtPos at FirstOperation and NewTool.
This is important for correct AutoCycle SetPass2 StrtPos values.
Changed SeqLabC to SeqLab where ToolPath output CRCOffC for LastFeat of ArcFeat.
Changed SeqC to SeqLab at CoolOff and CoolOn booleans at SameTool.
Change Post to CloseSub and Post2 at end of Prog.
DWB}
{9/26/94
Modified: CNCVIS1 M610.81.2 to CNCVIS1 M610.81.3
For: Star Metal
By: [cwh]
Modified the main section to handle the use of multiple parts better with
respect to initial postioning and spindle on and off commands.
}

{11/16/94 Fixed bug with Program Stops Tom Hubina}

{
Format: CNCVIS1 M610.81.5
3/17/95
Changed SetMaxSeparateSubCalls('50') to SetMaxSeparateSubCalls('500')
TH}

{6/9/95
Fixed CRC so it won't output on a helix
TH}

{7/10/95
Updated: CNCVIS1 M610.81.6
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2g Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added logic to suppress output of CRCOnC in OneFeat ToolPath.
Moved ResetCRCNum at start of ToolPath to CkCRC sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to ZMoveOnly Feature at ToolPath RapidFeat.
Outputs G40 at all Z Retract blocks.
Deleted DoArcCRC sub.
CkCRC sub now called, 3 places at ToolPath ArcFeat.
Deletes use of Flag(8)
Deleted CRCValue sub.
Not needed because problem has been resolved, see 5/5/93.
Deleted SetFlagF(9) at setup and initializations.
Was not being used anywhere.
Simplified output of Canned Drill Cycle block at IF Drilling.
DWB}

{7/14/95, Updated CNCVIS1 M610.81.7 to .85 format per v2.20 Update Instructions .01, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, ZOnlyRepAutocycle tested, incremented to .89, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{8/7/96
Initial: CNCVIS1 M610.89
Created: Fadal VMC Format 1 M000.89
ForUser: Murtaugh / Heighten Mfg
Control: Fadal Format 1
Machine: Fadal VMC
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readouts from Murtaugh
Added Tool List to beginning of program.
Deleted All 'G8's
Moved SubComment to SubID line.
Moved tool comments from DoOpComments to ToolChng line using DoToolComments sub.
Added DoToolComments and OperationComment to beginning of subs.
Deleted CRCOffsetC.
Changed CoolOn from M7 to M8.
Suppressed output of 1st WFO call in OpenMP for MultipleParts ExitClearancePlane.
OfstOff outputs H0Z0. Changed literals to OfstOff.
Added OfstOff call for MultipleParts FullUp.
Changed 'X0Y0Z0E0H0' at end of program to 'X0Y0' WFOOff.
Changed EOP from M30 to M2.
Modified RigidTap.
Changed Tap from G84 to G75.
Jim Radcliffe}

{9/26/96
Initial: Fadal Format 1 VMC [HM] MZ28.89
Created: Fadal Format 1 [HM] MZ28.89.1
ForUser: Murtaugh / Heighten Mfg
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per marked up readout from Murtaugh / Heighten Mfg
Added additional space to tool commant lines.
Changed ShiftP, UnshiftP, ShiftR & UnshiftR to output conditionaly.
Fixed output of OfstOff.
Fixed OpenMP for MultipleParts ExitClearancePlane.
Jim Radcliffe}

{11/22/96
Initial: Fadal Format 1 [HM] MZ28.89.1
Created: Fadal Format 1 [HM] MZ28.89.2
ForUser: Murtaugh / Heighten Mfg
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Added StartPos after OpenMP for MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
Jim Radcliffe}

{8Jan99
Original: Fadal Format 1 [HM] MZ28.89.2
Created: Fadal Format 1 [SM] Mxxx.89
For: Seymour Machine, Inc.
Changes made per: Scott Vanden Langenber: (920) 833 - 7543
Added Post Header Comment at the top of Prog.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Deleted G17 from MachSpec
Charles Winston}

{3/9/99
Initial: Fadal Format 1 [SM] MT74.89
Created: Fadal Format 1 [SM] PMT74.17.6
ForUser: Seymour
Develop: Compost2 PPC 1.7b15, Virtual Gibbs 5.05
Comment: Simple A Axis Positioning per CNCVIS1 PM610.17.6
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '00'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(UnitAngle#,2)
FORMAT(TrackCNO#,2)
FORMAT(TrackC#,2)
FORMAT(MoveC#,2)
FORMAT(Dwell#,2)
FORMAT(Recall#,4)
FORMAT(ADD#,4)
FORMAT(SpeedRPM#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(TLDia#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(TRUNC#,6)
FORMAT(Program2#,6)
FORMAT(CallMasterNum#,6)
FORMAT(RapidF#,7)

{Added Subroutines ****}

spReset: {update to the correct StartPos}
TrackXNO# SPX#
TrackYNO# SPY#
RETURN

resetSP: {update to the correct StartPos}
IF Rotations? OR Repeats? OR AutoCycle?
IF AbsValue?
spReset
ELSE
SetAbs
spReset
SetInc
END
END
RETURN

saveEP: {save the correct EndPos}
IF PointFeat?
IF AutoCycle?
SetACSPCompF
Save# Num#('1') ADD# Recall# Num#('1') SPX# { xOpEP }
Save# Num#('2') ADD# Recall# Num#('2') SPY# { yOpEP }
SetACSPComp
ELSE
Save# Num#('1') SPX# { xOpEP }
Save# Num#('2') SPY# { yOpEP }
END
ELSE
Save# Num#('1') EPX# { xOpEP }
Save# Num#('2') EPY# { yOpEP }
END
RETURN

getEP: {save the correct EndPos}
IF Rotations? OR Repeats? OR AutoCycle?
IF AbsValue?
saveEP
ELSE
SetAbs
saveEP
SetInc
END
END
RETURN

setSRXYtoACEP:
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
RETURN

{Prog Subroutines ****}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

wfo:
'E' NewWFO#
RETURN

wfoStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
wfo
END
ELSE
IF Flag?('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
wfo
END
ELSE
wfo
END
END
END
END
SetFlagF('2') { Do not output WFO second time wfoStuff is called for MP-WFO-OTAP-ECP }
RETURN

doSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program#
END
RETURN

doToolComments:
IF UseComments?
SetScale('1')
'* TOOL ' Tool#
IF ToolTypeComment?
': ' ToolDiameter# ' ' ToolType$
END
IF ToolComment?
' ' ToolComment$
END
RestoreScale
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
SeqLab '* OPERATION ' Operation#
IF OperationIDComment?
': ' OperationType$
END
EOL
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
RestoreScale
END
RETURN

psInit:
NewWFOF
FourthCWF
FourthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

psStuff:
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
psInit
EachPS
SeqLab PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqLab EndOpPS EOL
psStuff
NextPS
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

setAngleUnder360: {sets status register and machine to current rotary position between -360 and 360 deg}
{Fanuc yes, Fadal no.}
RETURN

doStartPos:
StrtPos
IF AAxisAvail?
CalcSCAng FadalMoveC
ELSE
TrackCNO# Num#('0')
END
RETURN

entryMove:
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedEnt/FeedRate }
ELSE
IF LAST Rotations? OR LAST Repeats?
RapidF# { Forces FeedEnt/FeedRate }
END
END
IF FeedEntry?
SeqLab Feed ZIn FeedEntC EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

startSub:
OpenSub
SeqLab SubIDF doSubComment EOL
SeqLab doToolComments EOL
doOpComments
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

stdSub:
FORMAT(Recall#,6)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLab CallLab Recall# Num#('10') EOL
startSub
FORMAT(Recall#,4)
RETURN

finishSub1: {part 1}
IF NOT FeedConnect?
SeqLab RapidC ZCP3C EOL
END
RETURN

finishSubG92: {part 2}
SeqLab Preset ShiftRC EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshftRC EOL
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqLab Rapid doStartPos SetWFO EOL
END
SeqLab CallLab OnePart EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
startSub
ELSE
FORMAT(Recall#,6)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLab CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
startSub
FORMAT(Recall#,4)
END
RETURN

closeMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
ELSE
SeqLab Preset ShiftPC EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshftPC EOL
END
RETURN

doAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqLab absOrIncC EOL
END
RETURN

ckCRC:
IF LastFeat?
IF NOT ArcFeat?
CRCOffC
END
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
{CRCOffsetC}
END
RETURN

tpPointFeat:
IF AutoCycle?
SeqLab MoveSXYC EOL
IF Repeats? AND ZshiftOnly?
SeqLab CallLabB TRUNC# SUB# Program# Num#('1') '01' EOL
ELSE
SeqLab CallLab '01' EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat?
SetFlagF('9') { For valid Drill Rotation Sub }
IF Rotations?
IF NOT LastFeat?
IF NOT MasterOp?
SetFlag('9') { valid Drill Rotation Sub }
NewProg
StartSub
END
END
END
ELSE
SeqLab doDrillAbsOrInc MoveSXYZC EOL
END
IF LastFeat?
IF Flag?('9') { valid Drill Rotation Sub }
restoreAbsOrInc
IF NOT MasterOp?
SeqLab EndSub EOL
CloseSub
END
END
END
END
RETURN

tpRapidFeat:
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
RETURN

tpLineFeat:
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
RETURN

tpArcFeat:
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqLab doAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
ArcFeedC ckCRCNum EOL
NEXTQuadrant
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF FirstFeat?
resetSP
END
IF PointFeat?
tpPointFeat
ELSE
IF RapidFeat?
tpRapidFeat
ELSE
IF FirstFeat? OR Rapid?
{SeqLab 'G8' EOL}
END
IF LineFeat?
tpLineFeat
ELSE
IF ArcFeat?
tpArcFeat
END
END
END
END
IF LastFeat?
getEP
END
NEXTFeat
SeqLab CRCOffC EOL
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqLab incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqLab absOrIncC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
RapidC ZCP2
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqLab absOrIncC Connect doStartPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubContour:
SetPass1
TrackZNO# SPZ#
startSub
RapidF#
IF AutoCycle?
NewProg
autoCycCutSub1 {build element sub}
TrackZNO# SPZ#
autoCycCutSub2
ELSE
toolPath
finishSub1
SeqLab EndSub EOL
CloseSub
END
SetPass1
SetStatusRapid
RapidF#
SetSRXYtoEP
TrackZNO# ClearancePlane2#
RETURN

doSepSubFeedConnect:
IF FeedConnect?
FeedEntC
END
RETURN

doSepSubSPMove:
SetStatusOff
IF SPXMove? OR SPYMove?
IF AutoCycle?
incValueC
END
SeqLab Connect StrtPosC doSepSubFeedConnect EOL
absOrIncC
ELSE
Connect
END
SetStatusOn
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusInc EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqLab RapidC ZInPlusInc EOL
END
END
SeqLab CallLab '01' EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqLab ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
SetAbs
TrackZNO# ADD# SPZ# MUL# RepsLess1# RepeatZ#
SetInc
RETURN

doSepSubExit:
IF NOT AbsValue?
setSepSubZ
END
IF AutoCycle?
SeqLab Rapid ZCP2 EOL
ELSE
Rapid { Will be output at millingOp ZCP3 }
END
RETURN

resetSepSubSR:
SetPass1
SetStatusRapid
RapidF#
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
RETURN

zonlyRepAutoCycle:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
IF FeedConnect?
doSepSubExit
END
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
autoCycPat {write pattern moves and main calls}
resetSepSubSR
TrackZNO# ClearancePlane2#
RETURN

zonlyRep:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
resetSepSubSR
IF FeedConnect?
doSepSubExit
ELSE
TrackZNO# ClearancePlane3#
END
RETURN

millingOp:
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
setSRXYtoACEP
ELSE
SeqLab RapidC ZCP3C EOL
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

drillingOp:
IF NOT Rotations?
IF PosApproach? { Positive Approach On }
{SeqLab 'M46' EOL}
END
END
SeqLab DrillCP EOL
GetCycle
SeqLab
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP doStartPos ZDepth RLevel Dwell Peck Retract
IF Tap?
'F' SpeedRPM# FadalTapQ
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLab CallLabB CallMasterNum# '01' EOL
skipToLastFeat
ELSE
TrackZNO# SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqLab CallLab '01' EOL
startSub
toolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
toolPath
END
END
setDrillEndOpZ
IF NOT Rotations?
IF PosApproach? { Positive Approach Off }
{SeqLab 'M47' EOL}
END
SeqLab DrillOff Rapid ZCP3 EOL
END
RETURN

getSpeed:
IF Drilling?
GetCycle
END
IF NOT RigidTap?
IF FirstOperation? OR NewTool?
SeqLab Speed SpinOn EOL
ELSE { SameTool }
IF LAST ProgStop?
SeqLab SpeedC SpinOn EOL
ELSE
SeqLab SpeedC EOL
END
END
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

rotateStartPosC:
TrackXNO# Recall# Num#('1') { xOpEP }
MoveSXC
TrackYNO# Recall# Num#('2') { yOpEP }
MoveSYC
CalcSCAng FadalMoveC
RETURN

rotaryReps: {use the correct EndPos}
EachRotation
IF Milling?
IF FirstRotation?
NewProg
SaveProgNum2
StartSub
millingOp
SeqLab EndSub EOL
CloseSub
checkPass
ELSE
SeqLab rotateStartPosC EOL
END
SeqLab CallLabB Program2# '01' EOL
ELSE
IF Drilling?
IF FirstRotation?
IF PosApproach? { Positive Approach On }
{SeqLab 'M46' EOL}
END
drillingOp
checkPass
ELSE
IF RetractToCP1? AND Equal? ClearancePlane1# ClearancePlane3#
SeqLab rotateStartPosC EOL
ELSE
IF NOT RetractToCP1? AND Equal? ClearancePlane2# ClearancePlane3#
SeqLab rotateStartPosC EOL
ELSE { Need to cancel Drill Cycle between Rotations }
SeqLab DrillOff Rapid ZCP3 EOL
SeqLab rotateStartPosC EOL
SeqLab DrillCP EOL
SeqLab
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP rotateStartPosC ZDepth RLevel Dwell Peck Retract
IF Tap?
'F' SpeedRPM# FadalTapQ
ELSE
FeedEnt
END
EOL
END
END
END
IF CallMasterOp?
IF NOT FirstRotation?
SeqLab CallLabB CallMasterNum# '01' EOL
END
ELSE
IF MasterOp?
IF NOT FirstRotation?
SeqLab CallLab '01' EOL
END
ELSE
IF Flag?('9') { valid Drill Rotation Sub }
SeqLab CallLab '01' EOL
END
END
END
IF LastRotation?
IF PosApproach? { Positive Approach Off }
{SeqLab 'M47' EOL}
END
SeqLab DrillOff Rapid ZCP3 EOL
END
END
END
NextRotation
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackZNO# ClearancePlane3#
RETURN

opGuts:
IF Rotations?
rotaryReps
ELSE
IF Milling?
millingOp
ELSE
IF Drilling?
drillingOp
END
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlagF('9') { For valid Drill Rotation Sub }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
EOR EOL
SeqLab ProgID1
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
SetProgNum('0')
IF UseComments?
IF ProgramComment?
SeqLab '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
SeqLab '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLab '* FIRST TOOL NOT IN SPINDLE' EOL
END
EachTool
SeqLab '* Tool ' TLNum# ': ' TLDia# ' ' TLToolType$ ' ' TLToolComment$ EOL
NextTool
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
{SeqLab 'G20' EOL Inch Mode }
SeqLab OpToolID ToolChng doToolComments EOL
doOpComments
doPostScript
RETURN

firstOp2:
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid doStartPos wfoStuff EOL
RETURN

firstOp3:
SeqLab OfstOn CoolOn EOL
RETURN

newToolOp1:
SeqLab Rapid AbsOrInc SpinOff CoolOff EOL
SeqLab OfstOff EOL
setAngleUnder360
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab 'G53' Home EOL
END
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng doToolComments EOL
doOpComments
doPostScript
RETURN

newToolOp4:
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid doStartPos wfoStuff EOL
RETURN

newToolOp5:
SeqLab OfstOn CoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqLab Rapid AbsOrInc SpinOff CoolOff EOL
SeqLab OfstOff EOL
SeqLab 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset?
SeqLab Rapid OfstOff EOL
END
END
setAngleUnder360
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
getSpeed
SeqLab PlaneC AbsOrInc Rapid doStartPos wfoStuff EOL
IF LAST ProgStop?
SeqLab OfstOn CoolOn EOL
ELSE
SeqLab
IF NewToolOffset?
OfstOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

end1:
SeqLab Rapid AbsOrInc SpinOff CoolOff EOL
SeqLab OfstOff EOL
setAngleUnder360
IF NotEqual? UnitAngle# Num#('0')
SeqLab absOrIncC RapidC 'A'
IF GreaterThan? UnitAngle# Num#('180') {Added - JHE}
'-'
END
TrackC# Num#('0') EOL
END
RETURN

end2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab absOrIncC Rapid FirstHome EOL
END
IF ProgStop?
SeqLab 'M00' EOL
END
RETURN

end3:
SeqLab 'X0Y0' WFOOff EOL
SeqLab EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

mpAllTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mpAllTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END