{Change Comments ***********************************************************}

{3/9/89 minor corections by JR}

{4/25/89
Copied & Modified; Fanuc 10T-MS [-] L001.58, for Brunswick.
Machine is a Cincinnati Series 208 Turning Center, Acramatic 850TC
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/17/91, Updated Cincinnati Acr 850TC L102.56 to .81 format, JR}

{8/6/91
Updated: Cincinnati Acr 850TC L102.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
Kim Michelman}

{8/6/91
Using "Reference Rewind Stop" characters (:) unstead of SeqLab (N) at beginning of operations.
Changed the startup code per the manual, ':' Program# Rapid Plane 'G62G70' AbsOrInc 'G95' Home GearRange EOL.
Added the GetSpinOn sub to differentiate the 'M13' from 'M03' and 'M14' from 'M04'.
The GetSpinOn replaced the SpinOn command throughout the processor.
Added the missing NextOp at the end of the prog.
Put the EOP on the same line as the FirstHome, per the manual.
Deleted the ProgStop and the Untool ToolChng from the end of the prog.
Kim Michelman}

{6/8/93
Copied & modified: Cincinnati Acr 850TC L102.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Use sequence number for colon blocks.
Added leading zero supression on G & M & T codes.
Changed ToolChng from M26 to M6.
Modified GearRanges.
Added XsAreRadii to initializations.
Added CoolOff at end of tool.
Reduce RPM to 125 at end of tool if next tool has a new gear or spindle direction.
Changed to use absolute arc centers.
Added spaces between codes.
Deleted "XatFinZ ThrdHeight" line before thread cycle.
This was to position to the major dia,
set CAM document to have Start X and Major Ż set the same.
Jim Radcliffe}

{8/6/93
Modified: Cin Acr 850 TC [IM] L289.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Modified retract to index position.
Machine has 2 turrets: Lower = Tools 1 thru 6 Upper = Tools 11 thru 16
When indexing from Lower to Upper retract Z to NewHome + 20"
When indexing from Upper to Lower retract X to NewHome + 13"
Unconditional axis output in FormatArc.
Deleted extra Rapid from Approach.
Moved callout of CSSOn for FirstOp and NewTool.
Changed format of output from 0. to 0 for a zero output.
Due to a recent visit to the Twilite Zone,
I had to start with a fresh Form (I used L001) to get this to work.
Colon block must imediatly follow a program stop.
Moved ProgStop to a line by itself after DoOpComments in same tool.
Rewrote CheckOffset to add Colon Block if ProgStop.
Modified R value for Threading by .050 for clearance
Jim Radcliffe}

{11/1/94
Copied & modified: Cin Acr 850 TC [IM] L289.82.2
For: Accurate Tool Co.
Control: Acramatic 850 SX
Machine: Cincinnati Milicron Avenger
Changed G76 to G33 for Threading Canned Cycle.
Moved EOP down to line by itself.
Added 1 NULL character to end of program.
Added X and I values for Tapered threading.
Jim Radcliffe}

{3/2/95
Updated: Cin Acr 850 SX L315.82.2
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Pete Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Added XSPC ZSPC at AutoFinish for NOT CannedCycle AND NOT Turning Operations.
Changed RapidC StrtPos to StockOff StrtPosC at AutoFinish for NOT CannedCycle Operations.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Added support for AutoFinish of non-Canned Threading Cycle.
Miscellaneous other changes.
DWB}

{3/15/95
Modified: Cin Acr 850 SX L315.82.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Added Address Spaces to Canned Tap and Peck Drilling Cycles in Mach Spec Drilling Dialog.
Added '##.0####;0 Format back in Address K of Mach Spec Threading Dialog.
Somehow, this disappeared.
Added call to RestoreScale prior to SafeStart Home block at beginning of FirstOperation.
Prior to calling RestoreScale, we were outputting Home on the SafeStart block, which did not get
correctly scaled during Metric>English conversion, and vice-versa.
DWB}

