{Change Comments ***********************************************************}

{7/24/90, Updated: Yasnac MX2 Matsuura M017.55 to .72.1 format, JR}
{7/30/90, Replaced SetSRXYZero with SetSRXYtoSP, JR}

{4/03/91
Modified: Yasnac MX2 Matsuura M017.73
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{9/29/91, Made from M017.79, added 4 axis capabilities, wfg}
{11/11/91, added 4 axis feed, wfg}

{*
6-11-92, v.80.03, [cwh]
added pre tool selection using 'PreTool'.
changed SpinOff from M5 to M19 and then hard coded an M5 at the end.
combined tool number and tool change (M06) lines.
6-12-92, [cwh]
changed arc format to use R when less than 175 degrees.
*}

{11/18/92, Updated to .81 format, minor corrections, JR}

{11/18/92 - 4/6/93
Copied & modified: Yasnac MX3 4A Mat A001.81
For: Unitek
Control: Servo II
Machine: Supermax YCM-40
Deleted Plane commands from MachSpec, no plane selection, arcs in the Z axis are segmented.
Three different feed addresses used:
X & Y use an F
Z uses an E - Changed FeedEnt to 'E' FeedEntry#.
C uses a D - Calculating based on FeedContour# and ZDepth#
Talked with Greg at Servo on 4/6/93 and modified usage of feeds per that discussion.
All FeedRates are called once at the beginning of the operation.
Only left in other places where they could have been modified due to ConstantSurfaceFeed.
No ToolChng command, using M00 for a manual tool change.
Coolant is M7, no spindle speed command, SpinOn only used, no EOR codes, or ProgID.
Comments use an open paren only.
Modified Subroutine commands:
Changed NewProg to TagInc
Deleted SubCall & RepLab
Changed CallLab to 'P' Tag#
Changed RepCycs to Repeats#, outputting '01' for only 1 repeat or part.
WFOs by PostScript request only, they are the same code as the tool offsets.
T code calls Diameter, X, Y, Z & C offsets.
No drill cycles, added manual drilling & put cycle in sub when there is more than 1 feature.
CRCOff with last linear feature.
Jim Radcliffe}

{6/25/93, v.81.4
For: general
By: [cwh]
Added the SetOpArcSegAcc to the EachOp/NextOp loop to set the arc segmentation
accuracy value to the value entered in ncCAM.
}

{9/21/94
Updated: Servo II A006.81.4
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M A001.81.2e Format.
Reorganized Prog Numeric Format Definitions to conform with master.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Minor modification to StartPos sub.
Added RotaryMove sub.
Minor modification to StdLine sub.
Added DrillStuff sub.
Contains code previously handled at toolPath PointFeat.
Minor modification to toolPath PointFeat, RapidFeat and LineFeat.
Minor modification to autoCycCutSub2 sub.
Moved UnSkipZ from finishSub1 to zonlyRep where SkipZ is set.
Added ckCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at ckCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at toolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at toolPath.
Outputs G40 for ZMoveOnly Feature at toolPath RapidFeat.
Modified Rotary PointFeat to support AutoCycles and Drilling better at toolPath.
Changed order of RapidFeat and LineFeat handling.
Checks for RotaryMill before other types.
Deleted FIRST modifier for CalcSCAng at StartPos sub.
It was Modifying all Operations by FirstOperation conditions.
Moved condition for checking IF RotaryMill? AND YZPlane? to common point.
Changed Post command to CloseSub Post2 at end of Prog
DWB}

{9/22/94
Copied: Servo II A006.81.4
Created: Servo II M693.81.5
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Versions: Catalyst v2.05.54C/Compost 4.21.22
Changes made per Pete Jackson.
Stripped all 4 Axis code for purpose of converting to 3 Axis Mill for Virtual.
Deleted StartPosX# from Prog Numeric Format Definitions.
Deleted StartPosY# from Prog Numeric Format Definitions.
Deleted SetScale('1') at restoreScale sub.
Deleted StartPos sub.
Deleted RotaryMove sub.
Deleted all IF RotaryMill? conditions.
Deleted all calls to RotaryMove sub.
Changed all calls to StartPos sub to StrtPos command.
Deleted SetOpArcSegAcc at Start of post processing.
Deleted literal 'C00.000', Home Reference Position at FirstOperation.
Deleted IF RotaryMill? AND YZPlane? condition at common point.
Deleted FORMULA for RotaryMill FeedRate at common point.
}

{2/9/96, Updated .81 version to .84, MPK}

{2/24/96
Copied: Servo II M693.84
Created: Servo II [MIDAS] M946.84
For: The Midas Company
Changes made per Bill Garland.
Removed G92 Line & Replaces it with G0X0Y0 literal
Added spindle speed to all M3 lines
Replaced OffstOff w/ M25 Literal
JM}

{3/22/96, Tested zonlyRepAutoCycle, Incremented number to .87, MPK}

{5/24/96
Modified: Servo II [TMC] M946.87
Created: Servo II [TMC] M946.12
For: The Midas Company
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Updated for Catalyst v3.0 per Fanuc 6M M001.12 Format.
Changed literal 'G0X0X0' to 'G0X0Y0' at FirstOperation.
This was a typo, see 2/24/96.
Commented out CRCOnC at ckCRC sub.
Customer requested no CutterRadiusCompensation.
Replaced manual Drill Cycles with Servo Version 4.0 Canned Drill Cycles.
Problems corrected:
1. Tagging now handles all situations, including special DrillSub handling.
Was not working for most nested conditions.
2. MultipleParts WorkFixtureOffsets no longer calls startSub.
Was causing OpenSub without corresponding CloseSub.
3. Deleted all remaining FeedEnt/FeedRate/DecelRate/ArcFeedC commands.
FeedRate is output at CommonPoint per program manual rules.
4. Deleted all NewWFO related commands.
Control does not support WorkFixtureOffsets.
Changes made per Bill Garland at The Midas Company.
DWB}

{5/24/96, M946.12, Updated for Catalyst v3.0 per Fanuc 6M (NW) D001.12 Format, DWB}

{07/15/98,
Initial: Servo II [TMC] D946.12
Created: Servo II [TMC] D946.12.1
For: The Midas Company

Changes to Prog:
1) Per Customer request - deleted previous Servo Canned Drill Cycles. Replaced
with manual Drill cycles from Fanuc 6M NoSubs NoDr M001.
2) drillPoint - This subroutine used to be DrillFeat, just renamed.
3) opGuts - Added code so that Zmoves will be in a subroutine.
CDH}

