{Change Comments ***********************************************************}

{7/24/90, Updated: Yasnac MX2 Matsuura M017.55 to .72.1 format, JR}
{7/30/90, Replaced SetSRXYZero with SetSRXYtoSP, JR}

{4/03/91
Modified: Yasnac MX2 Matsuura M017.73
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{9/29/91, Made from M017.79, added 4 axis capabilities, wfg}
{11/11/91, added 4 axis feed, wfg}

{*
6-11-92, v.80.03, [cwh]
added pre tool selection using 'PreTool'.
changed SpinOff from M5 to M19 and then hard coded an M5 at the end.
combined tool number and tool change (M06) lines.
6-12-92, [cwh]
changed arc format to use R when less than 175 degrees.
*}

{11/18/92, Updated to .81 format, minor corrections, JR}

{11/18/92 - 4/6/93
Copied & modified: Yasnac MX3 4A Mat A001.81
For: Unitek
Control: Servo II
Machine: Supermax YCM-40
Deleted Plane commands from MachSpec, no plane selection, arcs in the Z axis are segmented.
Three different feed addresses used:
X & Y use an F
Z uses an E - Changed FeedEnt to 'E' FeedEntry#.
C uses a D - Calculating based on FeedContour# and ZDepth#
Talked with Greg at Servo on 4/6/93 and modified usage of feeds per that discussion.
All FeedRates are called once at the beginning of the operation.
Only left in other places where they could have been modified due to ConstantSurfaceFeed.
No ToolChng command, using M00 for a manual tool change.
Coolant is M7, no spindle speed command, SpinOn only used, no EOR codes, or ProgID.
Comments use an open paren only.
Modified Subroutine commands:
Changed NewProg to TagInc
Deleted SubCall & RepLab
Changed CallLab to 'P' Tag#
Changed RepCycs to Repeats#, outputting '01' for only 1 repeat or part.
WFOs by PostScript request only, they are the same code as the tool offsets.
T code calls Diameter, X, Y, Z & C offsets.
No drill cycles, added manual drilling & put cycle in sub when there is more than 1 feature.
CRCOff with last linear feature.
Jim Radcliffe}

{6/25/93, v.81.4
For: general
By: [cwh]
Added the SetOpArcSegAcc to the EachOp/NextOp loop to set the arc segmentation
accuracy value to the value entered in ncCAM.
}

{9/21/94
Updated: Servo II A006.81.4
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M A001.81.2e Format.
Reorganized Prog Numeric Format Definitions to conform with master.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Minor modification to StartPos sub.
Added RotaryMove sub.
Minor modification to StdLine sub.
Added DrillStuff sub.
Contains code previously handled at ToolPath PointFeat.
Minor modification to ToolPath PointFeat, RapidFeat and LineFeat.
Minor modification to AutoCycCutSub2 sub.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 for ZMoveOnly Feature at ToolPath RapidFeat.
Modified Rotary PointFeat to support AutoCycles and Drilling better at ToolPath.
Changed order of RapidFeat and LineFeat handling.
Checks for RotaryMill before other types.
Deleted FIRST modifier for CalcSCAng at StartPos sub.
It was Modifying all Operations by FirstOperation conditions.
Moved condition for checking IF RotaryMill? AND YZPlane? to common point.
Changed Post command to CloseSub Post2 at end of Prog
DWB}

{9/22/94
Copied: Servo II A006.81.4
Created: Servo II M693.81.5
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Versions: Catalyst v2.05.54C/Compost 4.21.22
Changes made per Pete Jackson.
Stripped all 4 Axis code for purpose of converting to 3 Axis Mill for Virtual.
Deleted StartPosX# from Prog Numeric Format Definitions.
Deleted StartPosY# from Prog Numeric Format Definitions.
Deleted SetScale('1') at RestoreScale sub.
Deleted StartPos sub.
Deleted RotaryMove sub.
Deleted all IF RotaryMill? conditions.
Deleted all calls to RotaryMove sub.
Changed all calls to StartPos sub to StrtPos command.
Deleted SetOpArcSegAcc at Start of post processing.
Deleted literal 'C00.000', Home Reference Position at FirstOperation.
Deleted IF RotaryMill? AND YZPlane? condition at common point.
Deleted FORMULA for RotaryMill FeedRate at common point.
}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.##;0.'
#7 = '####.##;0.'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ZDepth#,4)
FORMAT(TrackZ#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(MUL#,7)
FORMAT(FeedEntry#,7)
FORMAT(Tag#,8)
FORMAT(Repeats#,8)
FORMAT(Parts#,8) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'( ' OperationComment$ EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'( ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'C' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'C' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'P' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC 'P' Tag# Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
TagInc
IF WorkFixtureOffsets?
'This processor does not support Multiple Parts with Work Fixture Offsets' EOL
ELSE
SeqC 'P' Tag# Parts# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'This processor does not support Multiple Parts with Work Fixture Offsets' EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF LastFeat? { Exit Length Feature }
CRCOffC
ELSE
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

DoLastPeck: {OldZ - Peck# ² Depth}
SeqC Feed 'Z' TrackZ# SPZ# EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid ZCP1 EOL {move to CP1}
ELSE
SeqC Rapid ZCP2 EOL {move to CP2}
END
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('1') Peck# SPZ# {if OldZ - Peck# > Depth}
Save# Num#('1') SUB# Recall# Num#('1') Peck# {Save#1 = OldZ - Peck# = NewZ}
SeqC Feed 'Z' TrackZ# Recall# Num#('1') EOL {move to NewZ}
IF PeckFullRetract?
SeqC Rapid ZCP2 EOL {move to CP2}
END
SeqC RapidC 'Z' TrackZ# ADD# Recall# Num#('1') Retract# EOL {move to RetractZ}
END
RETURN

DoDrillCycle:
SeqC ZCP2C EOL
IF Peck?
Save# Num#('1') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
ELSE
SeqC Feed 'Z' ZDepth# EOL
IF Dwell?
SeqC 'G4F' Dwell# EOL
END
IF FIRO?
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
IF FIFO?
SeqC ZCP2 EOL
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
END
END
IF TAP?
SeqC InverseSpinOn EOL
SeqC ZCP2 EOL
SeqC SpinOn EOL
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
END
END
END
RETURN

DrillStuff:
IF FirstFeat?
IF LastFeat?
DoDrillCycle
ELSE
TagInc
SeqC 'P' Tag# '01' EOL
StartSub
DoDrillCycle
SeqC EndSub EOL
CloseSub
END
ELSE
SeqC 'P' Tag# '01' EOL
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL {.80.01}
IF AutoCycle?
SeqC 'P' Tag# '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
DrillStuff
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
CRCOffC {.70}
END
SeqC RapidC MoveXYZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC {.82}
END
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
SeqC FormatArc ArcFeedC EOL
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
SeqC 'T' NewWFO# EOL
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC 'P' Tag# '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC 'P' Tag# '01' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + C move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - C move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ EOL
END
IF ProgramComment?
'( ' ProgramComment$ EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
SeqC 'G70' AbsOrInc 'G99' EOL
'( Set Home Reference Position' EOL
SeqC 'G93X00.0000Y00.0000Z00.0000' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
Seq OpToolID EOL
DoPostScript
WFOStuff
SeqC SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC RapidC OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC RapidC Home EOL
END

{Start new Operation}

SeqC 'M00' EOL { Manual ToolChng }
DoOpComments
Seq OpToolID EOL
DoPostScript
WFOStuff
SeqC SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC RapidC OfstOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos SpinOn EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC RapidC OfstOff EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}

{output all feed rates}
SeqC 'E' FeedEntry#
IF Milling?
FeedRate
END
EOL

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
ToolPath
SeqC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC RapidC OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END