{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
}

{Change Comments ***********************************************************}

{12/21/92
Copied & modified: Fanuc 5M M015.81.2
For: Thermacon Manufacturing
Machine:
Control: Fanuc 5M
Changes made per FAX and conversation with Doug Szot at Thermacon
This supports both Absolute and Incremental output.
This supports MultipleParts.
Using Var(1), Var(2) and Var(3) for logical control of MultiplePart Operations.
Using Var(4), Var(5), Var(6) and Var(7) for correct Positioning of AutoCycles that Repeat in
X and/or Y, and when AbsoluteMoves = FALSE.
Added literal 'G91M03G28Z0000S200' after safe start-up at FirstOperation.
Added literal 'G28X0000Y0000' after safe start-up at FirstOperation.
Added Preset Home 'Z0' after safe start-up at FirstOperation.
Added literal 'M00' after safe start-up at FirstOperation.
Changed all occurances of Speed5M to Speed.
Added LastFeatExtend for CRCOff at end of ToolPath for Non-AutoCycles.
Deleted all other occurances of CRCOffC as a result.
Added extra ToolChng at NewTool and end of Prog to unload Tool in Spindle.
DWB}

{2/2/93
Modified: Fanuc 5M [TM] M542.81.2
For: Thermacon Manufacturing
Removed all SpinOff codes from the prog.
Changed all Plane commands to conditional.
Moved the 'M03' from the 'G91' line to the 'G28' line at the beginnig of the prog.
Added a Rapid the MasterSub.
Changed RPM to a Max of 4000.
Changed CoolOff to only be output conditionally.
KLM}

{6/3/93
Modified: Fanuc 5M [TM] M542.81.2
For: Thermacon Manufacturing
Changes made per Douglas at Thermacon.
Updated to Version 4.1 per LongHand M001.81.3 Format.
Added Rapid to First Block at FirstOperation.
Changed Preset Home to Preset 'X0000Y0000' at FirstOperation.
Added Rapid AbsOrInc Home following Preset block at FirstOperation.
DWB}

{12/6/93
Modified: Fanuc 5M [TM] M542.81.5
For: Thermacon Manufacturing per Douglas
Modified to use subs per Fanuc 6M NoNest M001.81.2
Jim Radcliffe}

{4/4/94
Modified: Fanuc 5M [TM] M542.81.6
For: Thermacon Manufacturing
MultipleParts-FullUp; CloseMP was getting incorrect Preset values due to being
left in IncValue from OfstOff. Fixed by calling SetAbsOrInc before CloseMP.
Jim Radcliffe}

{5/12/94
Copied & modified: Fanuc 5M [TM] M542.81.7
For: CKC
Control: Fanuc 5M
Machine: Mazak V5
Override ToolChangeAtHome to allways change tools at machine home (G28X0Y0).
Added spaces between codes.
Modified FormatNameComment to include name of control and machine.
Modified ToolDiameter# format to show trailing zeros.
Jim Radcliffe}

{9/13/95, Updated Fanuc 5M Mazak V5 M657.81.7 to .85 format per Fanuc 6M NoNest M001.85, JR}

{2/12/96, Updated .85 number to .86, no changes necessary, MPK}
{3/25/96, Updated .86 to .89 version, TH}

