{Change Comments ***********************************************************}

{9/26/88, Added CRCOffC to rapid up and repeats, same as all other Fadal posts, WFG}
{6/5/89, Changed Maximum Spindle RPM from 10000 to 15000 in Form's 'Numbers' Dialog, JR}
{1/26/90, Updated: Fadal M003.58, to .69 format, JR}
{2/90/90, Updated: Fadal M003.69, to .70 format, JR}
{3/23/90, Changed SetMaxRPM from 10000 to 15000 in Prog, JR}

{4/6/90
Added '01' literal for looping once on CallLab line at ZonlyRepAutoCycle & ZonlyRep subs.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/10/90, Updated: Fadal M003.71 to .74 format, JR}
{3/6/91, Updated: Fadal M003.74 to .76.1 format, JR}
{4/3/91, Updated: Fadal M003.76.1, to .80 format, DWB}
{9/11/91, Updated: Fadal M003.79, to .81 format, DWB}

{* 11/3/93 [cwh]
Modeified: Fadal M003.81
To: Fadal M003.81.1
For: Gibbs and Associates

Modified the form so that it could be used with the 32MP and 32MPOL
versions of Catalyst ( Virtual ).
*}

{11/8/93
Modified: Fadal M003.81.1
For: Gibbs & Associates
Modified to get consecutive sequence numbers thru subroutines:
Changed; Seq to SeqLab, SeqC to SeqLabC and N to N? in MachSpec.
Added Retag
Jim Radcliffe}

{1/3/95
Updated: Fadal M003.81.2
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Changed FeedRateC to FeedEntC for FIFO Exit Moves.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Changed logic to output CRCOnC in OneFeat ToolPath.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 at all ZMoveOnly Feature Retract blocks.
Changed TrackZNO# ZDepth# to TrackZNO# FIRST SPZ# at IF Drilling.
SPZ# is affected by SetScale, whereas ZDepth# is not.
DWB}

{7/19/95, Updated Fadal M003.81.3 to .85 version per v2.20 Update Instructions .01, JR}

{8/15/95,
Fadal M003.85.1
Added literal '01' after CallMasterNum#
Added support for RigidTap per M610.85
TH}

{
Format: Fadal M003.85.2
8/28/95
Fixed duplicate call of Cycle command
Changed SeqLab to SeqLabC in rigid tap sections
TH}

{
Format: Fadal M003.85.3
10/12/95
Added UnTool ToolChng to CloseMP: to reload tool1 at the end of each part. This is a First Tool In Spindle post
TH}

{11/17/95
Modified: Fadal M003.85.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.08/Catalyst v2.28.04/Compost 4.21.33/1.0a
Changes made per Mike Dziminowicz of Hughes Aircraft Space & Comm.
Limited UnTool ToolChng block to AllToolsOnePart at CloseMP sub.
DWB}

{
Format: Fadal M003.85.5
11/28/95
Fixed CloseMP so the UnTool ToolChng block will not be output for WFO's if OneToolAllParts
TH}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/12/96,
Initial: Fadal M003.89
Created: Fadal Format 1 MXXX.89
For: Barry Alexander
Added Tool Change in FirstOperation and changed comment to 'FIRST TOOL NOT IN SPINDLE',
Added G28 after SpinOff in NewTool, Added 'G8' when milling after call to WFOStuff in FirstOperation and NewTool, MPK}

{9/11/96,
Initial: Fadal Format 1 [BA] M161.89
Created: Fadal Format 1 M161.89.1
For: Barry Alexander
Moved StrtPos onto separate line after Plane/Rapid/AbsOrInc line in FirstOp, NewTool,
and SameTool (for Progstop and NewToolOffset)
Moved OfstOn from separate line into Plane/Rapid/AbsOrInc line in FirstOp, NewTool, and SameTool
MPK}

{3/25/98,
Updated to D161.15 using D610.15,
CDH}

{2/12/99,
Initial : Fadal Format 1 [BA] D161.15
Created: Fadal Format 1 [FS] DQ11.15
Customer: Frontier Systems, Gene 949/623-2222
ComPost2: v1.7b15
MDD: 3C_VM3 or 3C_VM4

Changes to "Form":

1. Under Spindle & Collant, changed Coolant On Number to 8.
2. Under Tool Offset, added CRC Offset Label D

Changes to "Prog":

1. Changed ckCRC sub and added a call in FormatArc sub.
2. Added Inch/Metric Code at tape start.
3. Added Preset block (G92) at tape start. Also added FORMAT for HomeX# and HomeY#.
4. Moved CoolOn to SpinOn block.
5. Changed CoolOn to doCoolOn and added a sub to output M7 for ThruSpin.
6. Moved CoolOff from newToolOp1 sub to newToolOp2 and from end1 sub to end2.
7. Removed all G28 codes.
8. Added 1 block in end2 sub and always move Home at program end.
9. Removed OfstOff, WFOOff, and BYE from end3 sub.
10. Added 'E0' to all motion Home.
11. Added M46 to canned cycle block for PosApproach and M47 for regular approach.
12. Moved OfstOn from firstOp2 to firstOp3 sub and from newToolOp4 to newToolOp5 sub.
13. Added ckCRCNum sub and calls.
14. Moved G8 output to toolPath sub.
15. Moved SpinOff before CoolOff.
16. Added Rapid ZCP3 to G80.
17. Moved wfoStuff before SpinOn.
18. Added SetProgNum('0').
JHE}

