{Change Comments ***********************************************************}

{added CRCOffC to rapid up and repeats, same as all other Fadal posts, 9/26/88 WFG}
{Changed max rpm from 10000 to 15000 JR 6/5/89}

{1/26/90, Updated: Fadal M003.58, to .69 format, JR}
{2/90/90, Updated: Fadal M003.69, to .70 format, JR}
{3/23/90, 15000 max RPM, JR}

{4/6/90
Added '01' literal for looping once on CallLab line at ZonlyRepAutoCycle & ZonlyRep subs.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/10/90, Updated: Fadal M003.71 to .74 format, JR}

{8/10/90
Copied & modified: Fadal M003.74
For: Admiral
Add CRCOffsetC & ResetCRCNum.
Change to First Tool Not In Spindle.
OpToolID & ToolChng on same line.
WFO's output for MultipleParts & NewWFO only.
Added 'Z0H0' for offset cancel (full up) with CoolOff on same line.
Remove StrtPos from drill cycle line.
CoolOn on same line as OfstOn.
Combine M codes on 1 line.
Jim Radcliffe}

{4/03/91
Modified: Fadal (AEM) M332.74
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/2/92
Copied & modified from Fadal (AEM) M332.79
New designation Fadal Format 1 (Amcraft) M---.--
For Amcraft
Add WFO to move to StrtPos.
Add StrtPos to WFO's at multi parts.
Change 'Z0H0' to 'G0G49Z0' for offset cancel and remove CoolOff except at end.
Add 'X0Y10.E0' to bring table to operator for loading. Works with VMC 4020 only. Y value would differ
for other models. Not ideal way to handle but consistent with customers current method.
Add 'M0' before 'M2' at end of program so that table stops at modified E0 position.
Add StrtPos to drill cycle line.
Move Rapid StrtPos lines ahead of IF Multiparts? lines.
KC}

{8/19/92
Added "SetProgNum" to reset subroutine numbers to one "1" regardless of program number
KC}

{2/11/93
Created from Fadal Format 1 [AC] M509.81.2
For: Fadal
By: [cwh]
Changed 'X0Y10.E0' at end to 'X0Y0Z0E0'.
}
{2/16/93
For: Fadal
By: [cwh]
Changed EOP from M2 to M30.
Changed 'G0G49Z0M5M9' at end to 'M5M9' & 'G0G90Z0H0'.
Removed the trailing comments.
Added a 'G8' on a line by itself before the first G1, G2, G3 following a G0.
}
{2/22/93
For: Fadal
By: [cwh]
Changed all 'G0G49Z0' to 'G0H0Z0'.
}
{3/8/93
For: Fadal
By: [cwh]
Modified the tap cycle section to test for OptCyc1. ( rigid tap, set
in the post via a PS command. )
Modified the drilling cycle to check for Pulse coolant for use as
a Positive Approach flag. ( set in the post via a PS command. )
}
{5/5/93
For: Gibbs
By: [cwh]
Changed all CRCOffsetC to "'D' Tool#". Also made use of flag('1') to
determine when to output. This was done to counter act a change made
in the Catalyst post code that now adds 50 to the tool number to derive
the CRC Offset value.
}
{5/13/93
For: Fadal
By: [cwh]
Modified the WFOStuff routine to handle work fixture offsets better
with multiple parts by checking the NeedWFO1 boolean.
}
{6/17/93
For: Fadal
By: [cwh]
Modified the second and consequent tool changes from
G0 H0 Z0 M9
T# M6
to
M5 M9
T# M6
Changed the ending sequence to
G0 G90 M5 M9
G53 Z0
X0 Y0 Z0 E0 H0
M30
Changed the spindle on line for Rigid Tap cycles to
S####
G84.2
}
{6/23/93
For: Fadal
By: [cwh]
Modified the second and consequent tool changes to output a
'M5 M9' regardless of the ToolChangeAtHome? result.
}
{12/23/93
For: Fadal
By: [cwh]
Modified to output CRC on leadin arc moves. Also CRC cancelation is on a line by itself.
Modified to limit the maximum number of repeats per sub call to 99.
}