{3/16/95
Copied: Cin Acr 850 SX L315.82.4
Created: Cin Acr 850 SX [STM] L324.82.4
For: Sterling Thermal Motors
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Changed SetMaxRPM('1600') to SetMaxRPM('4000') at setup and initializations.
Added SetMinRPM('30') at setup and initializations.
Added literal 'G70', Inch Mode at Safe Start blocks at FirstOperation and NewTool.
Added GetToolChng sub called from FirstOperation, NewTool and end of Prog.
Contains condition to output ' M26' instead of ToolChng when NOT ToolChangeAtHome.
DWB}

{
Format: Cin Acr 850 SX L324.82.5
5/1/95
Moved 'G70' so it follows 'G97'
TH}

{5/26/95
Initial: Cin Acr 850 SX [STM] L324.82.5
Created: Cin Acr 850 SX [STM] L324.82.6
ForUser: Stirling Thermal Motors, Inc.
Machine: Model 250T
Comment: Changed Tap Cycle to G84 per faxed manual pages. Deleted DrillOff.
Jim Radcliffe}

{
Format: Cin Acr 850 SX L324.82.7
6/29/95
For: StoneAge
Added blank line to beginnning of program
TH}

{9/7/95, Updated Cin Acr 850 SX [STM] L324.82.7 to .85 format per v2.20 Update Instructions .01, JR}

{
Format: Cin Acr 850 SX L324.85.1
1/3/95
For: StoneAge
Changed ToolChng from M6 to M26.
Added I to G33 toolpath threading
Removed special GetNewHome sub and replaced with standard NewHome
TH}

{1/25/96
Initial: Cin Acr 850 SX [STM] L324.85.1
Created: Cin Acr 850 SX [STM] LXXX.85.2
For: StoneAge
Removed GoFirstHome sub, replaced with FirstHome command as per customer request,
eliminated 'I' value for straight threads, MPK}
{2/21/96,
Initial: Cin Acr 850 SX [STM] L324.85.2
Created: Cin Acr 850 SX [STM] L324.85.3
Multiplied 'I' value for tapered threads in order to get positive valued for OD threads and negative
for ID threads, MPK}
{3/5/96
Initial: Cin Acr 850 SX [STM] L324.85.3
Created: Cin Acr 850 SX [STM] L324.85.4
Made I vaule for threading always positive, MPK}

{
Format: Cin Acr 850 SX [STM] Lxxx.85.5
3/27/96
Changed ToolChng from M26 to M6.
TH}

{5/21/96,
Previous revision number is incorrect, should be M437.85, changing to .1 to match metric revision number,
no changess necessary, MPK}

{8/13/96
Initial: Cin Acr 850 SX [STM] L437.85.1
Created: Cin Acr 850 SX [STM] L437.85.2
ForUser: Boeing
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Corrected handling of Home commands, CSS and M6/M26
M26 sends machine home before indexing. Use in place of M6 IF NOT ToolChangeAtHome!
IF NOT ToolChangeAtHome, Home commands need to be suppressed!
G96 needs to come after the start position on X where CalcRPM1 calculates for and for R value!
Jim Radcliffe}

{9/6/96
Initial: Cin Acr 850 SX [STM] L437.85.2
Created: Cin Acr 850 SX [STM] L437.85.6 ( had to call .85.6 as STM has .85.5 version!!! )
ForUser: Boeing per Art Phelan at 206-655-5016
ForUser: Stirling Thermal Motors per Mike Slater at 313-995-1755
ForUser: Stone Age per Ed Deason at 970-259-2869
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Corrected M06/M26, Home/NoHome, colon block X&Z move & G33 G0.
Changed CheckHome on colon block to ThisOpEntryXCP ThisOpEntryZCP.
The colon block must have an X and Z move.
This move will occur AFTER the M6/M26 tool change!
Modified Approach sub accordingly to prevent redundant output & deleted AppMove sub.
NOTE: Colon block in CheckOffset laft alone as there is no program stop in Virtual!
This will have to be addressed when Virtual supports a program stop!
Corrected threading output of G33 and G0 on same line.
Updated Approach subs, SameTool and non-canned sections per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe - Please refer this processor back to me for any future development!}

