{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{12/4/96,
Modified: LongHand M001.12b
Created: LongHand M001.12c
Added .14 Additions:
NOTE: These changes have not been compiled yet.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted Flag(1) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Deleted version comments.
Simplified ExitMove sub.
Deleted OpenMP and CloseMP commands.
Simplified EndPartSub sub.
Modified WorkFixtureOffset logic.
Added Flag(1) for WFOStuff at setup and initializations.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(1) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
DWB}

{3/13/97,
Modified: LongHand M001.12c
Created: LongHand M001.12d
Added TrackXNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added TrackYNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added IF FirstOperation? OR EquallySpacedOffsets? condition at MPallTools1P sub.
Post was not outputting WFOStuff for NewTool Operations during MP-ESO-OPAT condition.
Deleted IF WorkFixtureOffsets? condition at DoNewPart sub.
Post was not outputting WFOStuff for NewPart during MP-ESO-OTAP condition.
Deleted all occurances of TagInit, TagInc and Tag#.
Replaced with PartNum# for better WFO handling.
DWB}

{4/17/97,
Modified: LongHand M001.12d
Created: LongHand M001.12e
Added SetPass1 at OpGuts IF Milling AND IF AutoCycle.
This fixed problem with returning to FirstHome at end of prog when final Operation consisted of
NoRepAutoCycle or XYZRepAutoCycle types.
ZonlyRepAutoCycle type did not seem to create this problem.
DWB}

{7/15/97
Modified: LongHand M001.12e
Created: LongHand M001.12f
For: Gibbs & Associates
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncEDM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncMAT 4.21.19/ncPost 4.33.10/ComPost2 MSL 68K
Improved handling of MultipleParts OneToolAllParts Output.
Rewrote MPLoop sub.
Simplified logic for handling OneToolAllParts situations.
No more need to keep track of Current Tool FirstOp, CurrentOp and LastOp.
Only using Vars(1) and (2).
Var(3) and Flags(2) and (3) no longer needed.
Deleted Var(3), NextToolOp# at ProgStart.
Deleted Flags(2) and (3) at ProgStart.
Deleted DoParts sub.
No longer necessary.
Deleted GetToolFirstOp sub.
No longer necessary.
Deleted GetToolLastOP sub.
No longer necessary.
Changed Var(8) to Var(3), LongHand Pecking at DoPeck, DrillFeature and ProgStart.
Changes made per Fanuc 6M NoSubs M877.89.1:
Fixed bug during MultipleParts AllToolsOnePart Output.
Commented out NOT FirstPart call to InitOp at MPallTools1P.
Was causing ncPost to beep and issue a series of alerts at start of additional Parts.
Problem disappeared if output was aborted and restarted, second processing of output, or
processing of output after any other MultipleParts/NoMPs situations.
Added FirstPart AND FirstOperation condition for calling InitOp at MPLoop sub.
Fixed MultipleParts WorkFixtureOffset bug.
Rewrote MPLoop sub.
Changed EachPart/NextPart loop to EachWFO/NextWFO loop.
EachPart/NextPart loop was causing coordinates of additional Parts to be affected by any
values entered into invisible EquallySpacedOffsets Edit Fields.
Deleted BadMPWFOReport sub and calls to same.
Deleted output comment regarding MultipleParts WorkFixtureOffsets and values in
EquallySpacedOffsets Edit Fields.
Rewrote XYZRepAutoCycle sub.
No longer necessary to Track Tool between Parts.
Added RapidC Move to StrtPos and ZCP2C inside of EachRep/NextRep loop just prior to
EACHFeat/NEXTFeat Loop.
Deleted TrackNo# FORMULAs of Vars(4) through (6).
Added CRCOffC and call to ExitMove inside of EachRep/NextRep loop just after EACHFeat/NEXTFeat
Loop.
Added SetSRSubMove at end of AutoCycCutSub2.
Deleted Vars(6) and (7) at end of ToolPath.
Deleted Vars(4) through (7) at ProgStart.
DWB}

{8/7/97,
Modified: LongHand M001.12f
Created: LongHand M001.12g
Changed Flag(1) to Flag(2).
Final changes to correct MultipleParts AllToolsOnePart Output bug.
Placed IF ToolChangeAtHome? SetHome logic inside EachOp/IF FirstOperation?/NextOp loop at InitOp
sub.
Deleted InitOp calls at MPallTools1P, MP1ToollAllPfu, MP1ToollAllPXcp, NoMPs and MPLoop subs.
Added InitOp call following ProgStart call at Start of executable Prog, Top Level.
Other Fine Tuning Modifications.
Deleted OpenSub command at InitOp sub.
Deleted LoadFeat Home code at NewToolOp2 sub.
Changed MoveXY to PRIME Home at NewToolOp2 sub.
Moved WFOStuff call from SameToolOp3 sub to SameToolOp2 sub.
Deleted LoadFeat FirstHome code at End2 sub.
Changed MoveXY to PRIME FirstHome at End2 sub.
Deleted Post command at End3 sub.
DWB}

{10/18/97,
Modified: LongHand M001.12g
Created: LongHand M001.12h
For: Gibbs & Associates
Versions: Catalyst v4.21.03(mac)/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Added routines for Non-AutoCycle FeedConnect Repeats w/ ZMoves.
Routines needed to make sure that Tool clears floor of contour.
Added FlagF(3) at ProgStart.
Standard Initialization.
Added comparison bewteen FIRST SPZ# and final EPZ# at end of ToolPath.
Flag(3) set if Tool needs to move up to get to FIRST SPZ#.
Added Flag(3) test at ExitMove.
Flag(3) moves Tool up prior to StrtPos.
FlagF(3) leaves Tool at higher final EPZ#.
Also sets Flag(3) for EntryMove test to move Tool to ZIn following move to StrtPos.
Added Flag(3) EntryMove test at XYZRep.
Moves Tool to ZIn following move to StrtPos.
Added FlagF(3) at end of XYZRep.
Clears Flag(3) to avoid problems with future Operations.
DWB}

{11/12/97
Modified: LongHand M001.12h
Created: LongHand M001.12i
For: Gibbs & Associates
Versions: Catalyst v4.21.11(mac)/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Eliminated all considerations regarding Non-AutoCycle ZShifting FeedConnect Repeats with ZMove.
Fanuc 6M M001.89 does not raise Tool for safety clearance and neither should this post.
User is responsible for making sure Tool will clear or should select Entry/Exit Connect.
Deleted all related changes made on 10/18/97.
Added condition to test for NOT EmptyLine at EntryMove sub.
This suppresses FeedEntC only block in case ZEndPoint of Previous Repeat equals ZStartPoint of
Next Repeat.
Deleted Move to ZInC for Non-AutoCycle FeedConnect Repeats with ZMoves at ExitMove sub, see 12/9/93.
Added IF NOT NoZMoves? condition at XYZRep sub.
Calls EntryMove sub.
Deleted FeedEntC on FeedC MoveSXYC block for additional FeedConnect Repeats at XYZRep sub.
DWB}

{1/15/98
Modified: LongHand M001.12i
Created: LongHand M001.12j
For: Gibbs & Associates
Versions: Catalyst v3.35C/ComPost2 1.1b3
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Deleted SetSRSubMove at end of AutoCycCutSub2.
DWB}

{1/29/98
Updated: LongHand M001.12j
Created: LongHand M001.12k
Updated for Catalyst v3.35C per LongHand M001.12j Format.
Added Var(4) for conditional SpeedC test at ProgStart sub.
Added Var(5) for conditional CS# test at ProgStart sub.
Added Flag(1) for conditional ProgStop test at ProgStart sub.
DWB}

{4/6/98
Modified: LongHand M001.12k
Created: LongHand M001.15
For: Gibbs & Associates
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changed FORMAT#20 to FORMAT#9 at Testing Subroutines.
FORMATs must be in sequential numbering order in order to work correctly.
DWB}

{5/15/98,
Updated: LongHand M001.15
Created: Fanuc 6M LH MV83.16
For: Gibbs & Associates
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Update necessary to stay consistant with AdvancedMill Update.
Added AbsValueC, IncValueC and AbsOrIncC Procedures.
Simplifies readability of Prog.
Reduces redundancy of output.
Allows us to return to earlier versions
Improves upon earlier problem with incremental output of ShiftPC command at CloseMP while
allowing us to return to .85 OfstOff blocks.
AbsValueC called from AbsOrIncC.
IncValueC called from AbsOrIncC, DoAbsOrInc and DoDrillAbsOrInc.
IncValueC called for OfstOff Blocks at NewToolOp1, two places at SameToolOp1 and DoAbsOrInc.
AbsOrIncC called for ShiftPC Block at CloseMP.
AbsOrIncC called from DoAbsOrInc, DoDrillAbsOrInc and RestoreAbsOrInc.
AbsOrIncC called for Home Block at NewToolOp2.
AbsOrIncC called for FirstHome Block at End2.
Added CRCOffC at AutoCycCutSub2.
Corrects unique situation in ZonlyRepAutoCycle where one Operation is CRCLeft and LastFeat
is an ArcFeat followed by another Operation that is CRCRight.
CRCOffC did not get output at end of CRCLeft Operation and CRCOnC did not get output at start
of CRCRight Operation.
Oddly, CRCOnC only outputs if CRCOffC has been output, not if CRCSide changes.
6/18/98
Changed to Lowercase Procedure Names.
Added comments to all SetFlag, SetFlagF and IF Flag statements.
Changed literal 'G80' to DrillOff at end of IF Drilling.
Changed literal 'G80' to DrillOff at firstOp1 and newToolOp3.
To allow for change in FORM without having to recompile.
Changed SpeedC to Speed at for LAST ProgStop condition at sameToolOp3.
6/30/98
Deleted Gibbs System XYRepeat support.
Virtual only support ZShiftOnly Repeats.
Deleted CycleWarning procedure.
Added cutAutoCycle procedure.
Called for all AutoCycle Operations.
Supports NoRepeat and ZShiftOnly Repeats.
Replaces noRepAutoCycle and zonlyRepAutoCycle procedures
Deleted xYZRepAutoCycle procedure.
Changed XYZRep to ZOnlyRep.
Supports ZShiftOnly Repeats.
Moved LongDrillStuff from OpGuts to LongDrillStuff.
Rewrote OpGuts Procedure.
Deleted Drilling Repeats at IF Drilling.
Rewrote PostScript instructions at progStart.
7/22/98
Reverted back to Gibbs System XYRepeat support.
IF setup correctly, Virtual will support XShift and/or YShift Repeats for both Contour and
Patterns.
Rules for correct setup (as best as I understand at the moment).
Geometry CSGroup must be oriented to a plane that intersects CS#1 in a perpendicular direction.
Example, XZPlane and YZPlane, and any oriented rotation of either Plane around the XYPlane.
Any change in the ZPitch of the Origin will cause ZShiftOnly Repeat Operation.
Set Desired ZStep so that Operation will result in multiple passes.
NOTE: If correctly setup, ZStep would be misleading.
Step will be in line with depth axis of CSGroup.
Restored with slight modifications the xyRep Procedure.
Restored with slight modifications the xyRep Procedure.
Restored related code to OpGuts Procedure.
ZShiftOnly Contour Operations remain Full SepSub.
Any customer requesting G92 Style will require copying code from archives.
Deleted Deceleration from ToolPath LineFeat and ArcFeat.
There are plans to support this in the future through the use of Construction Tools in the
Virtual Process.
DWB}

{9/28/98,
Initial : Fanuc 6M LH MV83.16b
Created: Haas [HTP] NMU13.16
Customer: Hendry Telephone Prod., Pete Maxwell 805/968-5332 ext 334

>> Changes to match the output of: Haas LH HTP MU13.13 <<

Changes to "Form":

1. Under Spindle and Coolant, changed Spindle Off to M19.

Changes to "Prog":

1. Added Post Header Comment.
2. Added Tool List to initOp sub. Added FORMAT to TLNum#, TLDia#, and TLLength#.
3. Changes to firstOp1, 2, and 3 subs.
4. Changes to newToolOp1, 2, 3, 4, and 5 subs.
5. Changes to sameToolOp1 and 3 subs.
6. Changes to end1, 2, and 3 subs.
7. Changes to newPart3 subs.
8. Added G74 for Left Hand tapping in drillStuff sub.
9. Moved ResetCRCNum from opGuts to toolPath.
JHE}

{Prog Numeric Format Definitions **************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(TLDia#,4) {Added - JHE}
FORMAT(TLLength#,4) {Added - JHE}
FORMAT(Recall#,5)
FORMAT(PartNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(TLNum#,5) {Added - JHE}
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines ************************}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

wFO:
'G' NewWFO#
RETURN

wFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
wFO
END
ELSE
IF Flag?('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
SetWFO
ELSE
wFO
END
ELSE
wFO
END
END
END
END
SetFlagF('2') { Do not output WFO second time wFOStuff is called for MP-WFO-OTAP-ECP }
RETURN

resetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN

doPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' PartNum# ' )' EOL
END
RETURN

doCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# '; ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# '; ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
restoreScale
END
RETURN

pSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

pSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
pSInit
EachPS
SeqC PostScript EOL
pSStuff
NextPS
RETURN

doEndOpPS:
pSInit
EachEOPS
SeqC EndOpPS EOL
pSStuff
NextPS
RETURN

pRIMEZCP2:
PRIME ZCP2
RETURN

LoadpRIMEZCP2:
LoadFeat Num#('0') Num#('0') PRIME ClearancePlane2#
RETURN

entryMove:
IF FeedEntry?
SeqC FeedC ZInC
IF NOT EmptyLine? { Mostly for FeedConnect ZShiftOnly with ZMove }
FeedEntC
END
EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

exitMove:
IF NOT FeedConnect?
CRCOffC
IF FIFO?
FeedC pRIMEZCP2 FeedEntC
ELSE
RapidC pRIMEZCP2
END
END
RETURN

exitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

formatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

toolPath:
ResetCRCNum {Moved to here - JHE}
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC formatArc ArcFeedC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

autoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
entryMove
END
SeqC IncValue EOL
RETURN

autoCycCutSub2: {part 2}
SeqC AbsOrInc CRCOffC
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

milling:
entryMove
toolPath
RETURN

xyRep:
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC EOL
END
IF NOT NoZMoves?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
SeqC ExitMove EOL
NextRep
RETURN

xyRepAutoCycle:
EachRep
DoCycleComment
IF NOT FirstCycle?
IF FIFO?
Rapid
END
SeqC RapidC StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
EACHFeat
IF NOT FirstFeat?
DoCycleComment
END
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
SeqC CRCOffC
LoadpRIMEZCP2
IF ZMove?
ExitMove
END
EOL
NextRep
RETURN

cutAutoCycle:
EACHFeat
doCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
autoCycCutSub1
IF Repeats?
IF ZShiftOnly?
EachRep
IF NOT FirstCycle?
IF FeedConnect?
doCycleComment
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqC AbsOrInc exitMove EOL
doCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC RapidC ZCP2 EOL
END
END
entryMove
SeqC IncValue EOL
END
toolPath
NextRep
END
ELSE
milling
END
autoCycCutSub2
NEXTFeat
RETURN

zOnlyRep:
EachRep
doCycleComment
IF NOT FirstCycle?
CRCOffC
IF SPXMove? OR SPYMove?
IF FeedConnect?
FeedC
ELSE
RapidC
END
SeqC MoveSXYC EOL
END
IF FeedEntry? AND NOT FeedConnect?
SeqC ZCP2C EOL
END
END
entryMove
toolPath
SeqC exitMove EOL
NextRep
RETURN

drillStuff:
SeqC DrillCP EOL
GetCycle
IF Tap? AND NOT CWSpindle? {Added - JHE}
SeqC 'G74'
ELSE
SeqC Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ#
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

opGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
cutAutoCycle
ELSE
xyRepAutoCycle
END
IF NOT FeedConnect?
SeqC exitMove2 EOL
END
ELSE
cutAutoCycle
SeqC exitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats?
IF ZShiftOnly?
zOnlyRep
ELSE
xyRep
END
ELSE
milling
END
SeqC CRCOffC exitMove2 EOL
END
ELSE
IF Drilling?
drillStuff
toolPath
setDrillEndOpZ
SeqC Rapid DrillOff ZCP3 EOL
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { LongHand PeckCycle }
SetFlagF('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
END
NextOp
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT; ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED; ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
EachTool {Added - JHE}
'( T' TLNum# '; ' TLDia# ' ' TLToolType$ '; L' TLLength# ' )' EOL
NextTool
restoreScale
RETURN

firstOp1:
SeqC Plane CRCOff DrillOff AbsOrInc Rapid 'G54' EOL {Added AbsOrInc Rapid 'G54' - JHE}
'N' Tool# EOL {Added this line - JHE}
SeqC OpToolID ToolChng EOL {Moved ToolChng to here - JHE}
doPartCycleComment
doOpComments
doPostScript
RETURN

firstOp2:
SeqC Speed SpinOn EOL
checkPass
SeqC AbsOrInc Rapid wFOStuff StrtPos EOL {Moved wFOStuff to here - JHE}
RETURN

firstOp3:
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
RETURN

newToolOp1:
SeqC CoolOff EOL
SeqC incValueC OfstOff SpinOff EOL {Moved SpinOff to here - JHE}
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqC absOrIncC Rapid PRIME Home EOL
ELSE
SeqC absOrIncC EOL {Changed from SpinOff - JHE}
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
'N' Tool# EOL {Added this line - JHE}
{SeqC Plane CRCOff DrillOff EOL} {Removed this line - JHE}
SeqC OpToolID ToolChng EOL {Moved ToolChng to here - JHE}
doPartCycleComment
doOpComments
doPostScript
RETURN

newToolOp4:
SeqC Speed SpinOn EOL
checkPass
SeqC PlaneC AbsOrInc Rapid wFOStuff StrtPos EOL {Moved wFOStuff to here - JHE}
RETURN

newToolOp5:
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC incValueC OfstOff SpinOff EOL {Moved SpinOff to here - JHE}
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC incValueC OfstOff EOL
END
END
RETURN

sameToolOp2: {Start new Operation}
doPartCycleComment
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
{SeqC wFOStuff EOL} {Moved to motion blocks - JHE}
IF LAST ProgStop?
SeqC Speed SpinOn EOL {Moved to here, new block - JHE}
SeqC PlaneC AbsOrInc Rapid wFOStuff StrtPos EOL
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
ELSE
SeqC PlaneC AbsOrInc Rapid wFOStuff StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

end1:
SeqC CoolOff EOL
SeqC incValueC OfstOff SpinOff EOL {Moved SpinOff to here - JHE}
RETURN

end2:
doEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC absOrIncC Rapid PRIME FirstHome EOL
ELSE
SeqC absOrIncC EOL {Changed from SpinOff - JHE}
SeqC 'G28Y0.' EOL {Added this line - JHE}
END
IF ProgStop?
SeqC 'M0' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop EOL
END
END
RETURN

end3:
SeqC PreTool ToolChng EOL {Added this line - JHE}
SeqC EOP EOL
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH; ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH; ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH; ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

mPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

mP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
resetWFO
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

mP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
resetWFO
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

noMPs: {no multiple parts}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

masterSub:
IF MultipleParts?
IF AllToolsOnePart?
mPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mP1ToollAllPXcp
END
END
ELSE
noMPs
END
RETURN

endPartSub:
{End of program ************************************************************}

{finish last operation}
end1
IF MultipleParts? AND OneToolAllParts?
resetWFO
END
end2
RETURN

newPart1: {Finish off last Part}
IF FullUp?
SeqC CoolOff EOL
SeqC incValueC OfstOff EOL
END
{doEndOpPS}
RETURN

newPart2: {Start new Part}
sameToolOp2
RETURN

newPart3: {Start new Part}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SeqC Speed EOL {Moved Speed to here - JHE}
SeqC PlaneC AbsOrInc Rapid wFOStuff StrtPos EOL {Moved wFOStuff to here - JHE}
IF FullUp?
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
END
RETURN

mPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
NewWFO
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
masterSub
NextOp
endPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Valid Tool Op }
IF FirstOperation? OR NewTool?
IF FirstPart?
masterSub
ELSE
newPart1
newPart2
newPart3
opGuts
END
ELSE
masterSub
END
IF LastOp?
IF LastPart?
Save# Num#('1') Num#('0')
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart?
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IncWFO
NextWFO
ELSE
NextPart
END
RETURN

{Start of executable Prog, Top Level ********************}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
mPLoop
resetWFO
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
endPartSub
END
ELSE
EachOp
masterSub
NextOp
endPartSub
END
end3