{Change Comments ***********************************************************}

{
10/24/94 [cwh]
B001.81.4 ( from B001.81.3 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/8/94
Modified: Fanuc 6M (FW) B001.81.4
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{
12/01/94
B001.81.6
Changed FirstOp3 to call out A0B0 to move to the first CS.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.

Added RecallWFO sub-routine to NotSameToolWFO and SameToolWFO to ouput the current fixture offset
and A0B0. Added for easier restarts at the machine. Both are only called from NoMPs.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.
}

{
12/02/94
Changed version number to .00 from .81
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/08/94
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added WFO1 and A0B0 if AxisAvail to End2:
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/09/94
Fixed RecalWFO to check AAxisAvail? and BAxisAvail?
Cleaned up FirstOp3 to use new checks placed in CSAngleA and CSAngleB
TH}

{
Format: Fanuc 6M (FW) B001.00.03
12/19/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fanuc 6M (FW) B001.00.04
1/10/95
NewToolOp3 now has an AbsOrInc on the line that calls out the Plane 'G80' CRCOff
NewToolOp5 no longer has the AbsOrInc command
NewToolOp5b has been created and has the AbsOrInc command
Changed MP1ToollAllPfu to call NewToolOp5b
Added AbsOrInc and Rapid to the FirstOperation? section of MP1ToollAllPXcp
Added Rapid to the NewTool? section of MP1ToollAllPXcp
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
MP1ToollAllPXcp, MP1ToollAllPFU, and MPallTools1P now output WFO if NOT WorkFixtureOffsets?
TH}

{
Format: Fanuc 6M (FW) B001.00.05
1/13/95
Replaced TrackZNO# ZDepth# with TrackZNO# FIRST SPZ# in the drilling section
Formatted TrackZNO# to #4
}

{
Format: Fanuc 6M (FW) B001.00.06
2/15/95
Fixed RecallWFO: to output correct WFO# if WFOCS
TH}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Fanuc 6M (FW) B001.10
7/27/95
Added G52 style output for too many coordinate systems
Updated to .10 format
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/29/96
Copied: Fanuc 6M (FW) B001.11
Created: Meldas 500M 0KK B970.11
For: Armstrong Blum
Machine: Mitsubishi CNC
Control: Meldas 500M 0KK Series
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.07/Compost 4.21.34.1/1.0a
Changes made per Jeff Kaiser and Lee Hench of Armstrong Blum.

Mach Spec changes:
Change Sub Call Label from P to L in Strings 2 Dialog.
Change Sub Repate Label from L to P in Strings 2 Dialog.
Change Program ID Label from O to L in Strings 2 Dialog.
Changed Call Sub from M98 to G22 in Commands 3 Dialog.
Changed Return From Sub from M99 to G23 in Commands 3 Dialog.
Changed End Program from M30 to M2 in Commands 4 Dialog.
Changed Optional End Program from M2 to M30 in Commands 4 Dialog.
Changed First Work Fixture Offset from G54 to G1 in Commands 5 Dialog.
Changed Last Work Fixture Offset from G59 to G48 in Commands 5 Dialog.
Changed Format for Address D, from #0 to ##0 in Default Formats Dialog.
Changed Format for Address F, from ###.#0;0. to ####.###;0. in Default Formats Dialog.
Changed Format for Address H, from #0 to ##0 in Default Formats Dialog.
Changed Format for Address L, from ###0 to #######0 in Default Formats Dialog.
Changed Format for Address N, from ###0 to ####0 in Default Formats Dialog.
Changed Format for Address O, from ###0 to #######0 in Default Formats Dialog.
Changed Format for Address S, from ###0 to ####0 in Default Formats Dialog.
Added Format for Address U, V and W, ####.####;0. in Default Formats Dialog.

Prog Changes:
Corrected problem with NotSameToolWFO sub.
The problem concerned ToolChanges where WFOCS? = TRUE but ChangeCS? = FALSE.
Post was outputting 'G' NewWFO# which equals FIRST WFO.
Post should have called CSWFO instead.
M001 forces WFO for FirstOperation and NewTool, even if it remains the same.
NOTE: This is probably a global bug with most, if not all, Advanced Mill Posts.

Changed NumOfCS from 6 to 48 two places at ProgStart.
Post supports G54.1 P1 to P48 WorkFixtureOffsets.
Changed literal 'G' to 'G54.1P' at CSWFO sub.
Changed literal 'G' to 'G54.1P' at CalcCSWFO sub.
Changed literal 'G' to 'G54.1P' two places at NotSameToolWFO sub.
Moved call to InitOp sub outside of EachOp/NextOp loop at MPallTools1P, MP1ToollAllPfu,
MP1ToollAllPXcp and NoMPs.
Added StartUpStuff sub, called at end of InitOp.
Added EachOp/NextOp loop at StartUpStuff sub.
This loop outputs G10 blocks that load CSOffset values into controls WorkFixtureOffset Table.
The post stores the initial CS# value to Var(1) prior to the loop.
During the loop, CS# is compared to Var(1).
When C# is GreaterThan Var(1), a new G10 block is output, and the new CS# value is stored in Var(1).
This ensures that a CS# is not output a second time.
This can happen when a user does a OneToolAllCSGroups type of output.
Customer has been instructed to introduce the CS# values in incrementing order if they want all
WorkFixtureOffsets to be loaded.
Moved SafeStart block from FirstOp1 to StartUpStuff sub.
Changed Seq to SeqC in SafeStart block at StartUpStuff sub.
Added Rapid to SafeStart block at StartUpStuff sub.
Added IncValue 'G28X0Y0Z0' block at StartUpStuff sub.
Added 'G28B0' block at StartUpStuff sub.
G28 returns the tool and/or table to the first reference position (origin (zero)).
Moved output of WFO1 prior to call of FirstOp1 at MPallTools1P, MP1ToollAllPfu and MP1ToollAllPXcp.
Added call to CSWFO prior to call of FirstOp1 at NoMPs.
Added 'G30Y0.Z0.' at FirstOp1.
G30 returns the tool and or table to the second reference position (origin (zero)).
Added ProgStop at FirstOp1.
Added Seq ' ' EOL block at FirstOp1, NewToolOp3 and SameToolOp1.
Once before DoOpComments, and once after.
Moved Speed SpinOn from FirstOp2 to FirstOp3 and FirstOp3a.
Moved Speed SpinOn from NewToolOp4 to NewToolOp5 and NewToolOp5a.
Follows OfstOn block.
Added PreTool to StrtPos block at FirstOp3 and NewToolOp5.
Added PreTool block at FirstOp3a and NewToolOp5a.
Added DIV# to FORMAT#4 at Prog Numeric Format Definitions.
Added CRCOffset# to FORMAT#5 at Prog Numeric Format Definitions.
Added CkCRCLoad sub.
Sub outputs 'G10L12P' CRCOffset# 'R' DIV# ToolDiameter# Num#('2').
This block loads compensation value into CRCOffset Table when CutterRadiusCompensation = TRUE.
G10 = Tool Compensation Offset input via program.
L10 = Column 10, Cutter Diameter, of Offset Table.
L11 = Column 11, Length Wear, of Offset Table.
L12 = Column 12, Cutter Radius, of Offset Table.
L13 = Column 13, Radius Wear, of Offset Table.
P#0 = CRCOffset#
R####.####;0. = Cutter Radius
Sub is called following OfstOn block at FirstOp3, FirstOp3a, NewToolOp5, NewToolOp5a and
NewToolOp5b.
Flag('5') controls when to output.
SetFlagF(5) occurs at FirstOp3, FirstOp3a, NewToolOp5, NewToolOp5a and NewToolOp5b.
Flag?(5) is tested two places at SameToolOp3.
IF TRUE, CkCRCLoad sub is called.
Moved SpinOff from NewToolOp2 to NewToolOp1.
Changed OfstOff blocks to 'G30Y0.Z0.' at NewToolOp1 and End1.
Changed OfstOff blocks to 'G30Z0.' two places at SameToolOp1.
Deleted IncValue/AbsValue control at NewToolOp1, two places at SameToolOp1 and at End1.
Deleted ToolChangeAtHome condition at NewToolOp2 and End2.
Moved ToolChng block from NewToolOp3 to NewToolOp2.
Changed Plane to PlaneC at NewToolOp3.
Deleted 'G80' CRCOffC at NewToolOp3.
Deleted OpToolID at NewToolOp3.
Added ToolChng 'T0' block at End2.
Deleted condition to unwind A and B axis.
Post now simply outputs 'G28' for each axis.
Changed 'P' CallMasterNum# to 'L' CallMasterNum# for CallMasterOp at IF Drilling.
Added support of Reverse Tap Canned Drilling Cycle.
IF Tap? AND NOT CWSpindle? will output 'G74' instead of Cycle.

Added GetCoolOn sub for support of M58, ThruSpindleCoolant.
PostScript Comments include SetFlood, FloodCoolant, SetThruSpindle and ThruSpindleCoolant.
Flag(6) controls when to call GetCoolOn for normal SameTool Operations.
Added support for non-Canned LongHand Web Drill Cycle at IF Drilling of OpGuts.
Operation must pass IF FIFO? AND OptCyc1? AND FourthCW?
Using FourthDegree# and CalcZSurf# for additional ZPositions.
ZRapidStart position is supported through FourthDegree# PostScript command.
ZRapidEnd position is supported through CalcZSurf# from Process Dialog.
NOTE: Wayne is currently creating an MDD that supports this.
When this is working, replace following:
Replace IF FIFO? AND OptCyc1? AND FourthCW? with FIRIFIRO?.
Replace FourthDegree# with Peck#.
Replace CalcZSurf# with Retract#.
Added necessary PostScript comments.
Added ModCSOffsetB sub.
This sub calculates and outputs a positive B-axis index position from 0Ą to 360Ą.
Uses Var(2).
DWB}

{4/11/96
Modified: Meldas 500M 0KK B970.11
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.11/Compost 4.21.34.1/1.0a
Versions: ncCad 4.33.02/ncEDM 4.33.01/ncPost 4.33.09/Compost 4.21.34.1/1.0a
Versions: ncCad 4.33.02/ncMAT 4.21.19/ncPost 4.33.09/Compost 4.21.34.1/1.0a
Changes made per Jeff Kaiser of Armstrong Blum.
Deleted CkCRCLoad sub, see 3/29/96.
Deleted NewToolOp5b sub.
Changed NewToolOp5b to NewToolOp5 at MP1ToollAllPfu.
Added logic to output T0 instead of PreTool for LastTool at NewToolOp5 and NewToolOp5a.
Deleted literal 'T0' from ToolChng block at End2.
Added SpinOff block for Web Drill Cycle at OpGuts.
Added SpinOn block for Web Drill Cycle at OpGuts.
When Tool reaches the bottom, spindle must be stopped prior to Retract.
Deleted EOR EOL block at end of all Subs.
Occurred at FinishSubG92, CloseMP (3x), SubCSMP, AutoCycCutSub2, ZonlyRepAutoCycle and ZonlyRep.
Changed order of IF WFOCS? OR Flag?('2') boolean to IF Flag?('2') OR WFOCS? at OpenMP and CloseMP.
Argument of Flag was being output at SubID for OpenMP and at EndSub for CloseMP.
Added support for G76 FI-FO Canned Drilling Fine Boring Cycle at IF Drilling.
G85 FI-D-FO is still supported.
Added M19G91G1Y-.005 spindle orientation block at FirstOp3, FirstOp3a, NewToolOp5 and
NewToolOp5a.
Added G53G92X0Y0Z0B0, Safe ReStart Block at end of StartUpStuff.
Made numerous other minor clean up changes.
DWB}

{4/18/96
Modified: Meldas 500M 0KK B970.12.1
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.13/Compost 4.21.34.1/1.0a
Changes made per Jeff Kaiser of Armstrong Blum.
Addec ToolComment for MultipleParts, OneToolAllParts and NOT SameTool at DoSubComment.
Changed Var(2) to Var(50) at ModCSOffsetB.
See 3/29/96.
Needed to free up Vars(1-48) for G10Blocks.
Added G10Block sub.
Called from StartUpStuff.
Outputs correct format for loading WFOs into control table.
Added VarInit sub.
Called from StartUpStuff.
Saves zero to Vars(1-48).
Rewrote StartUpStuff sub.
Necessary to correctly support MultipleParts.
Deleted IncValue 'G28X0Y0Z0' block.
Deleted call to CSWFO.
Deleted 'G53G92X0Y0Z0B0' Safe ReStart Block.
Added GetOfstOff sub.
Called from NewToolOp1, SameToolOp1 (2x) and End1.
Outputs literal 'G30Z0.' unless user processes MultipleParts, OneToolAllParts, ExitClearancePlane
in which case post will output Rapid ZCP1 instead.
Modified Web Drill Cycle at IF Drilling.
Changed FeedEntC to FeedEnt.
Added FeedEnt to second Feed Block.
Added literal 'M19', Spindle Orient Command, at bottom of second hole.
Added IncValue Feed 'Y-.005' following M19 block.
Deleted condition at FirstOp3.
Added AbsOrInc following IncValue block.
Changed G76 Canned Boring Cycle literal 'I.005J.005' to 'J-.005' at IF Drilling.
Modified G84 Tap FeedRate to be 'E' ThreadsPerInch#.
Using DIV# Num#('1') FeedTapIPR#('1') Formula.
Moved Speed SpinOn and GetCoolOn to StrtPos block at FirstOp3, FirstOp3a, NewToolOp5 and
NewToolOp5a.
Moved literal 'G30Y0.Z0.' from NewToolOp1 to NewToolOp2.
Deleted Seq ' ' EOL block at SameToolOp1.
Deleted IncValue OfstOff at End1.
Deleted IncValue 'G28X0.Y0.' at End1.
Added literal 'T0' block at End1.
Moved literal 'G30Y0.Z0.' from End1 to End2.
Moved call to OpenMP prior to calls to FirstOp3 and NewToolOp5 at MP1ToollAllPXcp.
Moved call to CloseMP following calls to NewToolOp1 and End1 at MP1ToollAllPXcp.
Customer wanted ExitClearancePlane output identicle to FullUp output with the exception of the
GetOfstOff sub stuff.
DWB}

{5/24/96
Modified: Meldas 500M 0KK B970.12.2
Created: Meldas 500M 0KK B970.12.3
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Jeff Myers of Gibbs & Associates.
Customer requested method of outputting true G10XYZ coordinate values.
Jeff instructed them to use machine coordinates in stock size dialogue and not use CS#1.
Added restriction of G10 Block for CS#1 at StartUpStuff sub.
Added CS#1 Warning at DoOpComments.
DWB}

{5/30/96
Modified: Meldas 500M 0KK B970.12.3
Created: Meldas 500M 0KK B970.12.4
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Lee Hensch of Armstrong Blum.
Customer reported that some Operations were not outputting a FeedRate.
This was caused by a Pocketing Operation with Rapid Entry whose FeedRate was identicle to
previous Operation.
Added FORMAT#9 at Prog Numeric Format Definitions.
Added RapidF# to FORMAT#9 at Prog Numeric Format Definitions.
Added RapidF# at start of OpGuts sub.
DWB}

{6/26/96
Updated: Meldas 500M 0KK B970.12.4
Modified: Meldas 500M 0KK B970.12.5
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Lee Hensch of Armstrong Blum.
Customer reported problem of outputting true G10XYZ coordinate values, see 5/24/96.
Not sure, but I think it has to do with creating the CSOrigins in machine coordinates.
Distance from Machine Home to Center of Table Rotation is always the same.
Instructed user to us normal dimensions from center of table rotation.
Added SUB# to FORMAT#4 at Prog Numeric Format Definitions.
Subtracting 14.1732 from CSOffsetX# and 31.1023 from CSOffsetZ# at DoCSWFOComment and G10Block.
Deleted changes made on 5/24/96.
Deleted condition to output warning when CS#1 is current at DoOpComments.
Deleted NotEqual CS#1 condition at StartUpStuff.
Customer reported bad CSOffsetB# values.
Changed CSOffsetB# from FORMAT#7 to FORMAT#8 at Prog Numeric Format Definitions.
Modified formulas at ModCSOffsetB.
Post was not calculating negative angles correctly.
Customer requested that Tapping Cycles output Speed and SpinOn at Cycle block, not StrtPos block.
Added GetSpeedOn sub to suppress from StrtPos block of Tapping Cycles.
GetSpeedOn sub is called from FirstOp3, FirstOp3a, NewToolOp5, NewToolOp5a and two places at
SameToolOp3
Added output of Speed SpinOn to Cycle block at OpGuts IF Drilling.
DWB}

{7/2/96
Modified: Meldas 500M 0KK B970.12.5
Created: Meldas 500M 0KK B970.12.6
For: Armstrong Blum
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Lee Hensch of Armstrong Blum.
Added call to GetCoolOn for ChangeCS at SameToolOp3.
Indexing B-Axis causes CoolOff.
Calling sub allows to turn CoolOn back on.
DWB}

{11Aug98
Original: Meldas 500M 0KK B970.12.6
Created: Meldas 500M 0KK B970.16
For: Armstrong-Blum
Changes made per: Lee Hench
Changes to ModCSOffsetB. CSOffsetB# was not outputting correctly.
Output only Absolute positive values from 0 to 360. The control decides the shortest rotation path to take.
Updated to .16 format per Fanuc 6M (FW) B001ż2
Charles Winston}

{19Aug98
Original: Meldas 500M 0KK B970.16
Created: Meldas 500M 0KK B970.16.1
For: Armstrong-Blum
Changes made per: Lee Hench
Modified formulas at ModCSOffsetB.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#####.##;0.'
#8 = '*#####.##;0.'
#9 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FourthDegree#,4) { Web Drill ZRapidStart OptCyc1 FIFO }
FORMAT(SUB#,4)
FORMAT(CalcZSurf#,4) { Web Drill ZRapidEnd OptCyc1 FIFO }
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(DIV#,4)
FORMAT(ToolDiameter#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(CSSubID#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Recall#,7)
FORMAT(CSOffsetA#,7)
FORMAT(CSOffsetB#,8)
FORMAT(RapidF#,9)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

CSWFO:
'G54.1P' ADD# CSPartNum# Num#('0')
RETURN

WFO:
'G54.1P' ADD# PartNum# Num#('0')
RETURN

WFOStuff:
IF Flag?('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2') { Do not output WFO second time WFOStuff is called for MP-WFO-OTAP-ECP }
RETURN

CSG52:
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

G52Stuff:
IF Flag?('7') AND NOT WFOCS?
IF FirstOperation? OR NewTool? OR ChangeCS?
IF MultipleParts?
IF WorkFixtureOffsets?
CSG52
END
ELSE
CSG52
END
END
END
RETURN

DoCSComment:
IF FirstOperation? OR NewTool? OR ChangeCS?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN

ModCSOffsetB:
IF BAxisAvail?
Save# Num#('50') DIV# CSOffsetB# Num#('360')
Save# Num#('50') SUB# Recall# Num#('50') TRUNC# Recall# Num#('50')
Save# Num#('50') MUL# Recall# Num#('50') Num#('360')
IF LTEqual? Recall# Num#('50') Num#('0')
Save# Num#('50') ABS# Recall# Num#('50')
ELSE
Save# Num#('50') SUB# Num#('360') Recall# Num#('50')
END
Recall# Num#('50')
END
RETURN

G10Block:
'G10' CSWFO
'X' SUB# CSOffsetX# Num#('14.1732') { X-Axis Distance from MachineHome to TableCenter }
'Y' CSOffsetY#
'Z' SUB# CSOffsetZ# Num#('31.1023') { Z-Axis Distance from MachineHome to TableCenter }
'B' ModCSOffsetB
RETURN

DoCSWFOComment:
IF FirstOperation? OR NewTool? OR ChangeCS?
'( ' CSWFO '='
' X' SUB# CSOffsetX# Num#('14.1732') { X-Axis Distance from MachineHome to TableCenter }
' Y' CSOffsetY#
' Z' SUB# CSOffsetZ# Num#('31.1023') { Z-Axis Distance from MachineHome to TableCenter }
IF Flag?('6') { TRUE = B-Style Output, FALSE = C-Style Output }
IF AAxisAvail?
' A' CSOffsetA#
END
IF BAxisAvail?
' B' ModCSOffsetB
END
END
' )' EOL
END
RETURN

CSComments:
DoCSComment
IF WFOCS? AND NOT MultipleParts?
DoCSWFOComment
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
IF MultipleParts? AND OneToolAllParts? NOT SameTool?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
CSComments
END
RETURN

CSAngleA:
IF AAxisAvail?
IF Flag?('6') AND WFOCS? { TRUE = B-Style Output, FALSE = C-Style Output }
'A0.'
ELSE
'A' CSOffsetA#
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
IF Flag?('6') AND WFOCS? { TRUE = B-Style Output, FALSE = C-Style Output }
'B0.'
ELSE
'B' CSOffsetB#
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
ResetCool
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

ToggleIncDecWFO:
IF Flag?('3') { Incrementing WFOs in effect }
SetFlagF('3')
ELSE { Decrementing WFOs in effect }
SetFlag('3')
END
RETURN

DoCSG52Ops:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqC SetWFO EOL
END
SeqC SubCall CallLab RepLab OnePart EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
DoCSG52Ops
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
DoCSG52Ops
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqC CSWFO EOL
END
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
ToggleIncDecWFO
END
END
ELSE
SeqC AbsOrIncC EOL
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
END
RETURN

DoAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
IncValueC
ELSE
AbsOrIncC
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
IncValueC
ELSE
AbsOrIncC
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqC AbsOrIncC EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc CRCOffC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

VarInit:
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
Save# Num#('4') Num#('0')
Save# Num#('5') Num#('0')
Save# Num#('6') Num#('0')
Save# Num#('7') Num#('0')
Save# Num#('8') Num#('0')
Save# Num#('9') Num#('0')
Save# Num#('10') Num#('0')
Save# Num#('11') Num#('0')
Save# Num#('12') Num#('0')
Save# Num#('13') Num#('0')
Save# Num#('14') Num#('0')
Save# Num#('15') Num#('0')
Save# Num#('16') Num#('0')
Save# Num#('17') Num#('0')
Save# Num#('18') Num#('0')
Save# Num#('19') Num#('0')
Save# Num#('20') Num#('0')
Save# Num#('21') Num#('0')
Save# Num#('22') Num#('0')
Save# Num#('23') Num#('0')
Save# Num#('24') Num#('0')
Save# Num#('25') Num#('0')
Save# Num#('26') Num#('0')
Save# Num#('27') Num#('0')
Save# Num#('28') Num#('0')
Save# Num#('29') Num#('0')
Save# Num#('30') Num#('0')
Save# Num#('31') Num#('0')
Save# Num#('32') Num#('0')
Save# Num#('33') Num#('0')
Save# Num#('34') Num#('0')
Save# Num#('35') Num#('0')
Save# Num#('36') Num#('0')
Save# Num#('37') Num#('0')
Save# Num#('38') Num#('0')
Save# Num#('39') Num#('0')
Save# Num#('40') Num#('0')
Save# Num#('41') Num#('0')
Save# Num#('42') Num#('0')
Save# Num#('43') Num#('0')
Save# Num#('44') Num#('0')
Save# Num#('45') Num#('0')
Save# Num#('46') Num#('0')
Save# Num#('47') Num#('0')
Save# Num#('48') Num#('0')
RETURN

StartUpStuff:
SeqC Rapid Plane DrillOff CRCOff EOL
IF WFOCS?
VarInit
IF MultipleParts?
EachPart
END
EachOp
IF Equal? Recall# ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1') Num#('0')
Save# ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1') Num#('1')
ClearCSOffset
SeqC G10Block EOL
END
NextOp
IF MultipleParts?
NextPart
END
VarInit
END
SeqC 'G28B0' EOL
RETURN

GetCoolOn:
IF NOT CoolOff?
IF ThruSpin?
'M58'
SetFlag('8') { For SameTool }
ELSE
CoolOn
SetFlagF('8') { For SameTool }
END
END
RETURN

GetSpeedOn:
IF Drilling?
GetCycle
IF NOT Tap?
Speed SpinOn
END
ELSE
Speed SpinOn
END
RETURN

GetOfstOff:
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
Rapid ZCP1 {OfstOff}
ELSE
'G30Z0.' {OfstOff}
END
RETURN

CheckPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
ClearCSOffset
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
ZonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC CRCOffC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF FIFO? AND OptCyc1? AND FourthCW? { Web Drill Cycle }
EachFeat
IF NOT FirstFeat?
SeqC RapidC MoveSXYC EOL
SeqC RapidC ZCP2C EOL
END
SeqC FeedC 'Z' FourthDegree# FeedEnt EOL
SeqC RapidC 'Z' CalcZSurf# EOL
SeqC FeedC ZDepth FeedEnt EOL
SeqC SpinOff EOL
SeqC 'M19' EOL
SeqC IncValue Feed 'Y-.005' EOL
SeqC AbsOrInc EOL
IF RetractToCP1?
SeqC RapidC ZCP1 EOL
ELSE
SeqC RapidC ZCP2 EOL
END
SeqC SpinOn EOL
NextFeat
ELSE
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
IF FIFO? AND NOT Dwell?
'G76'
ELSE
Cycle
END
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF FIFO? AND NOT Dwell?
'J-.005' { Shift away from wall }
END
IF Tap?
'E' DIV# Num#('1') FeedTapIPR#('1') { # of Threads per Inch }
Speed SpinOn
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqC SubCall 'L' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlag('3') { Incrementing WFOs in effect }
SetFlag('4') { This post supports IncWFO/DecWFO }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlag('6') { TRUE = B-Style Output, FALSE = C-Style Output }
SetFlag('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
SetFlagF('8') { SameTool GetCoolOn }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOp -' EOL
' all literals and commands before an EndOp command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an EndOp command will appear' EOL
' at the end of the operation. ' EOL
' SetFlood, SF' EOL
' This is a modal command affecting all operations.' EOL
' Outputs flood coolant, M8, for all following operations.' EOL
' This is the default setting.' EOL
' FloodCoolant, FCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Outputs flood coolant, M8, for the current operation.' EOL
' SetThruSpindle, STS' EOL
' This is a modal command affecting all operations.' EOL
' Outputs thru-the-spindle coolant, M58, for all following operations.' EOL
' ThruSpindleCoolant, TSCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Outputs thru-the-spindle coolant, M58, for the current operation.' EOL
' OptionalCycle1, OptCyc1' EOL
' This command, combined with now-obsolete 4thAxisCW(n) command will cause Post' EOL
' to output a non-Canned LongHand Web Drilling Cycle.' EOL
' 4thAxisCW(-1.25), 4ACW(-1.25) -' EOL
' This command, combined with OptionalCycle1 command will cause the Post Processor to' EOL
' output a non-Canned LongHand Web Drilling Cycle. Argument should contain ZRapidStart' EOL
' value. For this example, ZRapidStart value is equal to Z-1.25. In addition to this,' EOL
' Post Processor uses the the ZSurface Edit Field for ZRapidEnd position.' EOL
END

IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF Equal? NumOfCS# Num#('1') { 3 Axis Part - Output M-Style }
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
ELSE
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('48')
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to '
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
'G52'
ELSE
'non-WFO'
END
' style output. )' EOL
END
END
ELSE
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
END
ELSE
IF LTEqual? NumOfCS# Num#('48') {****}
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to '
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
'G52'
ELSE
'non-WFO'
END
' style output. )' EOL
END
END
END
END
END
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
StartUpStuff
RETURN

FirstOp1:
SeqC OpToolID EOL
SeqC 'G30Y0.Z0.' EOL
SeqC ToolChng EOL
SeqC ProgStop EOL
Seq ' ' EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqC WFOStuff EOL
G52Stuff
{ Speed SpinOn moved to FirstOp3 and FirstOp3a }
RETURN

FirstOp3:
CheckPass
SeqC AbsOrInc Rapid StrtPos GetSpeedOn GetCoolOn
IF NOT LastTool?
PreTool
END
CSAngleA CSAngleB EOL
SeqC OfstOn EOL
RETURN

FirstOp3a: {can't XY position before WFO}
CheckPass
SeqC GetSpeedOn GetCoolOn
IF NOT LastTool?
PreTool
END
EOL
SeqC OfstOn EOL
RETURN

NewToolOp1:
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC GetOfstOff EOL
RETURN

NewToolOp2:
DoEndOpPS
SeqC 'G30Y0.Z0.' EOL
SeqC ToolChng EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
Seq ' ' EOL
SeqC PlaneC EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqC WFOStuff EOL
G52Stuff
{ Speed SpinOn moved to NewToolOp5 and NewToolOp5a }
RETURN

NewToolOp5:
CheckPass
SeqC AbsOrInc Rapid StrtPos GetSpeedOn GetCoolOn
IF LastTool?
'T0'
ELSE
PreTool
END
CSAngleA CSAngleB EOL
SeqC OfstOn EOL
RETURN

NewToolOp5a:
CheckPass
SeqC GetSpeedOn GetCoolOn
IF LastTool?
'T0'
ELSE
PreTool
END
EOL
SeqC OfstOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC GetOfstOff EOL
SeqC 'M0' EOL
ELSE
IF NewToolOffset? OR ChangeCS?
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC GetOfstOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
G52Stuff
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos GetSpeedOn GetCoolOn CSAngleA CSAngleB EOL
SeqC OfstOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos
IF ChangeCS?
GetSpeedOn GetCoolOn
ELSE
IF Drilling?
GetCycle
IF NOT Tap?
SpeedC
END
END
IF NOT CoolOff? AND LAST CoolOff?
GetCoolOn
ELSE
IF ThruSpin? AND NOT Flag?('8')
GetCoolOn
ELSE
IF NOT ThruSpin? AND Flag?('8')
GetCoolOn
END
END
END
END
CSAngleA CSAngleB EOL
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC GetOfstOff EOL
RETURN

End2:
DoEndOpPS
SeqC 'G30Y0.Z0.' EOL
SeqC ToolChng EOL
SeqC 'T0' EOL
IF AAxisAvail?
SeqC 'G28' CSAngleA EOL
END
IF BAxisAvail?
SeqC 'G28' CSAngleB EOL
END
SeqC 'G30X0.' EOL
SeqC 'M60' EOL { Change Pallets }
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
OpenMP
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC 'G54.1P1' EOL { WFO1 }
END
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1
CloseMP
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}
InitOp

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END