{Change Comments ***********************************************************}

{8/11/89
Copied & modified; Fanuc OT [-] L031.55 for, Indarg.
Machine is a Mori Sieki AL20 with Fanuc OT Mate control.
Use 'G30X0.Z0.' for home position.
Add GearRange.
Delete FromCP & RLevel from drilling, changed K to U for Peck value,
and deleted G80.
Jim Radcliffe}

{3/27/90, Updated: Fanuc 0T Mate MS (-) L031.56 to .69.3 foramt, JR}

{3/27/90
Copied & modified: Fanuc 0T Mate MS (-) L031.69.3
For: Indarg
Positive side lathe. R format arcs.
2 line theading.
Jim Radcliffe}

{5/30/90
Modified: Fanuc OT Mate MS L031.69.3
Added R value to 1st Rough Contour Cycle line.
Updated to .69.5
Jim Radcliffe}

{7/23/90
Modified: Fanuc OT Mate MS L031.69.5
Deleted ReverseXZArcs
Changed StrtPos to StrtPosC in RoughContour & RoughPatternShift.
Updated to .69.7 format
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/3/90, Updated: Fanuc OT Mate MS L031.70 to .71 format, JR}
{9/12/90, added MovesComment, SeqLabC in for PostScript, JR}

{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/27/91
Modified: Fanuc 0T Mate MS L031.71.4
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{08/02/91
Updated: Fanuc 0T Mate MS L031.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{4/10/92
Updated: Fanuc 0T Mate MS L031.82
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 0T/3T Miyano L008.82.1 Format.
KM}

{8/26/95, Updated Fanuc 0T Mate MS L031.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{
Format: Fanuc 0T MS Lxxx.85.1
10/3/95
For: Haas Automation
Removed tool ofset cancels.
Put tool offset in place of offset cancel at start if operation
Changed to R format arcs
TH}

{7/14/97,
Initial: received modified post from Don Shultze of CEL
Created: Sinumerik [NE] Lxxx.85
For: Northern Engraving
added support for gear changes on rapid moves during non-canned roughing,
MPK}

{10/10/97,
Initial: Siemens 3T Tacchi [NE] L614.85
Created: Siemens 3T Tacchi [NE] L614.85.1
added getGearDrection sub and modified tpCheckGear to allow the post to only shift gears
in one direction per op.
Cleaned up stCheckGear.
MPK}

{10/16/97,
Initial: Siemens 3T Tacchi [NE] L614.85.1
Created: Siemens 3T Tacchi [NE] L614.85.2
removed literal testing routine that was mistakenly left in the tpCheckGear,
changed LOffsetOff to OpToolID at program end,
fixed output of wrong X coord when shifting between gear 2 and 3 in tpCheckGear,
MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '###.####;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2)
FORMAT(DIV#,2)
FORMAT(SUB#,2)
FORMAT(Recall#,2)
FORMAT(InFeedAngle#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(EPX#,2)
FORMAT(EPZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(CutDepth#,5)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(HOMEX#,2)
FORMAT(HOMEZ#,2)

{Prog Subroutines **********************************************************}

checkGear:
IF ConstantSurfaceFeed?
IF NOT Metric?
Save# Num#('5') Abs# DIV# MUL# Num#('12') SpeedSFPM# MUL# Num#('3.1416') CycleStartX#
ELSE
Save# Num#('5') Abs# DIV# MUL# Num#('1000') SpeedSFPM# MUL# Num#('3.1416') CycleStartX#
END

{ **** This section then saves into a variable what the gearrange was at the feature SP ***}
IF LessThan? Recall# Num#('5') Num#('100')
SeqLabC 'M41' EOL
Save# Num#('6') Num#('1')
ELSE
IF LessThan? Recall# Num#('5') Num#('275')
SeqLabC 'M42' EOL
Save# Num#('6') Num#('2')
ELSE
SeqLabC 'M43' EOL
Save# Num#('6') Num#('3')
END
END
ELSE
IF LessThan? SpeedRPM# Num#('100')
SeqLabC 'M41' EOL
Save# Num#('6') Num#('1')
ELSE
IF LessThan? SpeedRPM# Num#('275')
SeqLabC 'M42' EOL
Save# Num#('6') Num#('2')
ELSE
SeqLabC 'M43' EOL
Save# Num#('6') Num#('3')
END
END
END
RETURN

stCheckGear: {checks for necessary gear changes in ApproachSP when SameTool? is true}
IF SameTool?
IF ConstantSurfaceFeed?

{saves into a var which X pos will be used, depending on approach type}
IF ApproachFace?
Save# Num#('10') CycleStartX#
ELSE
Save# Num#('10') XOpCD#
END

{ **** This section Calculates CSS RPM at Cycle start ***}
IF NOT Metric?
Save# Num#('5') Abs# DIV# MUL# Num#('12') SpeedSFPM# MUL# Num#('3.1416') Recall# Num#('10')
ELSE
Save# Num#('5') Abs# DIV# MUL# Num#('1000') SpeedSFPM# MUL# Num#('3.1416') Recall# Num#('10')
END

{ **** This section then saves into a variable what the gearrange will be at the Cycle start. ***}
IF LessThan? Recall# Num#('5') Num#('100')
Save# Num#('7') Num#('1')
ELSE
IF LessThan? Recall# Num#('5') Num#('275')
Save# Num#('7') Num#('2')
ELSE
Save# Num#('7') Num#('3')
END
END

{outputs the gearchange and other required code}
IF NOT Equal? Recall# Num#('6') Recall# Num#('7')
SeqLabC SpinOff EOL
SeqLabC 'G04F1.' EOL
IF Equal? Recall# Num#('7') Num#('1')
SeqLabC 'M41' EOL
Save# Num#('6') Num#('1')
ELSE
IF Equal? Recall# Num#('7') Num#('2')
SeqLabC 'M42' EOL
Save# Num#('6') Num#('2')
ELSE
SeqLabC 'M43' EOL
Save# Num#('6') Num#('3')
END
END
SeqLabC Preset MaxRPM EOL
SeqLabC SpinOn EOL
SeqLabC 'G04F1.' EOL
END
END
END
RETURN

getGearDirection:
{Determines the direction of the cutting in order to determine which direction to allow gear changes}
IF Roughing? AND NOT CannedCycle? AND ConstantSurfaceFeed?
EachFeat
IF LastFeat?
Save# Num#('10') EPX#
END
IF GTEqual? CycleStartX# Recall# Num#('10')
SetFlag('2')
SetFlagF('1')
ELSE
SetFlag('1')
SetFlagF('2')
END
NextFeat
END
RETURN

tpCheckGear: {checks gears inside of toolPath}

{*** This sub was modified 10/10/97 to only allow the post to shift gears one direction per operation.}
{*** If the calculated RPM dictates a gear change in the opposite direction than what has been established,}
{*** the gear change will be suppressed}

IF Roughing? AND NOT CannedCycle? AND ConstantSurfaceFeed?

{ **** This section Calculates CSS RPM at feature EP ***}
IF NOT Metric?
Save# Num#('5') Abs# DIV# MUL# Num#('12') SpeedSFPM# MUL# Num#('3.1416') EPX#
ELSE
Save# Num#('5') Abs# DIV# MUL# Num#('1000') SpeedSFPM# MUL# Num#('3.1416') EPX#
END
{ **** This section then saves into a variable what the gearrange will be at the feature EP ***}
IF LessThan? Recall# Num#('5') Num#('100')
Save# Num#('7') Num#('1')
ELSE
IF LessThan? Recall# Num#('5') Num#('275')
Save# Num#('7') Num#('2')
ELSE
Save# Num#('7') Num#('3')
END
END

{*** This section allows gear changes to occur in the downward direction only if that is the direction determined by getGearDirection}

IF Flag?('1')
IF LessThan? Recall# Num#('7') Recall# Num#('6')
IF Equal? SPX# EPX#
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF NOT Equal? SPZ# EPZ#
IF Equal? Recall# Num#('6') Num#('1')
SeqLabC 'X' Recall# Num#('8') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('8') SPX#
ELSE
IF Equal? Recall# Num#('6') Num#('2')
IF Equal? Recall# Num#('7') Num#('1')
SeqLabC 'X' Recall# Num#('8') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('8') SPX#
END
ELSE
SeqLabC 'X' Recall# Num#('9') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('9') SPX#
END
END
END
EOL
END
SeqLabC SpinOff EOL
SeqLabC 'G04F1.' EOL
IF Equal? Recall# Num#('7') Num#('2')
SeqLabC 'M42' EOL
Save# Num#('6') Num#('2')
ELSE
SeqLabC 'M41' EOL
Save# Num#('6') Num#('1')
IF Equal? Recall# Num#('6') Num#('1') AND Equal? Recall# Num#('7') Num#('2')
SeqLabC RapidC MoveXC MoveZC EOL
END
END
SeqLabC Preset MaxRPM EOL
SeqLabC SpinOn EOL
SeqLabC 'G04F1.' EOL
END
END

{*** This section allows gear changes to occur in the upward direction only if that is the direction determined by getGearDirection}

IF Flag?('2')
IF GreaterThan? Recall# Num#('7') Recall# Num#('6')
IF Equal? SPX# EPX#
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF NOT Equal? SPZ# EPZ#
IF Equal? Recall# Num#('6') Num#('1')
SeqLabC 'X' Recall# Num#('8') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('8') SPX#
ELSE
IF Equal? Recall# Num#('6') Num#('2') AND Equal? Recall# Num#('7') Num#('1')
SeqLabC 'X' Recall# Num#('8') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('8') SPX#
ELSE
SeqLabC 'X' Recall# Num#('9') 'Z' SUB# SPZ# DIV# SUB# SPZ# EPZ# DIV# SUB# EPX# SPX# SUB# Recall# Num#('9') SPX#
END
END
END
EOL
END
SeqLabC SpinOff EOL
SeqLabC 'G04F1.' EOL
IF Equal? Recall# Num#('7') Num#('2')
SeqLabC 'M42' EOL
Save# Num#('6') Num#('2')
ELSE
SeqLabC 'M43' EOL
Save# Num#('6') Num#('3')
IF Equal? Recall# Num#('6') Num#('1') AND Equal? Recall# Num#('7') Num#('2')
IF NOT Equal? SPX# EPX#
SeqLabC RapidC MoveXC MoveZC EOL
END
END
END
SeqLabC Preset MaxRPM EOL
SeqLabC SpinOn EOL
SeqLabC 'G04F1.' EOL
END
END
END
RETURN

CalcBreakPoint:
{*** This sub calculates the X points at which a gear chang is appropriate given the current SFPM}
IF ConstantSurfaceFeed?
Save# Num#('8') Abs# DIV# MUL# Num#('12') SpeedSFPM# MUL# Num#('3.1416') NUM#('100')
Save# Num#('9') Abs# DIV# MUL# Num#('12') SpeedSFPM# MUL# Num#('3.1416') NUM#('275')
END
RETURN

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
stCheckGear
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
stCheckGear
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed SpinOn EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G95' Speed EOL
END
END
IF LAST ProgStop?
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
getGearDirection
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
tpCheckGear
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
SeqLabC Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
SeqLabC Rapid
ELSE
SeqLabC RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('850')
SetMaxFeed('100')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'%' ProgNum
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
SeqLabC 'G54' EOL
SeqLabC 'G90' EOL
SeqLabC checkGear EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
IF ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' Speed SpinOn EOL
SeqLabC OpToolID LatheOffset EOL
ELSE
SeqLabC ' G95' Speed SpinOn EOL
SeqLabC OpToolID LatheOffset EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC 'G0X' HomeX# CoolOff EOL
SeqLabC 'Z' HomeZ# SpinOff EOL
SeqLabC LOfstOff '00' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}
DoOpComments
DoPostScript
SeqLabC checkGear EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
IF ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' Speed SpinOn EOL
SeqLabC OpToolID LatheOffset EOL
ELSE
SeqLabC ' G95' Speed SpinOn EOL
SeqLabC OpToolID LatheOffset EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
CalcBreakPoint
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth 'R' CutDepth# EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLabC StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLabC StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLabC Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'07' {.7 thread lead distance for chamfer}
ELSE
'00'
END
IF SingleEdgeCut?
'60' {using 60 for standard tool angle, need ToolAnge# command}
ELSE
'00'
END
'Q'
IF ConstantVolumeCut?
'20' {.0020 minimum cut depth}
ELSE
CutDepth# {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
'R0' {using zero for no finish stock allowance, need XStckLeft# command}
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04F2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
SeqLabC Rapid
ELSE
SeqLabC RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF ConstantSurfaceFeed?
END
SeqLabC 'G0X' HOMEX# CoolOff EOL
SeqLabC 'Z' HOMEZ# SpinOff EOL
SeqLabC OpToolID '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END