{15Sep98
Original: Fanuc 5M Mazak V5 M657.89
Created: Fanuc 5M LH Mazak V5 M657.16m
For: Jamtab in Sweden
Added Post Boolean Description at the top of comments.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Created Metric Longhand Post per Fanuc 6M LH MV83ż2
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.000'
#5 = '#######0'
#6 = '####^###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(Recall#,5)
FORMAT(PartNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Tag#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post }
END
RETURN

WFO:
{ Not Supported }
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

ResetWFO:
{ Not Supported }
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' PartNum# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC FeedC ZInC
IF NOT EmptyLine? { Mostly for FeedConnect ZShiftOnly with ZMove }
FeedEntC
END
EOL
ELSE
SeqLabC RapidC ZInC EOL
END
RETURN

ExitMove:
IF NOT FeedConnect?
CRCOffC
IF FIFO?
FeedC PRIME ZCP2C FeedEntC
ELSE
RapidC PRIME ZCP2C
END
END
RETURN

ExitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

DoPeck: { LongDrillStuff }
{ Not Supported }
RETURN

DrillFeature: { LongDrillStuff }
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat? { Drilling Only }
SeqLabC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqLabC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqLabC AbsOrInc CRCOffC
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

CutAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqLabC RapidC MoveSXYC EOL
END
AutoCycCutSub1
IF Repeats?
IF ZShiftOnly?
EachRep
IF NOT FirstCycle?
IF FeedConnect?
DoCycleComment
IF SPXMove? OR SPYMove?
SeqLabC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqLabC AbsOrInc ExitMove EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqLabC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqLabC RapidC ZCP2 EOL
END
END
EntryMove
SeqLabC IncValue EOL
END
ToolPath
NextRep
END
ELSE
Milling
END
AutoCycCutSub2
NEXTFeat
RETURN

ZonlyRep:
{ NOTE: This Post Processor takes care of Z Clearance. }
EachRep
DoCycleComment
IF NOT FirstCycle?
CRCOffC
IF SPXMove? OR SPYMove?
IF FeedConnect?
FeedC
ELSE
RapidC
END
SeqLabC MoveSXYC EOL
END
IF FeedEntry? AND NOT FeedConnect?
SeqLabC ZCP2C EOL
END
END
EntryMove
ToolPath
SeqLabC ExitMove EOL
NextRep
RETURN

LongDrillStuff:
SeqLabC DrillCP EOL
GetCycle
SeqLabC StrtPosC EOL
ToolPath
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqLabC RapidC ZCP3C EOL
END
RETURN

DrillStuff:
SeqLabC DrillCP EOL
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

CheckPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

OpGuts:
ResetCRCNum
RapidF# { No Output }
IF Milling?
SeqLabC ZCP2C EOL
IF AutoCycle?
CutAutoCycle
IF Repeats? AND FeedConnect?
ELSE
SeqLabC ExitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats? AND ZShiftOnly?
ZonlyRep
ELSE
Milling
END
SeqLabC CRCOffC ExitMove2 EOL
END
ELSE
IF Drilling?
DrillStuff
ToolPath
SetDrillEndOpZ
SeqLabC DrillOff Rapid ZCP3 EOL
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
TagInit
SetFlood
SetMaxRPM('4000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { LongHand PeckCycle }
SetFlagF('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: Fanuc 5M Mazak V5 ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MM )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF MultipleParts? AND WorkFixtureOffsets?
'( This Procesor does not Support Work Fixture Offsets! )' EOL
'( The Multiple Parts are being processed with the Equally Spaced )' EOL
'( Offsets values! I suggest you make sure that they are set properly! )' EOL
END
RestoreScale
RETURN

FirstOp1:
SeqLab Rapid Plane DrillOff CRCOff EOL
SeqLabC ' G91 G28 Z0 ' EOL
SeqLabC ' G28 X0 Y0 ' EOL
SeqLabC Preset ' X0 Y0 Z0' EOL
SeqLabC ' M00' EOL
SeqLabC OpToolID EOL
SeqLabC ToolChng EOL
DoPartCycleComment
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqLabC WFOStuff EOL
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
RETURN

FirstOp3:
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
RETURN

NewToolOp1:
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
SeqLabC IncValueC OfstOff EOL
RETURN

NewToolOp2:
DoEndOpPS
SeqLabC IncValue ' G28 X0 Y0' EOL
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab PlaneC EOL
SeqLabC ToolChng EOL { Unload LAST Tool }
SeqLabC OpToolID EOL
SeqLabC ToolChng EOL { Load THIS Tool }
DoPartCycleComment
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqLabC WFOStuff EOL
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
RETURN

NewToolOp5:
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC IncValueC OfstOff EOL
SeqLabC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC IncValueC OfstOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC WFOStuff EOL
IF LAST ProgStop?
SeqLabC PlaneC AbsOrInc Rapid StrtPos Speed SpinOn EOL
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqLabC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC CoolOff EOL
SeqLabC IncValueC OfstOff EOL
RETURN

End2:
DoEndOpPS
SeqLabC IncValue ' G28 X0 Y0' EOL
IF ProgStop?
SeqLabC ' M00' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqLabC 'M00' EOL
END
END
SeqLabC ToolChng EOL
RETURN

End3:
SeqLabC EOP EOL
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
End1
IF MultipleParts? AND OneToolAllParts?
ResetWFO
END
End2
RETURN

NewPart1: {Finish off last Part}
IF FullUp?
SeqLabC CoolOff EOL
SeqLabC IncValueC OfstOff EOL
END
{DoEndOpPS}
RETURN

NewPart2: {Start new Part}
SameToolOp2
RETURN

NewPart3: {Start new Part}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SeqLabC WFOStuff EOL
SeqLabC PlaneC AbsOrInc Rapid StrtPos Speed EOL
IF FullUp?
SeqLabC OfstOn EOL
SeqLabC CoolOn EOL
END
RETURN

MPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
NewWFO
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
MasterSub
NextOp
EndPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Valid Tool Op }
IF FirstOperation? OR NewTool?
IF FirstPart?
MasterSub
ELSE
NewPart1
NewPart2
NewPart3
OpGuts
END
ELSE
MasterSub
END
IF LastOp?
IF LastPart?
Save# Num#('1') Num#('0')
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart?
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IncWFO
NextWFO
ELSE
NextPart
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}
InitOp

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
MPLoop
ResetWFO
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3