{Monarch by Danny Ball for Lordon Engr. 6/17/88}
{NegateZ and Table by WFG}
{'Z-' is up, 'Z+' is down}

{10/10/88}
{updated; Bendix Mon VMC75 M125.55 for Varec}
{deleted extra tool change and WFO call at beginning of tool}
{added EOR to end of prog and added 'D' toollendth offset to drilling}
{deleted G80's}
{changed format to preceding zeros}
{added 'G80' as first line of prog}
{Jim Radcliffe}

{5/15/90
Modified: Bendix 5 Mon VMC150 M133.55
For: Varec
Sequence numbers to have 3 places.
Move SpinOn line to after operation comments.
Fix; change EachPart & NextPart to EachRep & NextRep in Milling & Drilling sections.
Updated to .71.2 format, no nested subroutines.
Jim Radcliffe}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/9/91, Updated: Bendix 5 Mon VMC150 M133.72 to .80 format, JR}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '000^####'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(ClearancePlane2#,6)

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
SeqC 'G86R' ClearancePlane2# ZIn
IF FeedEntry?
IF SameTool? OR Repeats?
FeedEntC
ELSE
FeedEnt
END
ELSE
'F040'
END
EOL
RETURN

StartSub:
OpenSub
' ' EOL
EOR EOL
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SubWarning
SeqC '(CLS,' Program# ',' Repeats# ')' EOL
StartSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
SeqC RapidC ZCP3C EOL
END
SeqC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC '(CLS,' Program# ',1)' EOL
IncWFO
NextWFO
ELSE
SeqC '(CLS,' Program# ',' Parts# ')' EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath2: {NoNesting} {AutoCycles}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC RapidC MoveXYZC EOL
SeqC CRCOffC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
SeqC CRCOffC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
SeqC CRCOnC CRCOffsetC EOL
StdLine
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
Seq IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC RapidC PRIME ZCP2 EOL
END
NextRep
SeqC AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
IF AutoCycle?
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
SeqC '(CLS,' Program# ',1)' EOL
ELSE
CutAutoCycle
END
ELSE
SeqC '(CLS,' Program# ',1)' EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC RapidC MoveXYZC EOL
SeqC CRCOffC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
SeqC CRCOffC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
SeqC CRCOnC CRCOffsetC EOL
StdLine
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
IF Repeats? AND NOT FeedConnect?
EntryMove
END
SeqC CRCOnC CRCOffsetC EOL
ToolPath
END
RETURN

G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF NOT FirstCycle?
IF FeedConnect?
SeqC FeedC StrtPos EOL
ELSE
SeqC RapidC StrtPos EOL
EntryMove
END
END
SeqC CRCOnC CRCOffsetC EOL
ToolPath
FinishSub1
END
NextRep
ELSE
NewProg
StdSub
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
NewProg
AutoCycPat {write pattern moves and main calls}
StartSub
SaveSubStatus {save tool position}
SetSRXYtoSP
SeqC IncValue EOL
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
SeqC ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC RapidC PRIME ZCP2 EOL
END
NextRep
SeqC AbsOrInc RapidC ZCP2 EOL
SetSRSubXY {restore tool position}
SetSRSubMove
SeqC EndSub EOL
CloseSub
END
RETURN

ZonlyRep:
NewProg
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
IF MultipleParts? {NoNesting}
SkipZ
ToolPath
FinishSub1
ELSE
SeqC '(CLS,' Program# ',1)' EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
StartSub
SkipZ
SeqC CRCOnC CRCOffsetC EOL
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
END
RETURN

SpeedCode:
IF Tap?
TABLE(2,SpeedRPM#,1)
ELSE
TABLE(1,SpeedRPM#,1)
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
Plane {no output}
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
NegateZ
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq 'G80' EOL
Plane {no output}
DoOpComments
DoPostScript
SeqC AbsOrInc SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid StrtPos OpToolID ToolChng SpeedCode EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
SeqC AbsOrInc SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Seq Rapid StrtPos OpToolID ToolChng SpeedCode EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc SpinOn EOL
Seq Rapid StrtPos SpeedCode EOL
ELSE
{Start new Operation}

GetStartOfSameTool
Seq Rapid StrtPos SpeedCode EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC 'G86R' ClearancePlane2# ZIn
IF FeedEntry?
IF SameTool? OR Repeats?
FeedEntC
ELSE
FeedEnt
END
ELSE
'F040'
END
IF SameTool?
IF LAST ProgStop?
ToolOfst CoolOn EOL
SeqC 'G75' EOL
ELSE
IF NewToolOffset?
ToolOfst
END
IF CoolOff?
IF LAST NOT CoolOff?
CoolOff
END
ELSE
IF LAST CoolOff?
CoolOn
END
END
EOL
END
ELSE
ToolOfst CoolOn EOL
SeqC 'G75' EOL
END
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqC RapidC ZCP3C EOL
SeqC CRCOffC EOL
ELSE
IF Drilling?
IF Repeats?
IF MultipleParts?
EachRep
ELSE
NewProg
SeqC '(CLS,' Program# ',' Repeats# ')' EOL
OpenSub
' ' EOL
EOR EOL
SubID EOL
DoSubComment
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
END
GetCycle
SeqC Cycle RLevel ZDepth FeedEnt
IF SameTool?
IF LAST ProgStop?
ToolOfst CoolOn EOL
ELSE
IF NewToolOffset?
ToolOfst
END
IF CoolOff?
IF LAST NOT CoolOff?
CoolOff
END
ELSE
IF LAST CoolOff?
CoolOn
END
END
EOL
END
ELSE
ToolOfst CoolOn EOL
END
ToolPath
IF Repeats?
IF MultipleParts?
NextRep
ELSE
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
END
END
SeqC Rapid ZCP3 EOL
END
END
NextOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END