{6/10/94
Modified: CNCVIS1 M610.PST
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.21
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Reorganized Prog Formats.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added RestoreScale Sub per 4-Axis Post Processor.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added Move Checker at StdLine.
Deleted StrtPosC at AutoCycCutSub1
Moved SetPass1 from ZonlyRepAutoCycle to AutoCycPat
Made necessary corrections.
Added FORMAT#7 '00' for Recall# to output leading zeros for Repeat Loops value.
Modified OperationIDComment at DoOpComments.
Modified ToolTypeComment at DoOpComments.
Moved CheckPass call to before StrtPos at FirstOperation and NewTool.
This is important for correct AutoCycle SetPass2 StrtPos values.
Changed SeqLabC to SeqLab where ToolPath output CRCOffC for LastFeat of ArcFeat.
Changed SeqC to SeqLab at CoolOff and CoolOn booleans at SameTool.
Change Post to CloseSub and Post2 at end of Prog.
DWB}
{9/26/94
Modified: CNCVIS1 M610.81.2 to CNCVIS1 M610.81.3
For: Star Metal
By: [cwh]
Modified the main section to handle the use of multiple parts better with
respect to initial postioning and spindle on and off commands.
}

{11/16/94 Fixed bug with Program Stops Tom Hubina}

{
Format: CNCVIS1 M610.81.5
3/17/95
Changed SetMaxSeparateSubCalls('50') to SetMaxSeparateSubCalls('500')
TH}

{6/9/95
Fixed CRC so it won't output on a helix
TH}

{7/10/95
Updated: CNCVIS1 M610.81.6
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2g Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added logic to suppress output of CRCOnC in OneFeat ToolPath.
Moved ResetCRCNum at start of ToolPath to CkCRC sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to ZMoveOnly Feature at ToolPath RapidFeat.
Outputs G40 at all Z Retract blocks.
Deleted DoArcCRC sub.
CkCRC sub now called, 3 places at ToolPath ArcFeat.
Deletes use of Flag(8)
Deleted CRCValue sub.
Not needed because problem has been resolved, see 5/5/93.
Deleted SetFlagF(9) at setup and initializations.
Was not being used anywhere.
Simplified output of Canned Drill Cycle block at IF Drilling.
DWB}