{2/22/99,
Initial : Fadal Format 1 [FS] DQ11.15
Created: Fadal Format 1 [FS] DQ11.15.1
Customer: Frontier Systems, Gene 949/623-2222
ComPost2: v1.7b15
MDD: 3C_VM3 or 3C_VM4

Changes to "Prog":

1. Added doGainSetting sub to output M92 with 1st cut and M90 with last cut
when PIN(1) is entered.
2. Added SetPalletIn('0') in progStart, firstOp1, newToolOp3, and sameToolOp2 subs.
3. In firstOp1 and end2 sub, changed 'Z1.' to 'Z' TCZ#.
4. Moved DoPostScript before the PreSet block.
5. Added SetTCZ('1') in progStart and added FORMAT to TCZ#.
6. Added PIN(1) and TCZ(n) to PostScript description.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '#####.###;0.'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(CSOffsetA#,2)
FORMAT(CSOffsetB#,2)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(HomeX#,4) {Added - JHE 2/12}
FORMAT(HomeY#,4) {Added - JHE 2/12}
FORMAT(TCZ#,4) {Added - JHE 2/22}
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Recall#,7)
FORMAT(CallMasterNum#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

MPESWFO: { MultipleParts EquallySpaced }
'E' ADD# PartNum# SUB# NewWFO# Num#('1')
RETURN

WFO:
'E' ADD# PartNum# Num#('0')
RETURN

WFONum:
'E' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO
ELSE
MPESWFO
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

doCoolOn: {Added this sub - JHE 2/12}
IF ThruSpin?
'M7'
ELSE
IF Mist?
'M7.1'
ELSE {implies Flood}
CoolOn {output M8}
END
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '* SUB NUMBER: ' Program# EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
SeqLabC '* CS#' CS# ' - ' CSComment$ EOL
END
RETURN

ModCSOffsetA:
IF FirstOperation?
IF LessThan? CSOffsetA# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetA# LAST CSOffsetA#
'-'
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetA# Num#('360')
IF LessThan? CSOffsetA# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetA# MUL# Recall# Num#('1') Num#('360')
RETURN

ModCSOffsetB:
IF FirstOperation?
IF LessThan? CSOffsetB# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetB# LAST CSOffsetB#
'-'
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetB# Num#('360')
IF LessThan? CSOffsetB# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetB# MUL# Recall# Num#('1') Num#('360')
RETURN

CSComments:
IF FirstOperation? OR NewTool? OR ChangeCS?
DoCSComment
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
SeqLabC '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLabC '* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
SeqLabC '* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
SeqLabC '* ' ToolComment$ EOL
END
RestoreScale
END
CSComments
RETURN

CSAngleA:
IF AAxisAvail?
'A' ModCSOffsetA
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' ModCSOffsetB
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC SubIDF EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLabC '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLabC CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLabC CallLab Recall# Num#('10') EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftR EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftR EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

DoWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC Rapid StrtPos SetWFO EOL
END
SeqLabC CallLab OnePart EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLabC CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLabC CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
ELSE
SeqLabC Preset ShiftP EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

CkCRC:
IF XMove? OR YMove?
CRCOnC
END
IF LastFeat? AND EmptyLine?
CRCOffC
END
RETURN

ckCRCNum: {Added - JHE}
IF NOT LastFeat?
CRCOffsetC
END
RETURN

FormatArc:
DoAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

doGainSetting: {Added - JHE 2/22}
IF Equal? Pallet# Num#('1')
IF FirstFeat?
'M92'
ELSE
IF LastFeat?
'M90'
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC ckCRCNum doGainSetting EOL
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC CallLab OnePart EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF AutoCycle?
SeqLabC DoAbsOrInc
IF LastFeat?
CRCOffC
END
RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC {.82}
END
RapidC MoveXYZC EOL
END
END
ELSE
IF FirstFeat? OR Rapid? {Moved to here - JHE}
SeqLabC 'G8' EOL
END
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC ckCRCNum EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed ckCRCNum EOL
ELSE
SeqLabC FormatArc ArcFeedC ckCRCNum EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC CallLab OnePart EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC CallLab OnePart EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC
IF Tap? AND OptCyc1?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
FadalTapF FadalTapQ
ELSE
FeedEnt
END
IF PosApproach? {Added - JHE 2/12}
'M46' EOL
ELSE
'M47' EOL
END
IF CallMasterOp?
SeqLabC 'L' CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC CallLab OnePart EOL
StartSub
ToolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' Rapid ZCP3 EOL
SeqLabC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { CSAngleA and CSAngleB }
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetPalletIn('0') {Added - JHE 2/22}
SetTCZ('1') {Added - JHE 2/22}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' PIN(1) Output Gain Setting codes (M92 and M90)' EOL
' TCZ(n) Specifies the value to be output with the g92 block at tape ' EOL
' start and g49 block at tape end. 'n' default is 1. ' EOL
END
RETURN

InitOp:
EOR EOL
SeqLabC 'O' Program#
SetProgNum('0')
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
SeqLabC '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLabC '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLabC '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLabC '* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
SeqLabC '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLabC '* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
IF ToolChangeAtHome?
SetHome
END
IF Metric?
SeqLab 'G21' EOL { Metric Mode }
ELSE
SeqLab 'G20' EOL { Inch Mode }
END
SetPalletIn('0') {Added - JHE 2/22}
DoPostScript {Moved to here - JHE 2/22}
SeqLabC Preset 'X' HomeX# 'Y' HomeY# 'Z' TCZ# EOL {Changed from Z1. - JHE 2/22}
SeqLabC OpToolID ToolChng EOL
DoOpComments
RETURN

FirstOp2:
SeqLabC WFOStuff EOL
IF Drilling? AND RigidTap?
SeqLabC Speed doCoolOn EOL {Moved CoolOn to here - JHE}
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn doCoolOn EOL {Moved CoolOn to here - JHE}
END
CheckPass
SeqLabC Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
RETURN

FirstOp3:
SeqLabC OfstOn EOL {Moved to here - JHE}
{SeqLabC CoolOn EOL} {Moved - JHE}
RETURN

NewToolOp1:
SeqLabC SpinOff EOL
{SeqLabC CoolOff EOL} {Moved - JHE}
RETURN

NewToolOp2:
DoEndOpPS
SeqLabC CoolOff EOL {Moved to here - JHE}
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home 'E0' EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab OpToolID EOL
SeqLabC ToolChng EOL
SetPalletIn('0') {Added - JHE 2/22}
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqLabC WFOStuff EOL
IF Drilling? AND RigidTap?
SeqLabC Speed doCoolOn EOL {Moved CoolOn to here - JHE}
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn doCoolOn EOL {Moved CoolOn to here - JHE}
END
CheckPass
SeqLabC Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
RETURN

NewToolOp5:
SeqLabC OfstOn EOL {Moved to here - JHE}
{SeqLabC CoolOn EOL} {Moved - JHE}
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinOff CoolOff EOL
SeqLabC 'G53Z0.' EOL { OfstOff }
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC 'G53Z0.' EOL { OfstOff }
END
END
RETURN

SameToolOp2: {Start new Operation}
SetPalletIn('0') {Added - JHE 2/22}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC WFOStuff EOL {Moved to here - JHE}
IF LAST ProgStop?
IF Drilling? AND RigidTap?
SeqLabC Speed doCoolOn EOL {Moved CoolOn to here - JHE}
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn doCoolOn EOL {Moved CoolOn to here - JHE}
END
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
SeqLabC OfstOn EOL
{SeqLabC CoolOn EOL} {Moved - JHE}
ELSE
IF NewToolOffset? OR ChangeCS?
SeqLabC SpeedC EOL
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
SeqLabC OfstOn EOL
ELSE
SeqLabC SpeedC EOL
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC doCoolOn EOL
END
END
RETURN

End1:
SeqLabC SpinOff EOL
{SeqLabC CoolOff EOL} {Moved - JHE}
RETURN

End2:
DoEndOpPS
SeqLabC CoolOff EOL {Moved to here - JHE}
SeqLabC Rapid 'G49Z' TCZ# EOL {Changed from Z1. - JHE 2/22}
SeqLabC 'X' HomeX# 'Y' HomeY# 'E0' EOL {Changed from Home - JHE 2/12}
IF Equal? CSOffsetA# Num#('0') AND Equal? CSOffsetB# Num#('0')
ELSE
SeqLab
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
EOL
SeqLabC Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC UnTool ToolChng EOL
SeqLabC EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
ReTag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END