{Change Comments ***********************************************************}

{12/2/92,
Copied & modified: LongHand [AbsOrInc] M001.81.1
For: Belgium [ABELSYS]
Machine: CMS Construczioni Speciali Model PF13-2R5
Control: OSAI A-B 8600MC Numerical Control
Changes made per manual and sample programs supplied by Beno"t DE HERTOGH at Belgium.
Unique output of program requires all positioning outside of cutting area to be in Absolute values,
and all motion within cutting area, including ZIn moves to be in Incremental. This is because the
control has a 'U' table and a 'V' table, and allows program to be used for either table.
Converted to Metric.
Changed 'Y' address to 'U'
Changed to Non-Decimal FORMATs.
Added Spaces to all addresses except 'N'.
Changed Comment output from Parenthesis to semi-colons.
Changed FORMAT for Program# from '#######0' to '000000'.
Added ADD# to FORMAT#5 for special handling of Tool#.
ADD# Tool# Num#('10') for use with 'U' table.
Added ClearancePlane1# and ClearancePlane2# to FORMAT#4.
Added ToolOffset# to FORMAT#5.
Added IncValue at EntryMove sub.
Added AbsValue at ExitMove sub.
Forcing FormatArc sub to output unconditional ArcR.
Deleted IncValue at AutoCycCutSub1, EntryMove sub takes care of this.
Modified to output Rapid/Feed code in front of CRCOff, AbsValue and IncValue.
Made major changes to output of Canned Drilling Cycles.
Deleted WorkFixtureOffsets.
Deleted ToolLengthOffsets.
Deleted all CoolOn and CoolOff commands.
Added literal 'G27', Automatic Speed in Corners, for start of Milling operations.
Added literal 'G29', Speed=0 in Corners, for end of Milling operations.
Deleted EOR at start and end of output.
Added massive literal code for output at start of output.
Deleted EOP at end of output, they requested SpinOff instead.
DWB}

{12/2/92,
Copied & modified: AB 8600MC U M536.81.2m
For: Belgium [ABELSYS]
Changed 'U' address and FORMAT to 'V' in Prog and Mach Spec.
DWB}

{1/20/93,
Modified: AB 8600MC V M537.81.2m
For: Belgium [ABELSYS]
Changes made per sample program supplied by Beno"t DE HERTOGH at Belgium.
Changed back to Decimal FORMATs.
Changed back to AbsOrInc output.
Deleted IncValue at EntryMove and XYZRep subs.
Added IncValue at AutoCycCutSub1 sub.
Deleted AbsValue at ExitMove, ExitMove2 and XYZRep subs.
Changed AbsValue to AbsOrInc at AutoCycCutSub2 sub.
Changed AbsValue to AbsOrInc at FirstOperation, NewTool, SameTool and MPLoop.
Deleted AutoCycle move to ZCP3 at ExitMove2 sub.
Changed ZCP3 to ZCP3C at ExitMove2 sub.
Deleted CRCOffsetC from StdLine.
Deleted SetMaxFeed('500') from setup and initializations
Added ZFeedOn and ZFeedOff subs for special SetMaxFeed values
Added semi-colon at end of prog following SpinOff command.
DWB}

{3/15/93,
Modified: AB 8600MC V M537.81.3m
For: Belgium [ABELSYS]
Changes made per sample program supplied by Beno"t DE HERTOGH at Belgium.
Changed FORMAT for Program# from '000000' to '0000000'.
Modified values of ZFeedOn and ZFeedOff subs.
Changed ArcR to ArcIJC at FormatArc sub.
Changed all occurances of Plane command to call GetPlane sub for special Plane output.
Changed ToolOffset# to ADD# ToolOffset# Num#('5').
Changed ProgramNameComment to ProgramComment at ProgID at start of output.
DWB}