{9/23/96
Initial: Cin Acr 850 SX [STM] L437.85.6
Created: Cin Acr 850 SX [STM] L437.85.7
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per very reasonable and globaly OK requests by Mike Slater
Changed colon block ThisOpEntryXCP ThisOpEntryZCP to Approach.
Moved ApproachSP from Approach to main.
Moved G96 up to right after the preset line.
Added ApproachDia# sub for calculation of G97 and R values.
Fixed SameTool support of colon block and G96
Changed NewTool? to NewTool? OR LAST ProgStop? to treat SameTool ProgStop same as new tool!
Jim Radcliffe - Please refer this processor back to me for any future development!}

{10/7/96
Initial: Cin Acr 850 SX [STM] L437.85.7
Created: Cin Acr 850 SX [STM] L437.85.8
ForUser: Stirling Thermal Motors per Mike Slater at 313-995-1755
Control: Cincinnati Acramatic 850 SX
Machine: Cincinnati Avenger T250
Comment: Corrected StartSpeed to incorporate Max and Min RPM settings! G33 is Modal!
Jim Radcliffe}

{1/24/97
Initial: Cin Acr 850 SX [STM] L437.85.8
Created: Cin Acr 850 SX [STM] L437.85.9
ForUser: Boeing
Control: Cin Acr 850 SX
Machine: Cinturn 12" Universal Turning Center
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: Corrected StartSpeed to incorporate MaxRPM# from Virtual.
Jim Radcliffe}

