{10/2/89
This prog incorporates the new vectoring commands per
Post Note 10 and also has the format changes originally
made by Stan Lytle.
J. Cusimano}

{11/3/89
Copied & modified: Meldas 5000C OKK M241.61
For: Seibens
Added Zeros to G92 line.
Deleted G99 & M05 from MachSpec.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{12/12/90, Updated: Meldas 5000C OKK M241.63 to .76.1 format, JR}

{12/12/90
Copied & modified: Meldas 5000C OKK M241.76.1
For: Precision Machine
Delete Preset from beginning of prog.
Moved PreTool & ToolChng.
Added SpinOff code to MachSpec (M19).
Changed "'G44Z-1000'" offset cancel to "OfstOff" (G44Z0), Cancels ofset & Full-up.
Deleted "Preset 'Z0'" no longer needed.
Deleted "G28Z0" no longer needed.
Changed "'%'" to "EOR".
Move ProgramComment & TimeComment to Before EOR code at beginning of prog.
Put CRCOff on line by itself after Z move unless AutoCycle.
Jim Radcliffe}

{2/4/91 & 2/5/91
Modified: Meldas 5000C OKK [PM] M369.76
For: Precision Machine
Added 'G21' to beginning of all subs.
Added 'G20' to end of all subs (Also deleted Null Foot)
Deleted EOR from beginning of subs.
Changed 'M98P' Fanuc format to 'G22H' format.
Changed 'M99' to 'G23'
Added 'IF UseComments?' logic to first OP for ProgramComment$, Time$, etc.
Added Tagging for Subroutines - control calls sub using following format:
G22H <sub>Note: No looping capability - IE: L002;
G23 returns from sub (Identical to Fanuc M99) therefore no Tagging required
to return from sub.
Added Reseq because of Tagging.
Joe Cusimano & Shohreh}

{4/03/91
Modified: Meldas 5000C OKK [PM] M369.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{01/24/92
Modified: Meldas 5000C OKK [PM] M369.79
For: Gibbs & Associates / Precision Machine
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Added StrtPos line after the Cycle call in IF Drilling?
Kim Michelman}

{02/13/92
Modified: Meldas 5000C OKK [PM] M369.79
For: Precision Machine
Changed the Home command in NewTool to NewHome.
Kim Michelman}

{10/14/92
Modified: Meldas 5000C OKK [PM] M369.81.2
For: Precision Machine
Changed NewHome back to Home at NewTool.
Changed FirstHome back to Home at end of Prog.
Was causing an Lathe Alert to appear IF ToolChangeAtHome = TRUE.
DWB}

{10/15/93
Modified: Meldas 5000C OKK [PM] M369.81.3
For: Precision Machine
Deleted StrtPos from DrillCycle line.
Changed Program# to Tag# for SubComment.
Discriminate reading SetAbsOrInc, need to leave in SetInc if AutoCycle is true.
Update per Fanuc 6M M001.81.2
Jim Radcliffe}

{7/6/94
Modified: Meldas 5000C OKK [PM] M369.81.4
For: Precision Machine
Changed 'G28Z0' at beginning of program to 'G40G80G90G00'.
Added G99 to MachSpec for Retract to Second Clearance Plane in Drilling.
Suppressed output of StrtPos on line after Drill Cycle ling to be output only if RetractToCP1
Deleted 'G92Z0' line from beginning of program.
Changed 'G28X0Y0Z0' at end of program to 'G28X0Y0'
Z0 not needed as its allready there with OfstOff (G44ZO) command.
Added blocks to set program zero to beginning of program.
This procesor does not support WFO MultipleParts so I commented it accordingly.
Changed AbsValue to AbsOrInc.
Jim Radcliffe}

{9/28/95, Updated Meldas 5000C OKK [PM] M369.81.5 to .85 format per Meldas 5000C OKK M241.85, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###^0000;0' { used for CRC vectors}
#3 = '*###^0000;0' { used for CRC vectors}
#4 = '###^##0'
#5 = '*###^##0'
#6 = '####.####;0.'
#7 = '#######0'
#8 = '####^###;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(EPX#,2)
FORMAT(EPY#,2)
FORMAT(ToolDiameter#,6) {.72}
FORMAT(Tag#,7)
FORMAT(CallMasterNum#,7)
FORMAT(Operation#,7) {.72}
FORMAT(Tool#,7) {.72}
FORMAT(NewWFO#,7) {.72}
FORMAT(Parts#,7) {.72}
FORMAT(Dwell#,8) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,4)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,5)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,4)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,5)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC 'G21' EOL
DoSubComment
'>' Tag# EOL
SeqLab
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
SeqLabC SubCall 'Hł' Tag# EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
END
SeqLabC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
TagDown
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
'( This Processor does not support Multiple Parts with Work Fixture Offsets )' EOL
'( Only one part is being processed )' EOL
ELSE
EachPart
SeqLabC SubCall 'Hł' Tag# EOL
NextPart
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
TagDown
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
TagDown
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

NextVector: {only called for this feat a line}
IF NOT LastFeat? AND CutterRadiusCompensation?
IF AbsValue?
SetFlag('2')
SetInc
END
IF NEXT LineFeat?
SetStatusOff
'I' NEXT EPX# 'J' NEXT EPY#
SetStatusOn
ELSE
IF NEXT ArcFeat?
IF NEXT ArcCW?
FORMAT(ArcJ#,3)
FORMAT(ArcI#,2)
'I' NEXT ArcJ# 'J' NEXT ArcI#
ELSE
FORMAT(ArcJ#,2)
FORMAT(ArcI#,3)
'I' NEXT ArcJ# 'J' NEXT ArcI#
END
END
END
IF Flag?('2')
SetFlagF('2')
SetAbs
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC SubCall 'Hł' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC
DecelMove2
IF CutterRadiusCompensation?
IF AbsValue?
SetFlag('2')
SetInc
END
SetStatusOff
'I' EPX# 'J' EPY#
IF Flag?('2')
SetFlagF('2')
SetAbs
END
SetStatusOn
END
FeedRateC CRCOffsetC EOL
END
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC NextVector DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC NextVector FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC SubCall 'Hł' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
TagDown
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC SubCall 'Hł' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
' ' EOL
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
SetMaxFeed('400')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { NextVector AbsValue maintanance }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF UseComments?
ProgramComment$ ', ' Date$ ', ' Time$ EOL
END
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqLab Rapid CRCOff DrillOff AbsOrInc OpToolID EOL
SeqLabC IncValue Rapid 'G45X-0H48' EOL
SeqLabC IncValue 'G45Y-0H47' EOL
SeqLabC AbsOrInc Preset 'X0Y0' EOL
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
' ' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
SeqLabC
IF NOT LastTool?
PreTool
END
ToolChng EOL
DoPostScript
CheckPass
SeqLabC AbsOrInc Plane Rapid StrtPos Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC StrtPos EOL
END
SeqLabC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
SeqLabC OfstOff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
SeqLabC
END
SpinOff EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
' ' EOL

{Start new Operation}

DoOpComments
SeqLab PreTool ToolChng EOL
DoPostScript
CheckPass
SeqLabC AbsOrInc Plane Rapid StrtPos Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC StrtPos EOL
END
SeqLabC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC OfstOff EOL
SeqLabC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC AbsOrInc PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqLabC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLabC OfstOff EOL
SeqLabC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
SeqLabC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLabC AbsOrInc PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
SeqLabC CRCOffC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF RetractToCP1?
SeqLabC StrtPos EOL
END
IF CallMasterOp?
SeqLabC SubCall 'Hł' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
TagUp NewMasterTag
SeqLabC SubCall 'Hł' Tag# EOL
StartSub
ToolPath
SeqLabC EndSub EOL
SeqLabC 'G20' EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqLabC Rapid ZCP3C EOL
END
END
NextOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
SeqLabC OfstOff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EOL
CloseMP
SeqLabC
END
SpinOff EOL
DoEndOpPS
IF ProgStop?
SeqLabC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
IF FIRST ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
CloseMP
END
SeqLabC 'G28X0Y0' EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END</sub>