{Change Comments ***********************************************************}

{12/21/92
Copied & modified: Fanuc 5M M015.81.2
For: Thermacon Manufacturing
Machine:
Control: Fanuc 5M
Changes made per FAX and conversation with Doug Szot at Thermacon
This supports both Absolute and Incremental output.
This supports MultipleParts.
Using Var(1), Var(2) and Var(3) for logical control of MultiplePart Operations.
Using Var(4), Var(5), Var(6) and Var(7) for correct Positioning of AutoCycles that Repeat in
X and/or Y, and when AbsoluteMoves = FALSE.
Added literal 'G91M03G28Z0000S200' after safe start-up at FirstOperation.
Added literal 'G28X0000Y0000' after safe start-up at FirstOperation.
Added Preset Home 'Z0' after safe start-up at FirstOperation.
Added literal 'M00' after safe start-up at FirstOperation.
Changed all occurances of Speed5M to Speed.
Added LastFeatExtend for CRCOff at end of ToolPath for Non-AutoCycles.
Deleted all other occurances of CRCOffC as a result.
Added extra ToolChng at NewTool and end of Prog to unload Tool in Spindle.
DWB}

{2/2/93
Modified: Fanuc 5M [TM] M542.81.2
For: Thermacon Manufacturing
Removed all SpinOff codes from the prog.
Changed all Plane commands to conditional.
Moved the 'M03' from the 'G91' line to the 'G28' line at the beginnig of the prog.
Added a Rapid the MasterSub.
Changed RPM to a Max of 4000.
Changed CoolOff to only be output conditionally.
KLM}

{6/3/93
Modified: Fanuc 5M [TM] M542.81.2
For: Thermacon Manufacturing
Changes made per Douglas at Thermacon.
Updated to Version 4.1 per LongHand M001.81.3 Format.
Added Rapid to First Block at FirstOperation.
Changed Preset Home to Preset 'X0000Y0000' at FirstOperation.
Added Rapid AbsOrInc Home following Preset block at FirstOperation.
DWB}

{12/6/93
Modified: Fanuc 5M [TM] M542.81.5
For: Thermacon Manufacturing per Douglas
Modified to use subs per Fanuc 6M NoNest M001.81.2
Jim Radcliffe}

{4/4/94
Modified: Fanuc 5M [TM] M542.81.6
For: Thermacon Manufacturing
MultipleParts-FullUp; CloseMP was getting incorrect Preset values due to being
left in IncValue from OfstOff. Fixed by calling SetAbsOrInc before CloseMP.
Jim Radcliffe}

{5/12/94
Copied & modified: Fanuc 5M [TM] M542.81.7
For: CKC
Control: Fanuc 5M
Machine: Mazak V5
Override ToolChangeAtHome to allways change tools at machine home (G28X0Y0).
Added spaces between codes.
Modified FormatNameComment to include name of control and machine.
Modified ToolDiameter# format to show trailing zeros.
Jim Radcliffe}

{9/13/95, Updated Fanuc 5M Mazak V5 M657.81.7 to .85 format per Fanuc 6M NoNest M001.85, JR}

{2/12/96, Updated .85 number to .86, no changes necessary, MPK}

{3/25/96, Updated .86 to .89 version, TH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.0000'
#5 = '#######0'
#6 = '####^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Tag#,5)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC ' Pł' Tag# RepLab RepCycs SubCall EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
TagInc
SeqLabC ' Pł' Tag# RepLab Parts SubCall EOL
StartSub
RETURN

CloseMP:
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {NoNesting} {.72.1, this is for AutoCycles only}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqLabC IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqLabC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqLabC RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
ELSE
EntryMove
ToolPath2
IF FIFO? {.81}
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
SeqLabC ' Pł' Tag# SubCall EOL
ELSE
CutAutoCycle
END
ELSE
SeqLabC ' Pł' Tag# SubCall EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
IF LastFeat?
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect? {.72.1, minor changes to entry}
SeqLabC FeedC StrtPosC EOL
SeqLabC ZInC FeedEntC EOL
ELSE
SeqLabC RapidC StrtPosC EOL
SeqLabC ZCP2C EOL
IF FeedEntry?
SeqLabC FeedC ZInC FeedEntC EOL
ELSE
SeqLabC RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
END
NextRep
ELSE
TagInc
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
TagInc
AutoCycPat {write pattern moves and main calls}
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
SeqLabC ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqLabC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqLabC RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
SeqLabC EndSub EOL
CloseSub
END
RETURN

ZonlyRep:
TagInc
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
IF MultipleParts? {NoNesting}
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
ELSE
SeqLabC ' Pł' Tag# SubCall EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: Fanuc 5M Mazak V5 ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF MultipleParts? AND WorkFixtureOffsets?
'( This Procesor does not Support Work Fixture Offsets! )' EOL
'( The Multiple Parts are being processed with the Equally Spaced )' EOL
'( Offsets values! I suggest you make sure that they are set properly! )' EOL
END
OpenSub
RestoreScale
SeqLab Rapid Plane DrillOff CRCOff EOL
SeqLabC ' G91 G28 Z0 ' EOL
SeqLabC ' G28 X0 Y0 ' EOL
SeqLabC Preset ' X0 Y0 Z0' EOL
SeqLabC ' M00' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLabC OpToolID EOL
SeqLabC ToolChng EOL
DoOpComments
DoPostScript
SeqLabC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
SeqLabC IncValue OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SetAbsOrInc
CloseMP
END
DoEndOpPS
SeqLabC IncValue ' G28 X0 Y0' EOL
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

SeqLab PlaneC EOL
SeqLabC ToolChng EOL { Unload LAST Tool }
SeqLabC OpToolID EOL
SeqLabC ToolChng EOL { Load THIS Tool }
DoOpComments
DoPostScript
SeqLabC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF LAST ProgStop? OR NewToolOffset?
SeqLabC IncValue OfstOff EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M00' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
SeqLabC PlaneC AbsOrInc Rapid StrtPos SpeedC
IF LAST ProgStop?
SpinOn
END
EOL
IF LAST ProgStop? OR NewToolOffset?
SeqLabC OfstOn EOL
END
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END {common point for all operations}
ResetCRCNum {.72}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats? {NoNesting}
IF MultipleParts?
EachRep
ELSE
TagInc
StdSub
END
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF MultipleParts? OR Repeats? {NoNesting}
TrackZNO# FIRST SPZ#
ToolPath
ELSE
IF CallMasterOp?
SeqLabC ' Pł' CallMasterNum# SubCall EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
SeqLabC ' Pł' Tag# SubCall EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
END
SetDrillEndOpZ
SeqLabC ' G80' EOL
SeqLabC RapidC ZCP3C EOL
IF Repeats? {NoNesting}
IF MultipleParts?
NextRep
ELSE
FinishSubG92
END
END
SeqLabC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SetAbsOrInc
CloseMP
END
DoEndOpPS
SeqLabC IncValue ' G28 X0 Y0' EOL
IF ProgStop?
SeqLabC ' M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC ToolChng EOL
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END