{6/5/97
Initial: Cin Acr 850 SX [STM] L437.85.9
Created: Cin Acr 850 SX [D&H] Lxxx.85
ForUser: D & H Performance
Control: Cin Acr 850 SX
Machine: Avenger 250T Turning Center
Comment: modified to use a canned tapping cycle
added FORMAT(CalcZSurf#,2) and FORMAT(ClearancePlane3#,2)
changed so tap and rigidtap always goes thru canned section
changed canned drilling for tap and rigid tap
WS}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.0###;0'
#3 = '#######0'
#4 = '##.#0'
#5 = '+#.0###;0'
#6 = '0000'
#7 = '#'
#8 = '+###.0###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(InFeedAngle#,2)
FORMAT(ThisOpEntryXCP#,2)
FORMAT(XOpCD#,2)
FORMAT(StartPosX#,2)
FORMAT(CalcZSurf#,2)
FORMAT(ClearancePlane3#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(DIV#,3)
FORMAT(MaxRPM#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(XCutDepth#,5)
FORMAT(ZCutDepth#,5)
FORMAT(CycleStartXRadius#,5)
FORMAT(Program#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(MUL#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC StockOnNoCan ZSPC EOL
END
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# forces FeedRateC to output }
IF ApproachOD?
ThisOpEntryXCP AppMove
ELSE
IF ApproachID?
XOpCD AppMove
ELSE {ApproachFace}
StockOnNoCan XSP AppMove
END
END
RETURN

ApproachDia#:
IF ApproachOD?
ThisOpEntryXCP#
ELSE
IF ApproachID?
XOpCD#
ELSE {ApproachFace}
StartPosX#
END
END
RETURN

GetSpinOn:
IF CWSpindle?
IF CoolOff?
' M3'
ELSE
' M13'
END
ELSE
IF CoolOff?
' M4'
ELSE
' M14'
END
END
RETURN

Constant#:
IF Metric?
Num#('.1503937008') { 3.82 / 25.4 }
ELSE
Num#('3.82')
END
RETURN

ApproachDiaCalcRPM1#:
DIV# MUL# SpeedSFPM# Constant# MUL# ApproachDia# Num#('2')
RETURN

StartSpeed:
CSSOff
IF ConstantSurfaceFeed?
' S'
IF GreaterThan? ApproachDiaCalcRPM1# MaxRPM#
MaxRPM#
ELSE
IF GreaterThan? ApproachDiaCalcRPM1# Num#('4000') { SetMaxRPM('4000') }
'4000'
ELSE
IF LessThan? ApproachDiaCalcRPM1# Num#('30') { SetMinRPM('30') }
'30'
ELSE
ApproachDiaCalcRPM1#
END
END
END
ELSE
Speed
END
RETURN

CheckOffset:
DoEndOpPS
IF NewGear?
SeqLabC SpinOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
{tool offsets not used in this processor}
END
IF NewGear?
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96 R' StartPosX# Speed EOL { the R value on this line is not correct }
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
END
END
IF NewGear?
SeqLabC GetSpinOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoOpComments
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC
IF LAST ThreadFeat?
{ G33 is modal }
ELSE
' G33'
END
MoveXC MoveZC
IF Taper?
' I' MUL# DIV# Num#('1') Thread# DIV# Taper# FinishZInc#
END
ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST Tap? OR LAST RigidTap?
{rapid handled with drilling cycle}
ELSE
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
END
RETURN

GetToolChng:
IF ToolChangeAtHome?
ToolChng
ELSE
' M26'
END
RETURN

CheckNewHome:
IF ToolChangeAtHome?
NewHome
END
RETURN

CheckFirstHome:
IF ToolChangeAtHome?
FirstHome
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
SetMaxRPM('4000')
SetMinRPM('30')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
RestoreScale
SetHome
OpenSub
StockOff {.71.2}
' ' EOL
':?' Rapid Plane ' G95' ' G97' ' G70' Approach ' F.05' StartSpeed OpToolID GetToolChng GetSpinOn GearRange EOL
IF UseComments?
SetScale('1')
SeqLabC '(MSG, ' Program# ' )' EOL
IF ProgramNameComment?
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
RestoreScale
END
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96 R' ApproachDia# Speed EOL
END
ApproachSP
ELSE
IF NewTool? OR LAST ProgStop?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
SeqLabC LAST OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
IF CWSpindle? AND LAST NOT CWSpindle?
SeqLabC CSSOff ' G97' CheckNewHome ' S125' EOL
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SeqLabC CSSOff ' G97' CheckNewHome ' S125' EOL
ELSE
IF NewGear?
SeqLabC CSSOff ' G97' CheckNewHome ' S125' EOL
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CheckNewHome CalcRPM2 EOL
ELSE
SeqLabC CheckNewHome EOL
END
END
END
END

{Start new Operation}

DoOpComments
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END
':?' Rapid Plane ' G95' ' G97' ' G70' Approach ' F.05' StartSpeed OpToolID GetToolChng GetSpinOn GearRange EOL
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96 R' ApproachDia# Speed EOL
END
ApproachSP
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle? OR Tap? OR RigidTap?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
ToolPath
ELSE
SetPass2
SeqLabC Feed FeedRate EOL
IF RoughContour?
SeqLabC '(BAR,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
CutDepth XStkLeft ZStkLeft XSP ZSP ')' EOL
ELSE
IF RoughPatternShift?
SeqLabC '(CPY,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
XStkLeft ZStkLeft XSP ZSP ')' EOL
END
END
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
END
ELSE
IF Threading?
SeqLabC '(THD,' CutDepth
IF SingleEdgeCut?
' A' InFeedAngle#
ELSE
' A0'
END
' R' ADD# CycleStartXRadius#
IF ApproachOD?
Num#('.05')
ELSE {Approach ID}
Num#('-.05')
END
XatFinZ ZSP ')' EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
IF Taper?
XAtFinZ FinZ ' I' MUL# DIV# Num#('-1') Thread# DIV# Taper# FinishZInc#
ELSE
FinZ
END
ThrdLead EOL
SeqLabC '(ENC)' EOL
IF AutoFinish?
SeqLabC Rapid XatFinZ ZSP EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
FinZ ThrdLead EOL
SeqLabC RapidC ' X' CycleStartXRadius# EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap? OR RigidTap?
SeqLabC ' G84 R' CalcZSurf# ZDepth FeedRate EOL
SeqLabC Rapid ZCP3 EOL
ELSE
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
END
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' ADD# FinishXRadius# Taper# EOL
SeqLabC ' G33'
IF Taper?
XatFinZ FinZ ' I' MUL# DIV# Num#('-1') Thread# DIV# Taper# FinishZInc# ThrdLead EOL
ELSE
FinZ ThrdLead EOL
END
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF Tap? OR RigidTap?
SeqLabC CoolOff EOL
ELSE
IF ApproachOD?
SeqLabC OpExitXCPC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
SeqLabC OpExitZCPC CoolOff EOL
END
END
END
DoEndOpPS
SeqLabC CSSOff ' G97' CheckFirstHome ' S125' EOL
SeqLabC UnTool GetToolChng EOL
SeqLabC EOP EOL
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Post
ASCII('00') EOL
Close
Retag