{Change Comments ***********************************************************}

{6/18/93
Copied & modified: NTC TLV-510 Laser M343.81.4m
For: Quasar Ind.
Machine: NTC Laser
Control: TLM-610
Changed Tool Length Offset Label from 'A' to 'B' in Mach Specs Strings 2 dialog.
Deleted all support of Work Fixture Offsets in prog.
Changed FORMAT for Address '1' from '#0' to '#####.###;0' in Mach Specs Default Formats dialog.
Changed FORMAT for Address 'B' from '#####.###;0' to '#0' in Mach Specs Default Formats dialog.
Deleted literal 'M100 ' at ToolPath.
Cutting Condition Selection with piercing.
Changed literal 'M300' to 'M61' at FirstOperation.
Open Laser Shutter.
Changed all other occurances of literal 'M300' to 'M29'.
Changed all occurances of literal 'M310' to 'M29'.
Cancels Active M-Codes.
Replaced contents at EntryMove.
Replaced contents at FinishSub1.
Changed most of output between EachOp and NextOp in Main.
Added support of FeedRates in prog.
Deleted ProgID1 at FirstOperation.
DWB}

{10/19/93
Modified: NTC TLM-610 Laser M582.81.3m
For: 3 Dimensional Services
Changes made per Dave Krajci at 3 Dimensional Services.
Changed MoveXYC to MoveXYZC at ToolPath.
Customer reported that Post does not output ZMoves.
JR}

{2/23/94
Modified: NTC TLM-610 Laser M582.81.4m
For: 3 Dimensional Services
Versions: ncCad 4.32/ncCAM 4.32/ncPost 4.32.02/Compost 4.21.20
Changes made per Dave Krajci at 3 Dimensional Services.
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added FeedC MoveSZC at ToolPath PointFeat for Drilling.
Added RapidC DrillCP at ToolPath PointFeat for Drilling.
Changed FORMAT for Address F from '###^#0' to '####.##;0.' in Mach Spec Default Formats Dialog.
Customer reported that control hangs up when it encounters a move to current ZPos.
Added LoadFeat SPZ# to suppress block at EntryMove.
Changed ZIn to ZInC at EntryMove sub.
Changed ZCP2 to ZCP2C at AutoCycCutSub2.
Added LoadFeat CP3# to suppress block at IF Milling OR IF Drilling of Main Loop.
Modified FirstOperation to output Block Number on block by itself at start of output.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
LoadFeat Num#('0') Num#('0') SPZ#
IF ZMove?
IF FeedEntry?
SeqC FeedC ZInC EOL
SetStatusRapid { Force FeedC at FirstFeat }
ELSE
SeqC RapidC ZInC EOL
END
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
{ Not Needed }
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SkipZ
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
UnSkipZ
RETURN

OpenMP: { EquallySpacedOffsets Only }
IF WorkFixtureOffsets?
' ' EOL
' ( Note - Post does not support MultipleParts with WorkFixtureOffsets. )' EOL
' ( Please change to EquallySpacedOffsets. )' EOL
' ' EOL
ELSE
NewProg
SeqC SubCall CallLab RepLab Parts EOL
StartSub
END
RETURN

CloseMP:
IF NOT WorkFixtureOffsets?
SkipZ
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
UnSkipZ
END
RETURN

CkArcMove:
SetInc
SetStatusOff
IF GreaterThan? ArcI# Num#('-.0005')
IF LessThan? ArcI# Num#('.0005')
IF GreaterThan? ArcJ# Num#('-.0005')
IF LessThan? ArcJ# Num#('.0005')
SetFlag('1')
END
END
END
END
SetStatusOn
IF NOT AutoCycle?
SetAbsOrInc
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF XMove? OR YMove?
SeqC CkCRC FeedC MoveXYZC CRCOffsetC EOL
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYC EOL
SeqC FeedC MoveSZC EOL {.80.01}
SeqC ToolOfst EOL { Set Parameters for Power, Gas, etc. }
SeqC 'M29' EOL { Cancels Active M-Codes }
SeqC RapidC DrillCP EOL
END
ELSE
IF FirstFeat?
SeqC ToolOfst EOL { Set Parameters for Power, Gas, etc. }
END
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC FeedC MoveXYZC EOL
ELSE
StdLine
END
ELSE
IF ArcFeat?
SetFlagF('1')
CkArcMove
IF Flag?('1')
SetFlagF('1')
StdLine { Arc is too small }
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC FormatArc EOL
NEXTQuadrant
END
END
END
END
IF LastFeat?
SeqC CRCOffC EOL
SeqC 'M29' EOL { Cancels Active M-Codes }
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2C
ELSE
RapidC ZCP2C
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
{ Not Needed }
RETURN

ZonlyRep:
{ Not Needed }
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
SeqC PlaneC EOL { XYPlane no output }
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' METERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
Seq Plane ' ' EOL { XYPlane no output }
SeqC 'M61' EOL { Open Laser Shutter }
IF Milling?
SeqC FeedRate EOL
ELSE
SeqC FeedEnt EOL
END
SeqC 'M29' EOL { Cancels Active M-Codes }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC AbsOrInc EOL
SeqC Rapid 'Z100.' EOL
SeqC AbsOrInc Rapid 'X0.Y0.' EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

SeqC PlaneC EOL { XYPlane no output }
DoOpComments
DoPostScript
Seq 'M61' EOL { Open Laser Shutter }
IF Milling?
SeqC FeedRate EOL
ELSE
SeqC FeedEnt EOL
END
SeqC 'M29' EOL { Cancels Active M-Codes }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC AbsOrInc EOL
SeqC Rapid 'Z100.' EOL
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC 'M61' EOL { Open Laser Shutter }
IF Milling?
SeqC FeedRateC EOL
ELSE
SeqC FeedEntC EOL
END
SeqC 'M29' EOL { Cancels Active M-Codes }
SeqC AbsOrInc Rapid StrtPos EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc Rapid StrtPos EOL
END
END
END
END {common point for all operations}
IF Milling?
IF Repeats?
NewProg
G92Sub
ELSE {no repeat OPs}
Milling
END
IF NOT LastOp?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
ToolPath
IF Repeats?
FinishSubG92
END
IF NOT LastOp?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC RapidC ZCP3C EOL
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC AbsOrInc EOL
SeqC Rapid 'Z100.' EOL
SeqC AbsOrInc Rapid 'X0.Y0.' EOL
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END