{Change Comments ***********************************************************}

{6/17/88,
Created: Bendix Mon VMC75 M125.54
For: Lordon
Added NegateZ and Table.
'Z-' is up, 'Z+' is down
DWB}

{10/10/88,
Modified: Bendix Mon VMC75 M125.55
For: Lordon
Deleted extra ToolChng and WFO call at FirstOperation and NewTool.
Added Tool Comment to First line of FirstOperation and NewTool.
Added EOR to end of Prog
Added 'D' ToolLength Offset to Drilling.
Deleted all literal 'G80'.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/29/91,
Modified: Bendix 5C Mon VMC75 M125.57
For: Gibbs & Associates
Updated to new 4.0 Version per Fanuc 6M M001.80
DWB}

{3/4/92
Modified: Bendix 5C Mon VMC75 M125.79
For: Hughes TTSG
Changes made by request.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Deleted EntryMove sub and all occurances thereof.
Changed Coolant On to M07, [Mist Coolant] on Compost Commands 3 dialog.
Customer agrees to use M08 in Operation PostScript Dialog when needed.
Changed SpeedC to SpeedCode at SameTool.
Added IF FirstFeat? and ZMove? condition for Ramp-In Pocketing at ToolPath LineFeat.
Outputs SeqC FeedC MoveXYZC FeedEntC EOL instead of call to StdLine Sub.
Kim Michelman}

{2/28/95
Updated: Bendix 5C Mon VMC75 M125.81.1
Renamed: Bendix 5C Mon VMC75 M575.81.1
Renamed because M125 belongs to Lordon Engineering
For: Hughes T&SSG
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Bill Jordon of Hughes T&SSG.
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Changed FeedRateC to FeedEntC for FIFO Exit Moves.
Added CkCRC sub.
Moved code at start of IF Milling to CkCRC sub.
Added call to CkCRC sub at IF Milling.
Does not support 4.2 CRCOnC.
Changed MoveSXYC to MoveSXYZC for variable Drill Depths at ToolPath PointFeat.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
Added EntryMove sub back in.
Moved code at G92Sub sub and start of IF Milling to EntryMove sub.
Added call to EntryMove sub at G92Sub sub and IF Milling.
Moved ToolComment$ from FirstOperation and NewTool to DoOpComments.
Moved SpinOn from AbsOrInc block to StrtPos block at FirstOperation.
Added ToolChng block at FirstOperation, NewTool and end of Prog.
This raises Spindle to FullUp position.
Added ToolChangeAtHome at FirstOperation, NewTool and end of Prog.
Moved OpToolID ToolChng from StrtPos block to block prior at FirstOperation and NewTool.
Moved output of ZCP3 from IF Milling and IF Drilling to SameTool.
Added LAST modifier as needed.
Customer requested that move to ZCP3 be output for SameTool situations only.
ToolChng situations require M06 to raise Spindle to FullUp position.
Deleted IncValue OfstOff 2 places at SameTool.
Changed OfstOn to ToolOfst 2 places at SameTool.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane2#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF SameTool?
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
ELSE
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
'G86R' ClearancePlane2# ZIn
IF Flag?('1') { Set at IF Milling }
IF FeedEntry?
IF SameTool? OR Repeats?
FeedEntC
ELSE
FeedEnt
END
ELSE
'F20.'
END
END
RETURN

StartSub:
OpenSub
' ' EOL
EOR EOL
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC '(CLS,' Program# ',' Repeats# ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC '(CLS,' Program# ',1)' EOL
IncWFO
NextWFO
ELSE
SeqC '(CLS,' Program# ',' Parts# ')' EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { Called from IF Milling }
IF CutterRadiusCompensation?
SeqC CRCOnC CRCOffsetC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC '(CLS,' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
SeqC MoveSXYC EOL
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF AutoCycle?
SeqC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF FirstFeat? AND ZMove? { Assumes Pocketing with Ramp-In }
SeqC FeedC MoveXYZC FeedEntC EOL
ELSE
StdLine
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
AutoCycCutSub2
AutoCycPat
ELSE
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC EntryMove EOL
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(CLS,' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC '(CLS,' Program# ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
Plane {no output}
CheckPass
RETURN

SpeedCode:
IF Tap?
TABLE(2,SpeedRPM#,1)
ELSE
TABLE(1,SpeedRPM#,1)
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
NegateZ
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane {no output}
Seq AbsOrInc EOL
DoOpComments
DoPostScript
SeqC ToolChng EOL { Retract Spindle to FullUp Position }
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
SeqC OpToolID ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid StrtPos SpinOn SpeedCode EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC ToolChng EOL { Retract Spindle to FullUp Position }
SeqC CRCOffC EOL
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
Seq OpToolID ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid StrtPos SpinOn SpeedCode EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
IF LAST Milling?
IF LAST AutoCycle?
SeqC ZCP3C EOL
ELSE
IF LAST FIFO? {.81}
SeqC FeedC LAST ZCP3C LAST FeedEntC EOL
ELSE
SeqC RapidC LAST ZCP3C EOL
END
END
ELSE
SeqC Rapid LAST ZCP3 EOL
END
SeqC CRCOffC EOL
DoEndOpPS
IF LAST ProgStop?
SeqC ToolChng EOL { Retract Spindle to FullUp Position }
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos SpeedCode SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC ToolChng EOL { Retract Spindle to FullUp Position }

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos SpeedCode EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos SpeedCode EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SetFlag('1')
SeqC EntryMove
SetFlagF('1')
IF NOT SameTool?
ToolOfst CoolOn EOL
SeqC 'G75' { 360Ą Arcs }
END
EOL
CkCRC
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
ELSE
IF Drilling?
IF Repeats?
IF MultipleParts?
EachPart
ELSE
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
END
GetCycle
SeqC Cycle RLevel ZDepth FeedEnt
IF NOT SameTool?
ToolOfst CoolOn
END
EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
IF MultipleParts?
NextPart
ELSE
FinishSubG92
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC ToolChng EOL { Retract Spindle to FullUp Position }
SeqC CRCOffC EOL
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END