{Change Comments ***********************************************************}

{7/28/97,
Initial: Servo II [DE] M108.89
Created: Servo II [DTI] MXXX.89
For: Diversified Technologies Inc.
Added literal 'M00' and 'M25' to FirstOp for first Tool Change, {M25 is a full quill retract}
Added a literal 'M25' to just before move to Home in NewTool and end of Program,
eliminated IF NewToolOffset? case in SameTool, added literal 'M25' to all SameToolcases,
MPK}

{7/30/97,
Initial: Servo II [DTI] MX63.89
Created: Servo II [DTI] MX63.89.1
For: Diversified Technologies Inc.
Added tool calls to FirstOp and NewTool,
Added tool cancel (literal 'T0' to NewTool and end of program,
MPK}

{3/21/98
Updated & Modified: Servo II [DTI] MX63.89.1
Created: Servo II [DTI] MX63.89.2
For: Diversified Technologies Inc.
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Pete Staats of Diversified Technologies Inc.
Updated for Catalyst v3.35C per Fanuc 6M M001.89b Format.
Added G17 to Select XY Plane Edit Field of ComPost2 Work Planes Dialog.
Added G18 to Select XZ Plane Edit Field of ComPost2 Work Planes Dialog.
Added G19 to Select YZ Plane Edit Field of ComPost2 Work Planes Dialog.
Added missing ReverseXZArcs command at setup and initializations.
Added CRCOff command to StrtPos block at FirstOperation and NewTool.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.##;0.'
#7 = '####.##;0.'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ZDepth#,4)
FORMAT(CalcZSurf#,4)
FORMAT(CalcZFmSurf#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Dwell#,6)
FORMAT(FeedEntry#,7)
FORMAT(Tag#,8)
FORMAT(CallMasterNum#,8)
FORMAT(Repeats#,8)
FORMAT(Parts#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'( ' OperationComment$ EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'( ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'C' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'C' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'P' Tag# EOL { SubID }
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC 'P' Tag# Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
IF WorkFixtureOffsets?
'This processor does not support Multiple Parts with Work Fixture Offsets' EOL
ELSE
TagInc
SeqC 'P' Tag# Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

DrillCycle:
SeqC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
RLevel 'T' CalcZSurf# 'D' CalcZFmSurf# Dwell Peck
IF Peck? AND PeckChipBreaker?
'P' Retract#
END
EOL
RETURN

DoCycle:
IF Tap?
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
SeqC ZCP2 EOL
END
SeqC Feed MoveSZ EOL
IF Dwell?
SeqC 'G4F' Dwell# EOL
END
SeqC ZCP2 EOL
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
SeqC Rapid ZCP1 EOL
END
ELSE
DrillCycle
IF AbsoluteMoves?
SeqC IncValue 'X0.Y0.' EOL { execute cycle with incremental move of zero }
SeqC AbsValue DrillOff ZCP1 EOL { retract to CP1 }
ELSE
SeqC 'X0.Y0.' EOL { execute cycle with incremental move of zero }
SeqC DrillOff ZCP1 EOL { retract to CP1 }
END
END
RETURN

DrillPath:
EachFeat
IF FirstFeat?
SeqC MoveSXYC EOL
IF LastFeat?
DoCycle
ELSE { there is more than 1 hole so put the cycle in a sub! }
TagInc
SeqC 'P' Tag# '01' EOL
StartSub
DoCycle
SeqC EndSub EOL
CloseSub
END
ELSE
SeqC Rapid MoveSXYC EOL
SeqC 'P' Tag# '01' EOL
END
NextFeat
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC 'P' Tag# '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
SeqC FormatArc ArcFeedC EOL
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC 'P' Tag# '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC 'P' Tag# '01' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
SeqC WFOStuff EOL
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
TagInit
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + C move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - C move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ EOL
END
IF ProgramComment?
'( ' ProgramComment$ EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
SeqC 'G70' AbsOrInc 'G99' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqC 'M25' EOL {Full Quill Retract}
SeqC 'M00' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqC WFOStuff EOL
SeqC OpToolID EOL
CheckPass
SeqC Plane AbsOrInc CRCOff Rapid StrtPos EOL
SeqC ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC AbsOrInc Rapid StrtPos EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC 'T0' EOL
SeqC RapidC EOL
SeqC 'M25' EOL {Full Quill Retract}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC RapidC Home EOL
END

{Start new Operation}

SeqC 'M00' EOL { Manual ToolChng }
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqC WFOStuff EOL
SeqC OpToolID EOL
CheckPass
SeqC PlaneC AbsOrInc CRCOff Rapid StrtPos EOL
SeqC ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC AbsOrInc Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC 'M25' EOL {Full Quill Retract}
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
ELSE
SeqC 'M25' EOL {Full Quill Retract}
GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
END
END
END
END {common point for all operations}

{output all feed rates}
SeqC 'E' FeedEntry#
IF Milling?
FeedRate
END
EOL

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF Tap? OR RetractToCP1?
DrillPath
ELSE
DrillCycle
IF CallMasterOp?
SeqC 'P' CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
SeqC 'P' Tag# '01' EOL
StartSub
SeqC StrtPos EOL
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
SeqC StrtPos EOL
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
END
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC 'T0' EOL
SeqC RapidC EOL
SeqC 'M25' EOL {Full Quill Retract}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END