{Change Comments ***********************************************************}

{5/20/93
Copied & modified: Fanuc 10M M008.81.2
For: Haas Automation
Combined OpToolID and ToolChng on one block at FirstOperation and NewTool.
Combined WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos and OfstOn on one block at FirstOperation,
NewTool and SameTool.
Added CkCRC sub to cancel CutterRadiusCompensation on LastFeature of ToolPath.
Added literal 'G74' for Left-Handed Tapping at Drilling.
Moved Canned Drill Cycle Block to Main Program when Repeats = TRUE at Drilling.
Main program will output the Canned Drill Cycle, and the SubPrograms will contain only the
positions from the second feature on.
DWB}

{8/2/93
Modified: Haas M573.81.2
For: Haas Automation
Changes made per visit with Harold Moon at Haas Automation.
Added ProgramName$ to SubID block at StartSub.
Added blank lines between subs.
Deleted RepLab OnePart at OpenMP.
Moved Rapid, Feed and Connect Commands to be output in front of AbsOrInc on same block.
Deleted colons from all Comments.
Deleted Spaces following '(, and preceeding )' from ProgramNameComment at FirstOperation.
Changed Seq to 'N' Tool# EOL at FirstOperation and NewTool, output on block by itself.
Changed Safe Start block from G17G80G40 to G0G90G54G40G80G17 at FirstOperation and NewTool.
Changed StrtPos block from WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos OfstOn to
Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn at FirstOperation and NewTool.
Added PlaneC to StrtPos block at NewTool.
Moved OfstOn to beginning of CoolOn block at FirstOperation and NewTool.
Changed WFOStuff PlaneC AbsOrInc Rapid to Rapid AbsOrInc WFOStuff PlaneC at SameTool StrtPos block.
Added IF RetractToCP1 boolean at SameTool.
This is to force output of ZCP1 or ZCP2 for Drilling.
Changed RapidC ZCP3C to Rapid ZCP3 at Drilling.
Moved 'G80' to Rapid ZCP3 at Drilling.
Added literal 'M19', Spindle Orient, at OfstOff block at end of Prog.
Added MasterOp/CallMasterOp PostScript Command support for Drilling.
Routines have been added to call previously created subroutines.
Added MasterOpF and CallMasterOpF at PSInit.
Added PostScript Comments regarding MasterOp and CallMasterOp Commands.
Added support of MasterOp and CallMasterOp Commands at Drilling.
Added FORMAT for Recall# to output called sub.
DWB}

{8/16/93
Copied & modified: Haas M573.81.3
For: Q Corp
Control: Haas
Machine: Haas
Modified StdLine sub to use a D label and value same as tool number for CRCOffsetC.
Not using IncValue OfstOff for ToolChng, still using it for everything else.
Jim Radcliffe}

{8/19/93, .81.4, changed to First Tool In Spindle format, JR}
{8/26/93, .81.5, delete G74 Tapping Cycle, move ProgStop after M06, JR}
{9/9/93, .81.6, replaced tool change at first op, JR}

{11/14/94, .81.7, changed the arc format to use R's instead of I's and J's, TH}

{
Format: Haas [QC] M587.81.8
5/23/95
Fixed MasterOp to support Virtual Gibbs v2.20 specs
TH}

{
10/3/95
Added support for WFO's beyond G59. Now supports G54-G59, G110 - G129
TH}

{11/20/95
Initial: Haas [QC] M587.81.9
Created: Haas [QC] M587.85
ForUser: Q Corp
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Modifications per marked up readout from Kelly Angle
Updated to .85 format per Fanuc 6M M001.85.01.03
Commented out select Header Operation and footer comments.
Deleted 'N' Tool#.
Changed SeqC to Seq at beginning of tools.
Putput DoOpComments before ToolChng.
Jim Radcliffe}

{11/22/95, .85.1, Deleted FromCP command per Kelly at Q Corp, JR}

{11/30/95
Initial: Haas [QC] M587.85.1
Created: Haas [QC] M587.85.2
Comment: Changed to IJ format arcs
Jim Radcliffe}

{
Format: Haas [QC] M587.85.4
12/4/95
Turned off Allow R Format Arcs in Form
TH}

{12/15/95, Fixed OfstOff calls so they now call AbsValue afterwards, TH}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{4/8/97, updated to ad mill post per Fanuc 6M (NW) D001.15, MPK}

{6/24/97
Updated & Modified: Haas [QC] D587.15
Created: Haas [QC] D587.15.1
For: Q Corp
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Pete Jackson.
Updated for Catalyst v3.33C per Fanuc 6M (NW) D001.15 Format.
Modifications:
Added literal 'G' at wfo sub.
Value of WFO was output without G Address.
Changed SeqLabC to SeqC in IF Drilling CallMasterOp at opGuts sub.
Rewrote IF Drilling at opGuts sub.
Deleted wfoStuff call from SafeStart block at firstOp1 and newToolOp2.
Moved relevant blocks from newToolOp2 to newToolOp3.
Was causing MultipleParts AllToolsOnePart situation to output start of NewTool at end of
previous Tool SubProgram.
Rewrote sameToolOp1 and sameToolOp3.
Was not testing for ChangeCS.
Did not cause OfstOff and OfstOn for Indexing.
IF NOT CoolOff? AND LAST CoolOff? was not working.
DWB}

{04/02/99,
Initial: Haas [QC] D587.15.1
Created: Haas [VI] Dxxx.15
For: Vitols Tool & Machine

Changes to Prog:
1) Reinstated use of all prog comments that had previously been
commented out.
2) newToolOp1 - Post will now output OfstOff if not doing Multiple
Parts.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)

