{Prog Comments ****}

{
10/21/94 [cwh]
M689.82

Updated to new post prog format.

11/29/94 [ws]
Cin Acr A2100 M689.82.02 ( from M689.82.01 )

Modified so 'W' value posted on all drill lines based on "W = zretract - top surface"
Modified drilling 'R' value to be top surface via CalcZSurf#

11/30/94 [ws]
Cin Acr A2100 M689.82.03 ( from M689.82.02 )

Modified G80 line to include a 'R' value where R = zretract.

1/3/95 [ws]
Cin Acr A2100 M689.82.04 ( from M689.82.03 )

Modified so 'Z' value for drilling is calculated as "Z = Tip Depth - Top Surface"
Modified so when using Post Script command for coolant change coolant reset back to the original

2/15/95 [ws]
Cin Acr A2100 M689.82.05 ( from M689.82.04 )

Modified so output H word is not on a line by itself. (affects how MP NC code is output)
}

{
Format: Cin Acr 850SX Sabre C689.82.06
5/23/95
Upgraded to C Style Adv Mill post
Added functions to make all rotations incremental in a CW direction
Added functions to handle clamps if rotary motion
TH}

{ 8/29/95 - Updated to .10 format - TH}

{9/15/95 - Updated to include rigid tap changes made to M style post. - TH}

{
Format: Cin Acr 850SX Sabre C689.10.02
10/24/95
Added MSG, to DoCSWFOComment
TH}

