{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{
10/24/94 [cwh]
B001.81.4 ( from B001.81.3 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/8/94
Modified: Fanuc 6M (FW) B001.81.4
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{
12/01/94
B001.81.6
Changed FirstOp3 to call out A0B0 to move to the first CS.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.

Added RecallWFO sub-routine to NotSameToolWFO and SameToolWFO to ouput the current fixture offset
and A0B0. Added for easier restarts at the machine. Both are only called from NoMPs.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.
}

{
12/02/94
Changed version number to .00 from .81
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/08/94
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added WFO1 and A0B0 if AxisAvail to End2:
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/09/94
Fixed RecalWFO to check AAxisAvail? and BAxisAvail?
Cleaned up FirstOp3 to use new checks placed in CSAngleA and CSAngleB
TH}

{
Format: Fanuc 6M (FW) B001.00.03
12/19/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fanuc 6M (FW) B001.00.04
1/10/95
NewToolOp3 now has an AbsOrInc on the line that calls out the Plane 'G80' CRCOff
NewToolOp5 no longer has the AbsOrInc command
NewToolOp5b has been created and has the AbsOrInc command
Changed MP1ToollAllPfu to call NewToolOp5b
Added AbsOrInc and Rapid to the FirstOperation? section of MP1ToollAllPXcp
Added Rapid to the NewTool? section of MP1ToollAllPXcp
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
MP1ToollAllPXcp, MP1ToollAllPFU, and MPallTools1P now output WFO if NOT WorkFixtureOffsets?
TH}

{
Format: Fanuc 6M (FW) B001.00.05
1/13/95
Replaced TrackZNO# ZDepth# with TrackZNO# FIRST SPZ# in the drilling section
Formatted TrackZNO# to #4
}

{
Format: Fanuc 6M (FW) B001.00.06
2/15/95
Fixed RecallWFO: to output correct WFO# if WFOCS
TH}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Fanuc 6M (FW) B001.10
7/27/95
Added G52 style output for too many coordinate systems
Updated to .10 format
TH}

{11/10/95
Initial: Fanuc 6M (FW) B001.10
Created: Fanuc 6M (FW) B001.10.01
Develop: ComPost 4.21.33, Catalyst68K v2.30.14
Comment: Corrections to Processor.
To correct multiple parts output:
Added "OR Flag?('2')" to "IF WFOCS?" in "SubCSMP:".
To Simplify prog subs and correct errors in MP1ToollAllPXcp:
Changed FirstOp3a/NewToolOp5a to FirstOp4/NewToolOp6
Deleted NewToolOp5b sub and changed call to NewToolOp5 (they were identical!)
Deleted OfstOn and Cool On from FirstOp3/NewToolOp5
Added calls to FirstOp4/NewToolOp6 after calls to FirstOp3/NewToolOp5.
Changed StrtPos in MP1ToollAllPXcp to FirstOp3/NewToolOp5.
Corrected format of CSOffsetA# and CSOffsetB#.
Deleted RecallWFO sub. It was not used!
Jim Radcliffe}

{11/15/95
Initial: Fanuc 6M (FW) B001.10.01
Created: Fanuc 6M (FW) B001.10.02
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Corrections to Processor
Modified WFO Handling:
Changes:
Deleted NotSameToolWFO & SameToolWFO subs.
Added WFOStuff sub.
Changed all WFO calls in main loops to WFOStuff.
Results:
Changes do not effect Multiple Parts output.
Correct WFO is output by default at the beginning of each tool.
G52, if used, is output by default at the beginning of each tool.
G52, without WFO, is output at SameTool only if there is a change.
Jim Radcliffe}

{11/15/95
Initial: Fanuc 6M (FW) B001.10.02
Created: Mazatrol M Plus FH480 C000.10
ForUser: Yale Security
Control: Mazatrol M Plus
Machine: Mazak FH480
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: New Processor per manual, sample program and conversations with Tony Scricca
Jim Radcliffe}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{6 Oct98
Original: Mazatrol M Plus FH480 C896.12
Created: Mazatrol M Plus FH480 Cxxx.12
For: Richland Pattern
Changes made per: Steve Davis
Added Post Header Comment at the top of Prog.
Deleted PreTool ToolChng in BeginTool1
Charles Winston}

{20 Oct98
Original: Mazatrol M Plus [RP] CU98.12
Created: Mazatrol M Plus [RP] MU98.16
For: Richland Pattern
Changes made per: Conversation with Steve Davis and Adrian
Changed Post Header Comment at the top of Prog. ( ADV_MILL=F )
Deleted 'G91G30Y0.Z0.' and replaced with 'G53G49Z0.' to cancel toolOffst in NewTool, SameTool and End1
Deleted EOR and EOP in End3
Created 3_Axis mill Posts and Updated to.16 format per Fanuc 6M M001.16
Note: Customer does not have a 4th axis
Charles Winston}

{12Nov98
Original: Mazatrol M Plus [RP] MU98.16
Created: Mazatrol M Plus [RP] MU98.16.1
For: Richland Pattern
Changes made per: Conversation with Steve Davis and Adrian
Added Post Header Comment at the top of Prog.
Changed WFO Sub to output G54G61.1 to G54G61.9 and G54 thru G59
Deleted IncValue 'G30Z0.', 'G30Y0' and 'G28X0' at Init Prog
Added Literals 'G53G49Z0' and 'G53G49X0.Y0.' in FirstOp1
Added 'G43' ZCP1 in FirstOp1 and NewToolOp3
Deleted OfstOn in FirstOp3 and NewToolOp5
Changed ToolChangeAtHome in NewToolOp2 and End2, to output 'G53G49'
Moved Speed SpinOn onto a separate line in SameToolOp3 and added ZCP1
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(HomeX#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFO:
IF LessThan? PartNum# Num#('10')
'G54G61.' PartNum#
ELSE
IF LessThan? PartNum# Num#('19')
'G55G61.' SUB# PartNum# Num#('9')
ELSE
IF LessThan? PartNum# Num#('28')
'G56G61.' SUB# PartNum# Num#('18')
ELSE
IF LessThan? PartNum# Num#('37')
'G57G61.' SUB# PartNum# Num#('27')
ELSE
IF LessThan? PartNum# Num#('46')
'G58G61.' SUB# PartNum# Num#('36')
ELSE
'G59G61.' SUB# PartNum# Num#('45')
END
END
END
END
END
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFO
END
ELSE
IF Flag?('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFO
END
ELSE
WFO
END
END
END
END
SetFlagF('2') { Do not output WFO second time WFOStuff is called for MP-WFO-OTAP-ECP }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn
IF FirstOperation? OR NewTool?
FeedEnt
ELSE
FeedEntC
END
EOL
ELSE
SeqC RapidC ZIn EOL
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedRate }
END
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqC SetWFO EOL
END
SeqC SubCall CallLab RepLab OnePart EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
StartSub
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
StartSub
END
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC AbsOrIncC EOL
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
IncValueC
ELSE
AbsOrIncC
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
IncValueC
ELSE
AbsOrIncC
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqC AbsOrIncC EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

getACEPXY:
SetACSPCompF
Save# Num#('1') SPX# { Status Register Variable for X Axis }
Save# Num#('2') SPY# { Status Register Variable for Y Axis }
SetACSPComp
RETURN

setSRXYtoACEP:
SetPass1
SetSRXYtoEP
LoadFeat Num#('0') Num#('0') Num#('0')
TrackXNO# ADD# Recall# Num#('1') SPX# { Status Register Variable for X Axis }
TrackYNO# ADD# Recall# Num#('2') SPY# { Status Register Variable for Y Axis }
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF LastFeat?
getACEPXY
END
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC FormatArc ArcFeedC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValueC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrIncC CRCOffC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrIncC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusInc EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqC ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
TrackZNO# ADD# FIRST SPZ# MUL# RepsLess1# RepeatZ#
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC IncValueC StrtPosC EOL
AbsOrIncC
END
END
SetStatusOn
doSepSubZMoves
SetStatusOff
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
TrackZNO# FIRST SPZ#
AutoCycCutSub2
IF FeedConnect?
IF NOT AbsValue?
setSepSubZ
END
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqC StrtPosC EOL
END
END
doSepSubZMoves
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
IF FeedConnect? AND NOT AbsValue?
setSepSubZ
END
RETURN

CheckPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
ZonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC CRCOffC ZCP3C EOL
setSRXYtoACEP
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('3') Num#('0') { Status Register Variable for Z Axis }
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
IF ToolChangeAtHome?
SetHome
END
DoOpComments
DoPostScript
Seq Plane CRCOff DrillOff AbsOrInc EOL
SeqC 'G53G49Z0.' EOL
SeqC 'G53G49X0.Y0.' EOL
SeqC OpToolID EOL
SeqC 'G43' ZCP1 EOL
RETURN

FirstOp2:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

FirstOp3:
SeqC CoolOn EOL
RETURN

NewToolOp1:
SeqC CoolOff EOL
SeqC 'G53G49Z0.' EOL {OfstOff}
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrIncC 'G53G49' Home SpinOff EOL
ELSE
SeqC AbsOrIncC 'G53G49X0.Y0.' SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
Seq Plane CRCOff DrillOff AbsOrInc EOL
SeqC OpToolID EOL
SeqC 'G43' ZCP1 EOL
RETURN

NewToolOp4:
SeqC WFOStuff EOL
SeqC Speed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

NewToolOp5:
SeqC CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC 'G53G49Z0.' EOL {OfstOff}
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC 'G53G49Z0.' EOL {OfstOff}
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
IF LAST ProgStop?
SeqC Speed SpinOn EOL
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqC 'G43' EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
SeqC 'G53G49Z0.' EOL {OfstOff}
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC AbsOrIncC 'G53G49' FirstHome SpinOff EOL
ELSE
SeqC AbsOrIncC 'G53G49X0.Y0.' SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output WFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}
InitOp

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END