{07/22/98,
Initial: Servo II [TMC] D946.12.1
Created: Servo II [TMC] D946.12.2
For: The Midas Company

Changes to Prog:
1) opGuts - Added TrackZNO# SPZ# to right before toolPath call in Drilling.
CDH}

{03/05/99,
Initial: Servo II [TMC] D946.12.2
Created: Servo II Acra [WE] Dxxx.16
For: Wyatt Engineering

Changes to Form:
1) Default Formats - Changed N format to ####0^b

Changes to Prog:
1) Updated processor to .16 D-style format.
2) g52 - modified all g52 sub names to g49. This post outputs G49 offsets
instead of g52.
3) Flags/Variables - Modified all flags and variables to the .16 standard.
Changed all custom flags and variables to use numbers 22 and after.
4) NotSameToolWfo/SameToolWFO - Deleted these subs and all calls to these subs.
5) csCancel - Added this sub. It will output a 'G94X0.Y0.Z0.' at the end of an
op if a G94 offset has been output, or if there's a cs change.
6) opGuts - Drill cycles have been put back into the post. Verified cycles with
Servo manual.
7) FirstOp/NewTool/SameTool - Numerous changes specified by the customer.
CDH}

{03/25/99,
Initial: Servo II Acra [WE] DQ34.16
Created: Servo II Acra [WE] BQ34.16.1
For: Wyatt Eng.

Changes To Prog:
1) toolPath - Added unconditional XY movement if first feat of a drilling op.
XY coordinates need to be repeated for drilling cycles.
2) Modified post to output like B-style instead of D-style.
3) CSAngleA/CSAngleB - deleted contents of these subs. Customer has manual indexer.
4) initOp - Deleted ToolChangeAtHome?. This is already being called in firstOp1.
Deleted literal 'G0X0Y0'.
CDH}

