{Monarch by Danny Ball for Lordon Engr. 6/17/88}
{NegateZ and Table by WFG}
{'Z-' is up, 'Z+' is down}

{10/10/88}
{updated; Bendix Mon VMC75 M125.55 for Varec}
{deleted extra tool change and WFO call at beginning of tool}
{added EOR to end of prog and added 'D' toollendth offset to drilling}
{deleted G80's}
{changed format to preceding zeros}
{added 'G80' as first line of prog}
{Jim Radcliffe}

{5/15/90
Modified: Bendix 5 Mon VMC150 M133.55
For: Varec
Sequence numbers to have 3 places.
Move SpinOn line to after operation comments.
Fix; change EachPart & NextPart to EachRep & NextRep in Milling & Drilling sections.
Updated to .71.2 format, no nested subroutines.
Jim Radcliffe}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/9/91, Updated: Bendix 5 Mon VMC150 M133.72 to .80 format, JR}

{04/01/92
Modified: Bendix 5 Mon VMC150 M133.80
For: Hughes EDSG
Changed all formats from carrot to decimal point in the form, per request.
Added 'G80' ToolChng line before the home and firsthome commands to retract before going home.
Changed the Coolon in the form from M8 to M7.
Changed the order of the startup code to: G90
Sxxx M03
Txx Dxx M06
G86 XxxxYxxxZxxxRxxxFxxxM07
Kim Michelman}

{5/27/92
Modified: Bendix 5 Mon VMC150 M133.80.1
For: Hughes EDSG
Changed the Format#6 for ClearancePlane2# to decimal instead of carrot.
Changed the 'X', 'Y' and 'Z' format in the form to force a '0' if no output,
to avoid getting a variable with just a decimal.
Added StrtPos to the cycle line in Drilling.
Kim Michelman}

{6/17/92
Modified: Bendix 5 Mon VMC150 M133.80.2
For: Hughes EDSG
Changed SpinOn to only be output after calling a ToolOfst ToolChng together on a line.
Forced FeedEnt on the cycle line and the G86 line.
Removed ToolOfst from all lines, except the toolchange line.
Kim Michelman}

{4/11/95
Initial: Bendix 5C VMC150 HUG M502.80.3
ForUser: Hughes Aircraft Quan Van
Modified per marked up readout:
Added ResetCRCNum to ToolPath.
Changed sub call to Q and repeat the call for number of repeats.
Changed sub ID fo DFS statement and put subs in front of main.
Deleted EndSub command
Added DFS statement for main program ID.
Removed blank line between subs.
Moved OpenSub for main to line before the 1st EOR
Bugs:
The speed codes are not coming out on the DOS version.
Updated:
To .81 format per Fanuc 6M NoNest M001.81.4
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane2#,2)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqC 'G86' StrtPos ZIn 'R'ClearancePlane2#
IF FeedEntry?
FeedEnt
ELSE
'F040'
END
EOL
RETURN

StartSub:
OpenSub
EOR EOL
'(DFS,' Program# ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
SeqC CallLab EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
SeqC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC CallLab EOL
IncWFO
NextWFO
ELSE
EachPart
SeqC CallLab EOL
NextPart
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat? AND AutoCycle?
SeqC RapidC MoveXYZC EOL
SeqC CRCOffC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
RETURN

DoLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

StdLine:
IF AutoCycle?
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
SeqC CRCOffC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
SeqC CRCOnC CRCOffsetC EOL
DoLine
END
END
ELSE
DoLine
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {NoNesting} {AutoCycles}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
Seq IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
ELSE
EntryMove
ToolPath2
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
SeqC CallLab EOL
ELSE
CutAutoCycle
END
ELSE
SeqC CallLab EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
IF Repeats? AND NOT FeedConnect?
EntryMove
END
SeqC CRCOnC CRCOffsetC EOL
ToolPath
END
RETURN

G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
SeqC FeedC StrtPosC EOL
ELSE
SeqC RapidC StrtPosC EOL
EntryMove
END
END
SeqC CRCOnC CRCOffsetC EOL
ToolPath
FinishSub1
END
NextRep
ELSE
NewProg
SubWarning
StdSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
NewProg
AutoCycPat {write pattern moves and main calls}
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
SeqC ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
CloseSub
END
RETURN

ZonlyRep:
NewProg
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
IF MultipleParts? {NoNesting}
SkipZ
ToolPath
UnSkipZ
FinishSub1
ELSE
SeqC CallLab EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
StartSub
SkipZ
SeqC CRCOnC CRCOffsetC EOL
ToolPath
UnSkipZ
FinishSub1
CloseSub
END
RETURN

SpeedCode:
IF Tap?
TABLE(2,SpeedRPM#,1)
ELSE
TABLE(1,SpeedRPM#,1)
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
Plane {no output}
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
NegateZ
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
OpenSub
EOR EOL
'(DFS,' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq 'G80' EOL
Plane {no output}
DoOpComments
DoPostScript
SeqC AbsOrInc EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC OpToolID ToolOfst ToolChng EOL
SeqC SpeedCode SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC 'G80' ToolChng EOL
SeqC Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
SeqC AbsOrInc EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC OpToolID ToolOfst ToolChng EOL
SeqC SpeedCode SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc EOL
Seq Rapid StrtPos SpeedCode EOL
ELSE
{Start new Operation}

GetStartOfSameTool
Seq Rapid StrtPos SpeedCode EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC 'G86' StrtPos ZIn 'R'ClearancePlane2#
IF FeedEntry?
FeedEnt
ELSE
'F040'
END
IF SameTool?
IF LAST ProgStop?
CoolOn EOL
SeqC 'G75' EOL
ELSE
IF CoolOff?
IF LAST NOT CoolOff?
CoolOff
END
ELSE
IF LAST CoolOff?
CoolOn
END
END
EOL
END
ELSE
CoolOn EOL
SeqC 'G75' EOL
END
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
SeqC CRCOffC EOL
ELSE
IF Drilling?
IF Repeats?
IF MultipleParts?
EachRep
ELSE
NewProg
StdSub
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
END
GetCycle
SeqC Cycle StrtPos RLevel ZDepth FeedEnt
IF SameTool?
IF LAST ProgStop?
CoolOn
ELSE
IF CoolOff?
IF LAST NOT CoolOff?
CoolOff
END
ELSE
IF LAST CoolOff?
CoolOn
END
END
END
ELSE
CoolOn
END
EOL
TrackZNO# SPZ# {.81}
ToolPath
IF Repeats?
IF MultipleParts?
NextRep
ELSE
FinishSubG92
END
END
SeqC Rapid ZCP3 EOL
END
END
NextOp

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC 'G80' ToolChng EOL
SeqC FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END