{6/23/93
Modified: AB 8600MC V M537.81.4m
For: Belgium [ABELSYS]
Changes made per Beno"t DE Hertogh at Abelsys.
Updated to Version 4.1 per LongHand M001.81.3 Format.
Checked Use Absolute Arc Centers in Composts Booleans dialog.
Changed ArcIJC to ArcIJ at FormatArc.
Deleted SeqC from all comment blocks.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '#####.###;0'
#5 = '#######0'
#6 = '#.##;0.'
#7 = '#;'
#8 = '0000000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ADD#,5)
FORMAT(ToolOffset#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Tag#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(Program#,8) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

ZFeedOn:
IF Metric?
SetMaxFeed('6000')
ELSE
SetMaxFeed('236.22047244094')
END
RETURN

ZFeedOff:
IF Metric?
SetMaxFeed('20000')
ELSE
SetMaxFeed('787.40157480315')
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'; PART NO. ' Tag# EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'; CYCLE START' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
ZFeedOn
SeqC FeedC ZIn FeedEnt EOL
ZFeedOff
ELSE
SeqC RapidC ZIn EOL
END
RETURN

GetConnect:
IF FeedConnect?
FeedC
ELSE
RapidC
END
RETURN

ExitMove:
IF NOT FeedConnect?
SeqC
IF FIFO? { .81 }
FeedC
ELSE
IF NOT AutoCycle?
RapidC
END
END
CRCOffC PRIME ZCP2C
IF FIFO? { .81 }
ZFeedOn
FeedEntC
ZFeedOff
END
EOL
END
RETURN

ExitMove2:
IF FIFO? {.81}
ZFeedOn
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ZFeedOff
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC ArcIJ
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL {.80.01}
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets }
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
IF FIFO? {.81}
ZFeedOn
SeqC FeedC AbsOrInc ZCP2 FeedEntC EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
ZFeedOff
ELSE
SeqC RapidC AbsOrInc ZCP2 EOL
END
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
EachRep
IF NOT FirstCycle?
SeqC GetConnect CRCOffC StrtPosC EOL
END
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
IF ZshiftOnly?
EntryMove
END
ELSE
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
DoCycleComment
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF FirstCycle?
DoCycleComment
EntryMove
ELSE
IF NOT FeedConnect?
ExitMove
END
IF SPXMove? OR SPYMove?
SeqC GetConnect MoveSXYC EOL
END
DoCycleComment
IF NOT FeedConnect?
EntryMove
END
END
ToolPath
NextRep
AutoCycCutSub2
ReSetPass2 {restore for positioning moves}
NEXTFeat
RETURN

DrillStuff:
GetCycle
IF Dwell?
IF FIRO? OR FIFO?
SeqC ' TMR=' Dwell# EOL
END
END
SeqC
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
' R' ClearancePlane2#
IF RetractToCP1? {.81}
' R' ClearancePlane1#
END
ZFeedOn
ZDepth FeedEnt EOL
ZFeedOff
SeqC StrtPos EOL
TrackZNO# FIRST SPZ# {.81}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

GetPlane:
IF FirstOperation?
IF XYPlane?
SeqC '(DPI,X,V)' EOL
ELSE
IF XZPlane?
SeqC '(DPI,X,Z)' EOL
ELSE
IF YZPlane?
SeqC '(DPI,Z,V)' EOL
END
END
END
ELSE
IF XYPlane? AND LAST NOT XYPlane?
SeqC '(DPI,X,V)' EOL
ELSE
IF XZPlane? AND LAST NOT XZPlane?
SeqC '(DPI,X,Z)' EOL
ELSE
IF YZPlane? AND LAST NOT YZPlane?
SeqC '(DPI,Z,V)' EOL
END
END
END
END
Plane
RETURN

MasterSub:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE
IF ToolChangeAtHome?
SetHome
END
DoPartCycleComment
DoOpComments
Seq ' T' ADD# Tool# Num#('10') '.' ADD# ToolOffset# Num#('5') ToolChng EOL
DoPostScript
CheckPass
SeqC Rapid AbsOrInc StrtPos ' U0' EOL
SeqC Speed SpinOn EOL
SeqC ZCP1 EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE

{Finish off last Operation}

DoEndOpPS
IF ToolChangeAtHome?
SetAbs
LoadFeat
SUB# HomeX# CurOriginPosX#
SUB# HomeY# CurOriginPosY#
Num#('0') { Dummy Z }
SeqC MoveXY EOL
END
SeqC SpinOff EOL
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoPartCycleComment
DoOpComments
Seq ' T' ADD# Tool# Num#('10') '.' ADD# ToolOffset# Num#('5') ToolChng EOL
DoPostScript
CheckPass
GetPlane
SeqC Rapid AbsOrInc StrtPos ' U0' EOL
SeqC Speed SpinOn EOL
SeqC ZCP1 EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC ' M0' EOL

{Start new Operation}

GetStartOfSameTool
IF NewToolOffset?
SeqC ' T' ADD# Tool# Num#('10') '.' ADD# ToolOffset# Num#('5') EOL
END
GetPlane
SeqC Rapid AbsOrInc StrtPos EOL
SeqC SpeedC SpinOn EOL
SeqC ZCP1 EOL
ELSE
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC ' T' ADD# Tool# Num#('10') '.' ADD# ToolOffset# Num#('5') EOL
GetPlane
SeqC Rapid AbsOrInc StrtPos EOL
SeqC SpeedC EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
GetPlane
SeqC Rapid AbsOrInc StrtPos EOL
SeqC SpeedC EOL
END
END
END
END
END {common point for all operations}
ResetCRCNum {.72}
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF FirstOperation? OR NewTool?
SeqC ' G27' EOL { Automatic Speed in Corners }
';' EOL { Comment }
END
IF AutoCycle?
IF Repeats?
IF ZshiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
ELSE
NoRepAutoCycle
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
END
';' EOL { Comment }
IF LastOp? OR NEXT NewTool?
SeqC ' G29' EOL { Speed = 0 in Corner }
END
SeqC ExitMove2 EOL
ELSE
IF Drilling?
SeqC ZCP1C EOL
IF FirstOperation? OR NewTool?
';' EOL { Comment }
END
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC ' G80' EOL
';' EOL { Comment }
SeqC Rapid ZCP3 EOL
END
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SetAbs
LoadFeat
SUB# FIRST HomeX# CurOriginPosX#
SUB# FIRST HomeY# CurOriginPosY#
Num#('0') { Dummy Z }
SeqC MoveXY EOL
END
SeqC SpinOff EOL
IF ProgStop?
SeqC ' M0' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop EOL
END
END
';' EOL { Comment }
RETURN

MPLoop:
TagInit
IF AllToolsOnePart?
EachPart
TagInc
EachOp
MasterSub
NextOp
EndPartSub
NextPart
ELSE { OneToolAllParts }
Save# Num#('2') Recall# Num#('1')
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
EachPart
TagInc
EachOp
IF GTEqual? Operation# Recall# Num#('1')
IF LTEqual? Operation# Recall# Num#('2')
IF Equal? Operation# Recall# Num#('1')
IF NOT FirstPart?

{Finish off last Operation}

{DoEndOpPS}

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC AbsOrInc StrtPos ' U0' EOL
SeqC Speed SpinOn EOL
IF FullUp?
SeqC ZCP1 EOL
END
END
END
MasterSub
END
END
NextOp
NextPart
Save# Num#('1') ADD# Recall# Num#('2') Num#('1')
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbsOrInc
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('18000')
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
OpenSub
SeqC '(DIS,"' Program# 'V' { Display a Variable }
IF UseComments? AND ProgramComment?
' ' ProgramComment$
END
'")' EOL
';' EOL { Comment }
';' EOL
';' EOL
';' EOL
';' EOL
';' EOL
';' EOL
';' EOL
';' EOL
';' EOL
GetPlane
SeqC '(UAO,0)' EOL { Use Absolute Origin #0 }
SeqC '(UAO,2)' EOL { Use Absolute Origin #2 }
SeqC '(UCG,2,V-2600V,X-900X)' EOL { Define Graphics Display Field }
';' EOL
SeqC SpinOff EOL
SeqC ' M43' EOL { Work with both Tables }
SeqC ' M11' EOL { U Table Vacuum Off }
SeqC ' M12' EOL { V Table Vacuum Off }
SeqC ' M15' EOL { U Table Overpressure Off }
SeqC ' G29' EOL { Speed = 0 in Corner }
SetLineStrtChr('/')
SeqC ' M0' EOL { Synch with second Program }
SetLineStrtChr('')
SeqC ' M22' EOL { V Table Vacuum On }
';' EOL
IF UseComments?
IF ProgramNameComment?
'; PROGRAM: ' ProgramName$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' METERS' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
';' EOL
RestoreScale
IF MultipleParts?
IF WorkFixtureOffsets?
'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'Therefore, the output will be controlled by the following values that are' EOL
'already entered in Equally Spaced Offsets Edit Fields:' EOL
'X' PartShiftX# ' Y' PartShiftY# ' Z' PartShiftZ# EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL
END
Save# Num#('1') Num#('1')
EachOp
IF LastOp?
Save# Num#('3') Operation#
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END