{2/13/90, Updated: Fanuc 3000C Acroloc M066.53 to .70 & Added AbsOrInc on Preset ZCP1 line, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/03/91
Modified: Fanuc 3000C Acroloc M066.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{12/3/91
Copied & modified: Fanuc 3000C Acroloc M066.79
For: B&K Manufacturing
Control: Fanuc 3000C
Machine: Acraloc M12
Deleted Speep5M command. Speeds are set manually.
Added spindle codes to MachSpec, S03 forward S04 reverese.
Added OpToolID to FirstOperation.
Deleted DialTool from NewTool.
Added statement to change tools in NewTool.
Changed LastToolOffset to 'H' LAST ToolOffset# & added IncValue before OfstOff.
Added preset line after OfstOff line.
Changed ResetTool at end of Prog to 'T12'.
.80 update corrections
Jim Radcliffe}

#1 = '#.00'
#2 = '###^0000'
#3 = '00'
#4 = '###.###;0.'
#5 = '*###.###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CRCNormalVectorX#,2)
FORMAT(CRCNormalVectorY#,2)
FORMAT(ToolOffset#,3)

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,4)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,5)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,4)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,5)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab {force N# for proper tag}
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'M98Pł' Tag# 'R' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF FeedConnect?
SeqLabC CRCOffC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
END
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
TagInc
SeqLabC 'M98Pł' Tag# 'R' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC
IF EmptyLine?
FeedC MoveXYZC FeedRateC EOL
ELSE
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
DecelMove2
END
SeqLabC CRCOnC
IF EmptyLine?
FeedC MoveXYZC DecelFeed EOL
ELSE
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst DecelFeed EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CRCOnC
IF EmptyLine?
FeedC MoveXYZC FeedRateC EOL
ELSE
FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqLabC MoveSXYC EOL
IF AutoCycle?
SeqLabC 'M98Pł' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLabC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL {.69 removed RapidC}
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLabC Rapid ZCP2 EOL {.69}
END {.69}
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST NOT TOOL IN SPINDLE )' EOL
END
END
'( TOOL OFFSET SET TO FIRST CLEARANCE PLANE )' EOL
nullfoot EOL
'%' EOL
IF ToolChangeAtHome?
SetHome
END
TagInc
OpenSub
DoSubComment
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Plane 'G80' CRCOff EOL
SeqLabC OpToolID EOL
DoOpComments
DoPostScript
SeqLabC SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC IncValue 'G45Z-0H' ToolOffset# EOL
SeqLabC AbsOrInc Preset ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC IncValue OfstOff 'H' LAST ToolOffset# EOL
SeqLabC AbsOrInc Preset 'Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid Home EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

SeqLab Plane 'G80' CRCOffC EOL
IF NotEqual? LAST Tool# Num#('12')
IF LessThan? Tool# LAST Tool#
SeqLabC 'T12' EOL {index to 12 before going to a smaller tool#}
END
END
SeqLabC OpToolID EOL
DoOpComments
DoPostScript
SeqLabC SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC IncValue 'G45Z-0H' ToolOffset# EOL
SeqLabC AbsOrInc Preset ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC IncValue OfstOff 'H' LAST ToolOffset# EOL
SeqLabC AbsOrInc Preset 'Z0' EOL
SeqLabC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
SeqLabC SpinOn EOL
SeqLabC IncValue 'G45Z-0H' ToolOffset# EOL
SeqLabC AbsOrInc Preset ZCP1 EOL
ELSE
IF NewToolOffset?
SeqLabC IncValue OfstOff 'H' LAST ToolOffset# EOL
SeqLabC AbsOrInc Preset 'Z0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
SeqLabC SpinOn EOL
SeqLabC IncValue 'G45Z-0H' ToolOffset# EOL
SeqLabC AbsOrInc Preset ZCP1 EOL
ELSE
{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
ToolPath
SeqLabC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqLabC RapidC ZCP3C EOL
END
END
NextOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC IncValue OfstOff 'H' ToolOffset# EOL
SeqLabC AbsOrInc Preset 'Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid
IF ToolChangeAtHome?
FirstHome
END
EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
IF NotEqual? Tool# Num#('12')
IF LessThan? NextTool# Tool#
SeqLabC 'T12' EOL {index to 12 before going to a smaller tool#}
END
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC 'M30' EOL
'%' EOL
nullfoot EOL
'%' EOL
Post
'%' EOL
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END