{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{6/14/95, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{8/26/95, L001.85.01.01, Changed ToolAngle to 'A' InFeedAngle#, JR}
{6/18/96, rewrote CheckOffset to clean up and correct Speed bug, JR}

{8/13/96
Initial: Fanuc 10T MS [-] L001.85.01.02
Created: Bridgeport EZPath Lxxx.85
ForUser: Remmele Engineering Plant 50
Control: Bridgeport EZPath
Machine: Romi
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Basic G code output too run EZ-Path control in G Code format.
No Canned Cycles. No Turret! Absolute Arc centers.
PosSideLathe StandardXZArcs.
Jim Radcliffe}

{11/21/96
Initial: Bridgeport EZPath L503.85
Created: Bridgeport EZPath L503.85.1
ForUser: Remmele Engineering Plant 50
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per marked up readout and conversation with Dean Jahnz
Added ToolChng command with comment
Added speed line with comment.
Deleted EOR codes.
Doudled the value of I to get absolute diameter arc centers.
Changed StandardXZArcws to ReverseXZArcs.
Changed comments to use semi-colon instead of parentheses.
Jim Radcliffe}

{1/15/97
Initial: Bridgeport EZPath L503.85.1
Created: Bridgeport EZPath L503.85.2
ForUser: Remmele Engineering Plant 50
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: Modified per fax from Ji Guardini
Added semi-colon as first line of output.
Added '/' between OpToolID and LatheOffset.
Jim Radcliffe}

{10/8/98
Initial: Bridgeport EZPath L503.85.2
Created: Bridgeport EZPath [CT] Lxxx.85
ForUser: Cel Technologies
Control: Bridgeport EZPath
Machine: Bridgeport Turning Center
Develop: Compost2 v1.6b8, Virtual 4.29.63
Comment: Added Constant Surface Speed per marked up readout and conversation with Don Schulze.
Jim Radcliffe}

{3/17/99
Initial: Bridgeport EZPath [CEL] L779.85
Created: BP EZPath DX32R Romi Lxxx.85
ForUser: A-Z
Control: Bridgeport EZPath DX32R CNC
Machine: Romi
Develop: Compost2 PPC 1.7b15, Virtual Gibbs 5.05
Comment: New processor per sample program and conversation with Jerry
Commented out Spindle On and Off codes. Spindle is turned on and off manually.
Added GearRange. M11 0-2000 M12 2001-4000
Commented out tool oofset cancel.
Added spaces between codes.
Changed to leading zero suppression on G and M codes.
Commented out Home on tool change line.
Suppressed output of M00 at end of tool if Prog stop was not selected in Virtual.
Added 'G90' to tools first approach move.
Jim Radcliffe}

{3/19/99
Initial: BP EZPath DX32R Romi L832.85
Created: BP EZPath DX32R Romi L832.85.1
Comment: Changed low gear range setting from 2000 to 2001. S2000 was setting high range!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcRPM1#,6)
FORMAT(SpeedRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
IF NOT Threading?
FeedC
END
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
IF NOT Threading?
FeedRateC
END
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
' G90' Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

DoSpindle:
IF ConstantSurfaceFeed?
CSSOn ' G37'
ELSE
CSSOff ' G36'
END
Speed {SpinOn} ' ' ASCII('39')
IF CWSpindle?
'Forward '
ELSE
'Reverse '
END
'RPM = '
IF ConstantSurfaceFeed?
CalcRPM1#
ELSE
SpeedRPM#
END
RETURN

CheckOffset:
DoEndOpPS
SeqC
IF NewToolOffset?
{LOfstOff '00'}
END
IF LAST ProgStop?
CoolOff
ELSE
IF CoolOff? AND LAST NOT CoolOff?
CoolOff
END
END
EOL
IF LAST ProgStop?
SeqC ' M0' EOL
END
DoOpComments
DoPostScript
IF NewToolOffset?
SeqC OpToolID '/' LatheOffset ToolChng ' ' ASCII('39') 'Tool Change ID=' Tool# EOL
END
IF NewGear?
SeqC GearRange EOL
END
IF LAST ProgStop?
IF ConstantSurfaceFeed?
SeqC ' G38' MaxRPM EOL
END
SeqC DoSpindle EOL
ELSE
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC ' G38' MaxRPM EOL
END
ELSE
SeqC ' G38' MaxRPM EOL
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC DoSpindle EOL
END
ELSE
SeqC DoSpindle EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC DoSpindle EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC DoSpindle EOL
END
END
END
END
SeqC
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC {SpinOff} EOL
SeqC ' G04 P2000' EOL
SeqC Speed {InverseSpinOn} EOL
ELSE
IF Dwell?
SeqC ' G04 P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST Threading?
Rapid
ELSE
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
ReverseXZArcs
SetMaxRPM('4000')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
';' EOL
IF UseComments?
IF ProgramNameComment?
'; ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ABSOLUTE INCHES' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
DoOpComments
DoPostScript
Seq {Rapid Home} OpToolID '/' LatheOffset ToolChng ' ' ASCII('39') 'Tool Change ID=' Tool# EOL
SeqC GearRange EOL
IF ConstantSurfaceFeed?
SeqC ' G38' MaxRPM EOL
END
SeqC DoSpindle EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC NewHome {LOfstOff '00'} CoolOff EOL
IF LAST ProgStop?
SeqC ' M0' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq {Rapid Home} OpToolID '/' LatheOffset ToolChng ' ' ASCII('39') 'Tool Change ID=' Tool# EOL
SeqC GearRange EOL
IF ConstantSurfaceFeed?
SeqC ' G38' MaxRPM EOL
END
SeqC DoSpindle EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqC ' G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqC {SpinOff} EOL
SeqC ' G04 P2000' EOL
SeqC Speed {SpinOn} EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF Threading?
Rapid
ELSE
IF CannedCycle?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC FirstHome {OpToolID '00'} CoolOff EOL
SeqC EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
END
Close