{Prog Subroutines ****}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

MPESWFO: { MultipleParts EquallySpaced }
'G'
IF GreaterThan? ADD# PartNum# SUB# NewWFO# Num#('1') Num#('59')
ADD# ADD# PartNum# SUB# NewWFO# Num#('1') Num#('50')
ELSE
ADD# PartNum# SUB# NewWFO# Num#('1')
END
RETURN

wfo:
'G'
IF GreaterThan? ADD# PartNum# Num#('53') Num#('59')
ADD# ADD# PartNum# Num#('53') Num#('50')
ELSE
ADD# PartNum# Num#('53')
END
RETURN

WFONum:
'G' NewWFO#
RETURN

wfoStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO
ELSE
MPESWFO
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

doSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )' EOL
END
RETURN

doCSComment:
IF AAxisAvail? OR BAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN

csComments:
IF FirstOperation? OR NewTool? OR ChangeCS?
DoCSComment
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
restoreScale
END
csComments
RETURN

csAngleA:
IF AAxisAvail?
'A' CSOffsetA#
END
RETURN

csAngleAC:
IF AChange?
csAngleA
END
RETURN

csAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN

csAngleBC:
IF BChange?
csAngleB
END
RETURN

psInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

psStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
psInit
EachPS
SeqC PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqC EndOpPS EOL
psStuff
NextPS
RETURN

entryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

startSub:
OpenSub
' ' EOL
SubID
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

stdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
startSub
RETURN

finishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

finishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

toggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
IF GreaterThan? PartNum# Num#('6')
SeqC 'G' ADD# PartNum# Num#('103') EOL
ELSE
SeqC SetWFO EOL
END
END
SeqC SubCall CallLab EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
doWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
toggleIncDecWFO
END
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { wfoStuff }
END
END
startSub
RETURN

closeMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

doAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

formatArc:
doAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
IF NOT EmptyLine?
SetFlag('6')
END
END
END
RETURN

ckCRCNum:
IF Flag?('6')
SetFlagF('6')
'D' Tool#
END
RETURN

toolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC doDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC doAbsOrInc RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC doAbsOrInc FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC doAbsOrInc FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC doAbsOrInc FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC formatArc ArcFeedC EOL
DecelMove2
END
SeqC formatArc DecelFeed EOL
ELSE
SeqC formatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc
ELSE
IF FIFO?
FeedC AbsOrInc ZCP2 FeedEntC
ELSE
RapidC AbsOrInc ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqC Connect AbsOrInc StrtPos EOL
milling
finishSub1
finishSubG92
RETURN

zonlyRepAutoCycle:
autoCycPat {write pattern moves and main calls}
startSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
autoCycCutSub1 {build element sub}
autoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

zonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
startSub
TrackZNO# FIRST SPZ#
toolPath
finishSub1
SeqC EndSub EOL
CloseSub
RETURN

checkPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

opGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
zonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
g92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC Cycle StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF Repeats?
NewProg
stdSub
END
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
skipToLastFeat
setDrillEndOpZ
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
startSub
toolPath
setDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
toolPath
setDrillEndOpZ
END
END
IF Repeats?
finishSubG92
END
IF NOT MasterOp? AND NOT CallMasterOp?
SeqC Rapid 'G80' ZCP3 EOL
END
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { wfoStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('6') { 'D' Tool# at ckCRCNum }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
doOpComments
Seq OpToolID ToolChng EOL
doPostScript
SeqC Rapid AbsOrInc CRCOff 'G80' Plane EOL
RETURN

firstOp2:
checkPass
SeqC Rapid AbsOrInc wfoStuff StrtPos csAngleA csAngleB Speed SpinOn EOL
RETURN

firstOp3:
SeqC OfstOn CoolOn EOL
RETURN

newToolOp1:
SeqC CoolOff EOL
IF MultipleParts?
IF OneToolAllParts? AND FullUp?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
ELSE
SeqC OfstOff EOL
END
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
RETURN

newToolOp3: {Start new Operation}
doOpComments
Seq OpToolID ToolChng EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
doPostScript
SeqC Rapid AbsOrInc CRCOff 'G80' Plane EOL
RETURN

newToolOp4:
checkPass
SeqC Rapid AbsOrInc wfoStuff StrtPos csAngleA csAngleB Speed SpinOn EOL
RETURN

newToolOp5:
SeqC OfstOn CoolOn EOL
RETURN

sameToolOp1:
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
doEndOpPS
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
doEndOpPS
END
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC Rapid AbsOrInc PlaneC wfoStuff StrtPos csAngleA csAngleB SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
SeqC Rapid AbsOrInc PlaneC wfoStuff StrtPos csAngleA csAngleB SpeedC EOL
SeqC
IF NewToolOffset? OR ChangeCS?
OfstOn
ELSE
IF Drilling?
IF RetractToCP1?
ZCP1
ELSE
ZCP2
END
END
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

end1:
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
RETURN

end2:
doEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
SeqC UnTool ToolChng EOL
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

end3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
{'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL}
END
IF FileFeetComment?
{'( FILE LENGTH ' FileFeet# ' FEET )' EOL}
END
IF FileMetersComment?
{'( FILE LENGTH ' FileMeters# ' METERS )' EOL}
END
Close
END
RETURN

mpallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
initOp
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
initOp
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
initOp
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP {End of program}
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { wfoStuff }
IF FirstOperation?
initOp
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1 {End of program}
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
mpallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END