{1/17/96, Updated .10 to .11 version, MPK}
{3/22/96,
Initial: Cin Acr 850SX Sabre C689.11
Created: Cin Acr 850SX Sabre CXXX.11
Put AbsOrInc at beginning of FormatArc sub on its own line (850SX control gave an error for
helixes otherwise, added M60 before EOP at program end. MPK}
{3/25/96,
Initial: Cin Acr 850SX Sabre C966.11
Created: Cin Acr 850SX Sabre C966.12
Undid previous move of AbsOrInc on FormatArc sub.
Tested ZOnlyRepAutoCycle, incremented # to .12, removed all RestoreAbsOrInc, added RestoreAbsOrInc
before Return in ToolPath. Changed position of DoAbsOrInc as per Fanuc 6M M001.12, MPK}
{4/22/96,
Initial: Cin Acr 850SX [D&H] C966.12
Created: Cin Acr 850SX [D&H] C966.12.1
Added a move to home before first tool call, added M26 (Z full up) before all moves to home, corrected OpenMP
sub by adding two lines to output SP, spindle speed, and coolant on for equally spaced multiple parts, removed move to
home at end of program, removed M52 at end of program, MPK}
{5/20/96.
Initial: Cin Acr 850SX [D&H] C966.12.1
Created: Cin Acr 850SX [D&H] C966.12.2
Eliminated tagging from post, now uses Program# instead. Changed remaining SubCall and EndSub commands to
literals of the CMI commmands. Post formerly did not do multiple parts, One Tool all Parts, full up; added support for
this by adding M26 and StrtPos at the end of G92 Mulitple parts subs in the case of equally spaced offsets and M26
with StrtPos after the WFO call for work fixture offsets. IMPORTANT: Multiple parts only works with
workfixture offsets if WFOCS? is true. MPK}
{7/3/96,
Added NotSameToolWFO to FirstOp3b, deleted call to NotSameToolWFO in NoMPs, in NotSameToolWFO
changed change 'H' NewWFO# to CSWFO when IF CahngeCS? is false, put DoCSWFOComment after CSWFO
call in NotSameToolWFO, deleted sequence label before CSWFO in NotSameToolWFO when IF CSWFO is true, MPK}

{7/16/96,
Initial: Cin Acr 850SX [D&H] C966.12.3
Created: Cin Acr 850SX [D&H] C966.12.4
Added ResetCool To DoCool sub and added AND NOT CoolOff? to IF ThruSpin? boolean, MPK}

{2/10/97,
Initial: Cin Acr 850SX [D&H] C966.12.4
Created: Cin Acr 850SX [D&H] C966.12.5
Formatted FeedTapIPR# with format #4, MPK}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '##.##;0'
#7 = '0000'
#8 = '+####.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CP1LessCP2#,4)
FORMAT(ADD#,4)
FORMAT(SUB#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(CalcZSurf#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(ToolDiameter#,4)
FORMAT(Repeats#,5)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(HelixPitch#,8)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(CSOffsetA#,8)
FORMAT(CSOffsetB#,8)
FORMAT(TrackZNO#,4)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'H' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'H' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A'
IF LessThan? SUB# LAST CSOffsetA# CSOffsetA# NUM#('0')
ADD# NUM#('360') SUB# LAST CSOffsetA# CSOffsetA#
ELSE
SUB# LAST CSOffsetA# CSOffsetA#
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B'
IF LessThan? SUB# LAST CSOffsetB# CSOffsetB# NUM#('0')
ADD# NUM#('360') SUB# LAST CSOffsetB# CSOffsetB#
ELSE
SUB# LAST CSOffsetB# CSOffsetB#
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'(MSG, CS#' CS# ' - ' CSComment$ ' )' EOL
'(MSG, ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

DoCoolOn:
ResetCool
IF ThruSpin? AND NOT CoolOff?
'M27'
ELSE
CoolOn
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
ResetCool
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'(DFS,L' Program# ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'G10=[T2]V0' EOL {sets temporary register #2 to 0}
SeqLabC 'Q' Program# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Program# ')' EOL {call subroutine}
SeqLabC 'G10=[T2]V[T2]+1' EOL {increment register #2 by 1}
SeqLabC 'G11E[T2]=' Repeats# 'L' Program# '2' EOL {if register #2 is equal to number of repeats then jump to branch label 2}
SeqLabC 'G11L-' Program# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Program# '2' EOL {branch label 2}
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
{
IF Flag?('1') AND AbsoluteMoves?
IncValue
SetFlag('2')
END
}
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
{
IF Flag?('2')
AbsValue EOL
END
}
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
{SeqLabC SetWFO EOL}
IF Flag?('21') {set MPallTools1P } {FirstOp1 code}
DoOpComments
DoPostScript
':?' Plane 'G70' AbsOrInc Rapid 'T' Tool# ToolChng EOL { Inch }
END
IF Flag?('20') {set in both MPallTools1P and MP1ToollAllP}
SeqLabC Rapid StrtPos ZCP1 Speed SpinOn SetWFO EOL
SeqLabC DoCoolOn EOL
IF NOT Flag?('21')
SetFlagF('20')
END
ELSE
SeqLabC Rapid StrtPos ZCP1 Speed SpinOn SetWFO EOL
END
SeqLabC '(CLS,L' Program# ')' EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqLabC Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
SeqLabC 'G10=[T1]V0' EOL {sets temporary register #1 to 0}
SeqLabC 'Q' Program# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Program# ')' EOL {call subroutine}
SeqLabC 'G10=[T1]V[T1]+1' EOL {increment register #1 by 1}
SeqLabC 'G11E[T1]=' Parts# 'L' Program# '2' EOL {if register #1 is equal to number of parts then jump to branch label 2}
SeqLabC 'G11L-' Program# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Program# '2' EOL {branch label 2}
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqLabC '(ENS)' EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLabC CalcCSWFO EOL
IF GreaterThan? PartNum# Num#('1')
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL {sends spindle full up}
SeqLabC StrtPos EOL
END
END
SeqLabC '(CLS,L' CSSubID# ')' EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLabC CalcCSWFO EOL
IF GreaterThan? PartNum# Num#('1')
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL {sends spindle full up}
SeqLabC StrtPos EOL
END
END
SeqLabC '(CLS,L' CSSubID# ')' EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqLabC '(ENS)' EOL
CloseSub
{SeqLabC WFO1 EOL}
ELSE
SeqLabC Preset ShiftPC EOL
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL
SeqLabC StrtPos EOL
END
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLabC '(ENS)' EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

RestoreAbs:
IF AbsoluteMoves? AND NOT AbsValue?
AbsValue
END
RETURN

ckHMove:
SetStatusOff
SetFlagF('9')
IF YZPlane?
IF NotEqual? SUB# SPY# ArcI# SUB# ArcI# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPX# ArcI# SUB# ArcI# EPX#
SetFlag('9')
END
END
SetStatusOn
RETURN

ckVMove:
SetStatusOff
SetFlagF('9')
IF XYPlane?
IF NotEqual? SUB# SPY# ArcJ# SUB# ArcJ# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPZ# ArcJ# SUB# ArcJ# EPZ#
SetFlag('9')
END
END
SetStatusOn
RETURN

ckMove:
IF NOT FullArc?
IF XYPlane? AND NOT ZMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT YMove?
ckHMove
END
END
ELSE
IF XZPlane? AND NOT YMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
ELSE
IF YZPlane? AND NOT XMove?
IF NOT YMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
END
END
END
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ ArcIJ 'K' HelixPitch#
ELSE
MoveX MoveY ArcIJ
END
ELSE
{ ??? what about incr subs here ??? }
IF XZPlane?
IF YMove?
MoveX MoveY MoveZ ArcIJ 'J' HelixPitch#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveX MoveY MoveZ ArcIJ 'I' HelixPitch#
ELSE
MoveY MoveZ ArcIJ
END
END
{ ??? }
END
RETURN

CkCRC:
IF LastFeat? { Exit Length Feature }
CRCOffC
ELSE
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
END
RETURN

StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYC MoveZC FeedRateC EOL { CRCOffsetC }
RestoreAbsOrInc
DecelMove2
END
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYC MoveZC DecelFeed EOL { CRCOffsetC }
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc FeedC CkCRC MoveXYC MoveZC FeedRateC EOL { CRCOffsetC }
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS,L' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Drilling?
IF SPXMove? OR SPYMove? OR SPZMove?
SeqLabC MoveSXYZC
IF RetractToCP1?
IF NotEqual? SUB# ClearancePlane1# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane1# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane1# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ClearancePlane2# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane2# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane2# CalcZSurf#
END
END
END
EOL
END
ELSE
SeqLabC MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
CRCOffC
END
SeqLabC DoAbsOrInc RapidC MoveXYC MoveZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC
END
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc RapidC MoveXYC MoveZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYC MoveZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
DoAbsOrInc
SeqLabC FeedC MoveXYC MoveZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
ckMove
IF Flag?('9')
SetFlagF('9')
StdLine
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC DoAbsOrInc FormatArc DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
IF LastFeat? AND CutterRadiusCompensation? AND NOT AutoCycle?
CRCOffC
IF NOT EmptyLine?
SeqLabC DoAbsOrInc LastFeatExtend EOL { ??? any zmoves ??? }
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC '(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,L' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC '(ENS)' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
SetFlagF('2')
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqLabC '(CLS,L' Program# ')' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC '(ENS)' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
SetFlagF('20') { used for Multiple Parts in OpenMP }
SetFlagF('21') { used for Multiple Parts in OpenMP }
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
SetMaxFeed('500')

IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('16')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to Non-WFO style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('16') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to Non-WFO style output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
ZonlyRep {rep change 1}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle

SeqLabC PlaneC
IF FIFO? AND Dwell? { Bore/Ream with Dwell }
'G89'
ELSE
Cycle
IF Tap?
'G95' { switch to Feed per Revolution units }
END
END
StrtPos
'Z' Sub# Add# ClearancePlane2# Zdepth# CalcZSurf# { Z = tip depth - Top Surface}
'R' CalcZSurf#
IF RetractToCP1?
IF NotEqual? SUB# ClearancePlane1# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane1# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane1# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ClearancePlane2# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane2# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane2# CalcZSurf#
END
END
END
Peck
IF Peck?
FeedEnt
IF PeckChipBreaker?
'J0'
ELSE
'J1'
END
ELSE
IF RigidTap?
'F' FeedTapIPR#('1') Speed SpinOn 'J1'
ELSE
IF Tap?
'F' FeedTapIPR#('1')
ELSE
FeedEnt
END
END
END
EOL

IF CallMasterOp?
SeqLabC '(CLS,L' CallMasterNum# ')' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC '(CLS,L' Program# ')' EOL
StartSub
ToolPath
SeqLabC '(ENS)' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC DrillOff
IF RigidTap?
'J0' EOL
SeqLabC 'G94' 'F1.'
ELSE
IF RetractToCP1?
'R' ClearancePlane1#
ELSE
'R' ClearancePlane2#
END
IF Tap?
EOL
SeqLabC 'G94' 'F1.'
END
END
EOL
IF Repeats?
FinishSubG92
END
SeqLabC Rapid ZCP3C EOL
END
END
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
SetFlagF('2')
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
CSWFO EOL
DoCSWFOComment
ELSE
SeqLabC CSWFO EOL
END
ClearCSOffset
ELSE
IF NeedWFO1?
'H' NewWFO#
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqLabC CSWFO EOL
END
ClearCSOffset
END
RETURN

ChkABMove:
IF AChange? OR BChange?
IncValue
END
RETURN

ChkClamp:
IF AChange? OR BChange?
'M10'
END
RETURN

InitOp:
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SetProgNum('0')
RETURN

FirstOp1:
DoOpComments
DoPostScript
':?' Plane 'G70' AbsOrInc Rapid EOL
IF ToolChangeAtHome?
SeqLabC 'M26' Home EOL
END
SeqLabC 'T' Tool# ToolChng EOL { Inch }
RETURN

FirstOp2:
CheckPass
RETURN

FirstOp3:
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

FirstOp3a: {can't XY position before WFO}
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

FirstOp3b:
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs Rapid StrtPos ZCP1 Speed SpinOn NotSameToolWFO EOL
SeqLabC DoCoolOn EOL
RETURN

NewToolOp1:
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC 'M26' EOL
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
':?' Plane 'G70' AbsOrInc Rapid 'T' Tool# ToolChng EOL { Inch }
RETURN

NewToolOp4:
CheckPass
RETURN

NewToolOp5:
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs PlaneC Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

NewToolOp5a:
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs PlaneC Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

NewToolOp5b:
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
SeqLabC RestoreAbs PlaneC Rapid StrtPos ZCP1 Speed SpinOn NotSameToolWFO EOL
SeqLabC DoCoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
{ ??? due full up here ??? }
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC ChkABMove CSAngleAC CSAngleBC ChkClamp EOL
IF LAST ProgStop?
SeqLabC RestoreAbs PlaneC Rapid StrtPos ZCP1 Speed SpinOn EOL
SeqLabC DoCoolOn EOL
ELSE
IF NewToolOffset? OR ChangeCS?
SeqLabC RestoreAbs PlaneC Rapid StrtPos ZCP1 SpeedC EOL
ELSE
SeqLabC RestoreAbs PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC DoCoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
DoEndOpPS
IF NotEqual? CSOffsetA# Num#('0')
SeqLabC IncValue
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
'M10' EOL

SeqLabC AbsValue Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
ELSE
IF NotEqual? CSOffsetB# Num#('0')
SeqLabC IncValue
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
'M10' EOL

SeqLabC AbsValue Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC 'M60' EOL
SeqLabC EOP EOL { Unload Last Tool }
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
EOR EOL
Close
ReTag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
{FirstOp1}
FirstOp2
{FirstOp3}
SetFlag('20') {Does FirstOp3 stuff in OpenMP}
SetFlag('21') { Does FirstOp1 stuff in OpenMP}
OpenMP
SetFlagF('20')
SetFlagF('21')
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
{FirstOp3}
SetFlag('20') {Does FirstOp3 Stuff in OpenMP}
OpenMP
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
{NewToolOp5}
SetFlag('20') {Does NewToolOp5 Stuff in OpenMP}
OpenMP
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
{FirstOp3a}
SetFlag('20') {Does FirstOp3a Stuff in OpenMP}
OpenMP
SeqLabC StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
{NewToolOp5a}
SetFlag('20') {Does NewToolOp5a Stuff in OpenMP}
OpenMP
SeqLabC StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3b
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5b
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END