{03/25/99,
Changed to Metric.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.###;0.'
#5 = '#######0'
#6 = '###.##;0.'
#7 = '00'
#8 = '*#####.##;0.'
#9 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(ToolDiameter#,4)
FORMAT(SUB#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(CalcZSurf#,4)
FORMAT(Peck#,4)
FORMAT(Retract#,4)
FORMAT(CalcZFmSurf#,4)
FORMAT(ZDepth#,4)
FORMAT(TrackZ#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Dwell#,6)
FORMAT(FeedEntry#,6)
FORMAT(Parts#,7)
FORMAT(Tag#,7)
FORMAT(CallMasterNum#,7)
FORMAT(Repeats#,7)
FORMAT(CSOffsetA#,8)
FORMAT(CSOffsetB#,8)
FORMAT(RapidF#,9)

{Prog Subroutines ****}

restoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

csWFO:
'G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

calccsWFO: {(iPart-1)*NumOfCS#)}
'G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

cSG49:
SeqC 'G94X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SetFlag('22')
RETURN

g49Stuff:
IF NOT Flag?('7') AND NOT WFOCS?
IF FirstOperation? OR NewTool? OR ChangeCS?
IF MultipleParts?
IF WorkFixtureOffsets?
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
END
ELSE
cSG49
END
END
END
RETURN

doRotationComment:
'( CS#' CS# ' - ' CSComment$
IF Flag?('6') { TRUE = B-Style Output, FALSE = C-Style Output }
IF AAxisAvail?
' C-AXIS: ' CSOffsetA#
END
IF BAxisAvail?
' B-AXIS: ' CSOffsetB#
END
END
EOL
RETURN

doSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'( ' OperationComment$ EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'( ' ToolComment$ EOL
END
restoreScale
doRotationComment
END
RETURN

csAngleA:
{ Customer has Manual Indexer }
RETURN

csAngleAC:
IF AChange?
csAngleA
END
RETURN

csAngleB:
{ Customer has Manual Indexer }
RETURN

csAngleBC:
IF BChange?
csAngleB
END
RETURN

psInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

psStuff:
RETURN

doPostScript:
psInit
EachPS
SeqC PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqC EndOpPS EOL
psStuff
NextPS
RETURN

entryMove:
IF FeedEntry?
SeqC Feed ZIn
IF FirstOperation? OR NewTool?
FeedEnt
ELSE
FeedEntC
END
EOL
ELSE
SeqC RapidC ZIn EOL
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedRate }
END
END
RETURN

startSub:
OpenSub
'P' Tag# EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

stdSub:
SeqC 'P' Tag# Repeats# EOL
startSub
RETURN

finishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

finishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
TagDown
CloseSub
SeqC Preset UnshftRC EOL
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

toggleIncDecWFO:
IF Flag?('3') { Incrementing WFOs in effect }
SetFlagF('3')
ELSE { Decrementing WFOs in effect }
SetFlag('3')
END
RETURN

openMP:
NewProg
IF Flag?('7') OR WFOCS?
startSub
SaveCSProg
SaveCSOpStart
ELSE
IF WorkFixtureOffsets?
'This processor does not support Multiple Parts with Work Fixture Offsets' EOL
ELSE
TagUp TagInc
SeqC 'P' Tag# Parts# EOL
startSub
END
END
RETURN

docsWFOOps:
IF Flag?('7')
SeqC SetWFO EOL
EachCSOp
SeqC 'G94X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ELSE
EachCSOp
SeqC calccsWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
END
RETURN

closeMP:
IF Flag?('7') OR WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
docsWFOOps
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
docsWFOOps
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
'This processor does not support Multiple Parts with Work Fixture Offsets' EOL
ELSE
SeqC absOrIncC EOL
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
TagDown
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

subCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
startSub
SaveCSProg
END
END
RETURN

doAbsOrInc:
IF Flag?('1') { milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') { milling ZShiftOnly SepSubs/DrillSubs activated }
SeqC absOrIncC EOL
END
RETURN

formatArc:
doAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
{CRCOnC} { Not Supported }
END
END
RETURN

formatLine:
doAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ CRCOffsetC not supported }
RETURN

getACEPXY:
SetACSPCompF
Save# Num#('1') SPX# { Status Register Variable for X Axis }
Save# Num#('2') SPY# { Status Register Variable for Y Axis }
SetACSPComp
RETURN

setSRXYtoACEP:
SetPass1
SetSRXYtoEP
LoadFeat Num#('0') Num#('0') Num#('0')
TrackXNO# ADD# Recall# Num#('1') SPX# { Status Register Variable for X Axis }
TrackYNO# ADD# Recall# Num#('2') SPY# { Status Register Variable for Y Axis }
RETURN

toolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF LastFeat?
getACEPXY
END
IF FirstFeat?
SeqC MoveSX MoveSY EOL
ELSE
SeqC MoveSXYC EOL
END
SeqC 'P' Tag# '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC doDrillAbsOrInc
IF FirstFeat?
SeqC MoveSX MoveSY EOL
ELSE
MoveSXYC
END
EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqC formatLine ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC formatArc ArcFeedC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqC incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqC absOrIncC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
TagUp TagInc
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
TagDown
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqC absOrIncC Connect StrtPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusInc EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
SeqC 'P' Tag# '01' EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqC ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
TrackZNO# ADD# FIRST SPZ# MUL# RepsLess1# RepeatZ#
RETURN

zonlyRepAutoCycle:
autoCycPat {write pattern moves and main calls}
startSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC incValueC StrtPosC EOL
absOrIncC
END
END
SetStatusOn
doSepSubZMoves
SetStatusOff
NextCycle
SetStatusOn
autoCycCutSub1 {build element sub}
TrackZNO# FIRST SPZ#
autoCycCutSub2
IF FeedConnect?
IF NOT AbsValue?
setSepSubZ
END
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
TagDown
CloseSub
{Element shift, not pattern}
TagDown
RETURN

zonlyRep:
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC StrtPosC EOL
END
END
doSepSubZMoves
NextCycle
startSub
TrackZNO# FIRST SPZ#
toolPath
finishSub1
SeqC EndSub EOL
TagDown
CloseSub
IF FeedConnect? AND NOT AbsValue?
setSepSubZ
END
RETURN

doPeck:
IF NOT Flag?('21')
SetScale('1')
IF GreaterThan? SUB# Recall# Num#('4') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('4') SUB# Recall# Num#('4') Peck# {Save#1 = OldZ - Peck# = NewZ}
restoreScale
SeqC Feed 'Z' TrackZ# MUL# Recall# Num#('4') NumSc#('1') FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
SeqC Rapid ZCP2 EOL {move to CP2}
END
SeqC RapidC 'Z' TrackZ# ADD# Recall# Num#('4') Retract# EOL {move to RetractZ}
ELSE
restoreScale
SeqC Feed 'Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid ZCP1 EOL {move to CP1}
ELSE
SeqC Rapid ZCP2 EOL {move to CP2}
END
SetFlag('21')
END
END
RETURN

drillPoint:
SeqC ZCP2C EOL
IF Peck?
SetFlagF('21') { done flag }
SetScale('1')
Save# Num#('21') ClearancePlane2#
restoreScale
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck doPeck
ELSE
SeqC Feed 'Z' ZDepth# FeedEntC EOL
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
IF FIRO?
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
IF FIFO?
SeqC ZCP2 EOL
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
END
END
IF TAP?
SeqC InverseSpinOn EOL
SeqC ZCP2 EOL
SeqC SpinOn EOL
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
END
END
END
RETURN

checkPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
IF NOT Flag?('7')
ClearCSOffset
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

opGuts:

{output all feed rates}
SeqC 'E' FeedEntry#
IF milling?
FeedRate
END
EOL

IF milling?
SeqC ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqC CRCOffC ZCP3C EOL
setSRXYtoACEP
ELSE
IF FIFO?
SeqC CRCOffC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC CRCOffC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC Cycle
'C' ClearancePlane2#
'T' CalcZSurf#
'D' CalcZFmSurf#
IF Dwell?
'B' Dwell#
END
IF Peck?
IF PeckChipBreaker?
'P' Retract#
END
'I' Peck#
END
EOL
IF CallMasterOp?
SeqC 'P' CallMasterNum# '01' EOL
skipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
TagUp NewMasterTag
SeqC 'P' Tag# '01' EOL
startSub
toolPath
SeqC EndSub EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
toolPath
END
END
setDrillEndOpZ
SeqC DrillOff Rapid ZCP3 EOL
END
END
RETURN

progStart:
InitProg
TagInit
StandardXZArcs
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('3') Num#('0') { Status Register Variable for Z Axis }
Save# Num#('21') Num#('0') { Pecking }
SetFlagF('1') { milling ZShiftOnly SepSubs }
SetFlag('3') { Incrementing WFOs in effect }
SetFlag('4') { This post supports IncWFO/DecWFO }
SetFlag('6') { TRUE = B-Style Output, FALSE = C-Style Output }
SetFlagF('7') { TRUE = D-Style Output }
SetFlagF('8') { TRUE = D-Style Output, FALSE = Local G52-WFO Coordinates }
SetFlagF('21') { Pecking }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
END

IF NOT Flag?('7')
IF Equal? NumOfCS# Num#('1') { 3 Axis Part - Output M-Style }
SetFlag('7')
ELSE
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('1')
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to '
IF Flag?('7')
'non'
ELSE
'G52'
END
'-wfo style output. )' EOL
END
END
ELSE
SetFlag('7')
END
ELSE
IF LTEqual? NumOfCS# Num#('1') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
END
END
END
END
RETURN

csCancel:
IF NewTool?
IF Flag?('22') OR ChangeCS?
SeqC 'G94X0.Y0.Z0.' EOL
SetFlagF('22')
END
ELSE
IF SameTool?
IF ChangeCS?
SeqC 'G94X0.Y0.Z0.' EOL
SetFlagF('22')
END
END
END
RETURN

initOp:
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ EOL
END
IF ProgramComment?
'( ' ProgramComment$ EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
restoreScale
SeqC 'G71' AbsOrInc 'G99' EOL
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
doOpComments
Seq OpToolID EOL
doPostScript
RETURN

firstOp2:
g49Stuff
SeqC ZCP1 EOL
SeqC SpinOn Speed EOL
checkPass
SeqC Plane AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
RETURN

firstOp3:
SeqC CoolOn EOL
RETURN

newToolOp1:
SeqC CoolOff EOL
SeqC RapidC 'M25' EOL
csCancel
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqC absOrIncC Rapid Home SpinOff EOL
END
SeqC 'M00' EOL { Manual ToolChng }
RETURN

newToolOp3: {Start new Operation}
doOpComments
Seq OpToolID EOL
doPostScript
RETURN

newToolOp4:
g49Stuff
SeqC ZCP1 EOL
SeqC SpinOn Speed EOL
checkPass
SeqC Plane AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
RETURN

newToolOp5:
SeqC CoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
csCancel
SeqC RapidC 'M25' EOL
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
Seq OpToolID EOL
g49Stuff
SeqC ZCP1C EOL
SeqC PlaneC AbsOrInc Rapid StrtPos csAngleA csAngleB Speed EOL
IF Last ProgStop?
SpinOn
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
RETURN

end1:
SeqC CoolOff EOL
SeqC RapidC 'M25' EOL
IF Flag?('22')
SeqC 'G94X0.Y0.Z0.' EOL
END
RETURN

end2:
doEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC absOrIncC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
RETURN

end3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END
RETURN

mpallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
NewToolOp1
newToolOp2 {to tool change, CS problem}
subCSMP
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END
opGuts
NextOp
end1
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp
IF FirstOperation?
firstOp1
firstOp2
openMP
firstOp3
ELSE
IF NewTool?
NewToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
openMP
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END
opGuts
NextOp
end1
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
SeqC AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
ELSE
IF NewTool?
closeMP
NewToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
SeqC AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END
opGuts
NextOp
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
NewToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
NextOp
end1
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mpallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END