{7/14/95, Updated CNCVIS1 M610.81.7 to .85 format per v2.20 Update Instructions .01, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, ZOnlyRepAutocycle tested, incremented to .89, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{12/17/96
Updated: CNCVIS1 M610.89
Created: CNCVIS1 M610.89.1
For: Arobotek
Versions: Catalyst v3.23C/Compost 4.21.37/v1.0b1
Changes made per Jim Radcliff.
Updated for Catalyst v3.20C per Fanuc 6M M001.89a Format
Added M001.14 source.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted version comments.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of StdLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqLab and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqLab and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}

{4/11/97
Updated: CNCVIS1 M610.89.1
Created: CNCVIS1 M610.15
For: Gibbs & Associates/Precision Products
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Pete Jackson/David Davis of Precision Products
Updated for Catalyst v3.33C per Fanuc 6M M001.15 Format
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
Corrected problem with output of literal 'G8' block at ToolPath.
Deleted IF NOT Rapid? and IF LAST Rapid? Booleans.
IF LAST Rapid? Boolean was causing post to output extra EntryFeedRates during Toolpath.
IF LAST Rapid? Boolean is an incorrect use of a non-ToolPath command.
Developers original intent on 2/16/93 to block on FIRST LineFeat OR ArcFeat following RapidFeat
condition was not working as intended.
When I changed IF LAST Rapid? to IF LAST RapidFeat, the post output more 'G9' blocks and
extra EntryFeedRate problem disappeared.
Left IF FirstFeat? boolean in place.
This caused no difference in occurance of G8 blocks.
DWB}

{5/16/97,
Initial: CNCVIS1 M610.15
Created: CNCVIS1 M610.15.1
Changed FadalTapF to 'F' SpeedRPM#, FadalTapF was erroneously being scaled when posting metric parts, MPK}

{1/26/98,
Initial: CNCVIS1 M610.15.1
Created: CNCVIS1 [MM] Mxxx.15
For: Milltek Mfg.
Changed SeqLab's to SeqLabC's per customer.
In Form: Changed M7 to M8.
Moved CoolOn in FirstOp3 and NewToolOp5 to after OffstOn.
Deleted commands in ckCRCNum.
Added UnTool at end of prog.
In an effort to simplify and clear up confusion...all sub-routine names have been modified
to start with a lower-case letter.
CDH}

{2/5/98,
Initial: CNCVIS1 [MM] MV04.15
Created: CNCVIS1 [MM] MV04.15.1
For: Milltek Mfg.
The command EndSubs outputs a M30 at the end of all sub-programs. However, it also outputs
a line number which cannot be supressed.. This customer does not want any line numbers in his program.
To remedy this, the command Endsubs was removed, and replaced with the doEndsub sub-routine. This sub-routine
will create the last sub-program in the program, output a literal M30, and then close the sub-routine.
It will only create this sub-program if one sub-program has already been created, using Flag('4').
CDH}

{2/12/98
Modified: CNCVIS1 [MM] MV04.15.1
Created: CNCVIS1 [MM] MV04.15.2
For: Milltek Mfg
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Ken Bondurant of Milltek Mfg, phone call and fax.
Deleted literal 'AAA' from EndSub block at closeMP.
Debugging Tool accidentally left in by previous developer.
DWB}

{10/28/98,
Initial: CNCVIS1 [MM] MV04.15.2
Created: Fadal Format 1 [TE] MT23.15
For: Tinsley Eng. Co.

Changes to Form:
1) Program Stops - Changed End Program number to 2.

Changes to Prog:
1) InitOp - changed comment to read: First Tool In Spindle
2) FirstOp1 - Deleted Tool change line.
3) NewToolOp1/End1 - changed 'G53Z0' to 'G28'.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(SpeedRPM#,5)
FORMAT(Recall#,6)
FORMAT(CallMasterNum#,6)

{Prog Subroutines ****}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

wFONum:
'E' NewWFO#
RETURN

wFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
wFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
wFONum
END
ELSE
wFONum
END
END
END
END
SetFlagF('2')
RETURN

doSubComment:
IF UseComments? AND SubComment?
SeqLabC '* SUB NUMBER: ' Program# EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
SeqLabC '* OPERATION ' Operation#
IF OperationIDComment?
': ' OperationType$
END
EOL
IF OperationComment?
SeqLabC '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLabC '* ' WorkGroupComment$ EOL
END
SeqLabC '* TOOL ' Tool#
IF ToolTypeComment?
': ' ToolDiameter# ' ' ToolType$
END
EOL
IF ToolComment?
SeqLabC '* ' ToolComment$ EOL
END
restoreScale
END
RETURN

pSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

pSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
pSInit
EachPS
SeqLabC PostScript EOL
pSStuff
NextPS
RETURN

doEndOpPS:
pSInit
EachEOPS
SeqLabC EndOpPS EOL
pSStuff
NextPS
RETURN

entryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

startSub:
SetFlag('4') {Flag for doEndSub}
OpenSub
SeqLabC SubIDF EOL
doSubComment
RETURN

doEndSub: {This will create the last sub-program, only if one has already been created}
IF Flag?('4')
OpenSub
SeqLabC 'M30' EOL
CloseSub
END
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLabC '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

stdSub:
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLabC CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLabC CallLab Recall# Num#('10') EOL
startSub
RETURN

finishSub1: {part 1}
SeqLabC CRCOffC EOL
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

finishSubG92: {part 2}
SeqLabC Preset ShiftR EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftR EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC Rapid StrtPos SetWFO EOL
END
SeqLabC CallLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLabC CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLabC CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { wFOStuff }
END
END
startSub
RETURN

closeMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
ELSE
SeqLabC Preset ShiftP EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftP EOL
END
RETURN

doAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

ckCRC:
IF LastFeat?
IF NOT ArcFeat?
CRCOffC
END
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
RETURN

formatArc:
doAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC CallLab OnePart EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC doDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF FirstFeat?
SeqLabC 'G8' EOL
END
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC doAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqLabC doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC formatArc ArcFeedC ckCRCNum EOL
DecelMove2
END
SeqLabC formatArc DecelFeed ckCRCNum EOL
ELSE
SeqLabC formatArc ArcFeedC ckCRCNum EOL
END
NEXTQuadrant
IF LastFeat?
SeqLabC CRCOffC EOL
END
END
END
END
END
NEXTFeat
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqLabC AbsOrInc Connect StrtPos EOL
milling
finishSub1
finishSubG92
RETURN

zonlyRepAutoCycle:
autoCycPat {write pattern moves and main calls}
startSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC CallLab '01' EOL
NextCycle
SetStatusOn
autoCycCutSub1 {build element sub}
autoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

zonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
SeqLabC CallLab '01' EOL
NextCycle
startSub
TrackZNO# FIRST SPZ#
toolPath
finishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

getSpeed:
IF Drilling?
GetCycle
END
IF Drilling? AND RigidTap?
IF FirstOperation? OR NewTool?
SeqLabC Speed EOL
END
SeqLabC SpeedC EOL
SeqLabC 'G84.2' EOL
ELSE
IF FirstOperation? OR NewTool?
SeqLabC Speed SpinOn EOL
ELSE { SameTool }
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
ELSE
SeqLabC SpeedC EOL
END
END
END
RETURN

checkPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

opGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { milling ZShiftOnly SepSubs }
zonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
g92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
SeqLabC CRCOffC EOL { Just in case }
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
stdSub
SeqLabC AbsOrInc Rapid StrtPos wFOStuff EOL
END
IF Pulse? { Positive Approach On }
SeqLabC 'M46' EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF RigidTap?
'F' SpeedRPM# FadalTapQ
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLabC 'L' CallMasterNum# '01' EOL
skipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC CallLab '01' EOL
startSub
toolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
toolPath
END
END
setDrillEndOpZ
IF Pulse? { Positive Approach Off }
SeqLabC 'M47' EOL
ResetCool
END
SeqLabC Rapid 'G80' ZCP3 EOL
IF Repeats?
finishSubG92
END
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { milling ZShiftOnly SepSubs }
SetFlagF('2') { wFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('4') { If no subs, then suppresses doEndSub }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
EOR EOL
SeqLabC 'O' Program#
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
SetProgNum('0')
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
SeqLabC '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLabC '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLabC '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLabC '* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
SeqLabC '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLabC '* FIRST TOOL IN SPINDLE' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
doOpComments
doPostScript
RETURN

firstOp2:
getSpeed
checkPass
SeqLabC Plane AbsOrInc Rapid StrtPos wFOStuff EOL
RETURN

firstOp3:
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
RETURN

newToolOp1:
SeqLabC Rapid AbsOrInc SpinOff CoolOff EOL
SeqLabC 'G28' EOL { OfstOff }
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqLabC 'G28' Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
SeqLabC OpToolID ToolChng EOL
doOpComments
doPostScript
RETURN

newToolOp4:
getSpeed
checkPass
SeqLabC Plane AbsOrInc Rapid StrtPos wFOStuff EOL
RETURN

newToolOp5:
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqLabC 'G0H0Z0' CoolOff SpinOff 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC 'G0H0Z0' EOL
ELSE
END
END
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
IF LAST ProgStop?
getSpeed
SeqLabC PlaneC AbsOrInc Rapid StrtPos wFOStuff EOL
SeqLabC OfstOn CoolOn EOL
ELSE
IF NewToolOffset?
getSpeed
SeqLabC PlaneC AbsOrInc Rapid StrtPos wFOStuff EOL
SeqLabC OfstOn EOL
ELSE
getSpeed
SeqLabC PlaneC AbsOrInc Rapid StrtPos wFOStuff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC Rapid AbsOrInc SpinOff CoolOff EOL { 'G0G90M5M9' }
SeqLabC 'G28' EOL { OfstOff }
RETURN

end2:
doEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqLabC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
RETURN

End3:
SeqLabC 'X0Y0Z0E0H0' EOL
IF NOT FirstTool?
SeqLabC UnTool ToolChng EOL
END
SeqLabC EOP EOL
doEndSub
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Reseq
{ File Length Comments deleted 2/16/93 }
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
initOp
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
closeMP
end3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
initOp
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
closeMP
end2
end3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
initOp
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP {End of program}
end1
end2
end3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { wFOStuff }
IF FirstOperation?
initOp
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END