{Change Comments ***********************************************************}

{9/19/95, L201.82.1m, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.02 Format, DWB}

{9/19/95
Copied: Fanuc 0TA Colchester L201.85m
Created: Fanuc 0TA [C&W] L379.85m
For: Fructus/C&W
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.22/Compost 4.21.32/1.0a
Changes made per Mikael Bagge of Fructus.
Form changes:
Changed G92 to G50 in Commands 1 Dialog.
Changed FORMAT for P ThreadHeight from ^###0 to ^##0 in Canned Threading Dialog
Changed FORMAT for Q Depth of First Thread Pass from ^###0 to ^##0 in Canned Threading Dialog
Prog changes:
Modified Canned Threading.
Moved InfeedAngle# from FORMAT#2 to FORMAT#6.
Output as two digit integer part of 6 digit P Parameter of two-block cycle definition.
Deleted Chamfer condition at CannedCycle Threading.
Outputs literal '00' always for Thread Ending Angle.
Deleted SingleEdgeCut condition at CannedCycle Threading.
Outputs InFeedAngle# for Thread Lead Angle.
Modified Canned PeckChipBreaker.
Added Retract# to FORMAT#4, changed Retract to 'R' Retract# at Canned Drilling.
Added Peck# to FORMAT#4, changed Retract to 'Q' Peck# at Canned Drilling.
Deleted Chamfer condition at CannedCycle Threading.
Outputs literal '00' always for Thread Ending Angle.
Deleted SingleEdgeCut condition at CannedCycle Threading.
Outputs InFeedAngle# for Thread Lead Angle.
Added support of special M13/M14 [CW/CCW] Spindle/Coolant combo command.
Added GetSpinCoolOn sub prior to CheckOffset sub.
Called during all ToolChange and ProgStop events.
Outputs normal SpinOn when CoolOff? boolean returns TRUE.
Changed SpinOn to GetSpinCoolOn call at CheckOffset sub, FirstOperation and NewTool.
Deleted CoolOn when LAST ProgStop? returns TRUE at CheckOffset sub.
Deleted CoolOn at AppMove sub.
Added G96 ConstantSurfaceSpeed TurnOn at ToolChange Position.
Deleted CalcRPM1 at FirstOperation and NewTool.
Moved CSSOn 'G96' Speed from CommonPoint to FirstOperation and NewTool.
Deleted CSSOff 'G97' CalcRPM2 at NewTool.
Deleted CSSOff 'G97' CalcEPRPM# at end of Prog.
Changed OpToolID '00' to OpToolID LatheOffset at FirstOperation and NewTool.
Deleted OpToolID LatheOffset from AppMove sub.
Deleted all NewGear and GearRange Commands at CheckOffset sub, FirstOperation and NewTool.
Added SetAbs at setup and initializations.
Changed MoveType$ to literal 'ABSOLUTE' at FirstOperation ProgramComments.
Deleted AbsOrInc 'G21G95' SafeStart at FirstOperation.
Deleted UnTool '00' at end of Prog.
DWB}

{6/5/96
Initial: Fanuc 0TA [C&W] L379.85m
Created: Fanuc 0TC [Gimbel] Lxxx.85m
ForUser: Gimbel
Control: Fanuc 0T-C
Machine: Victor V Turn
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New processor per notes from Kim Vind Andersen
Changed GetSpinCoolOn to standard SpinOn and added CoolOn commands.
Changed G33 threading command to G32.
Jim Radcliffe}

{12/23/96
Initial: Fanuc 0TC [Gimbel] L461.85m
Created: Fanuc 0TC [Gimbel] L461.85.1m
ForUser: Gimbel
Develop: ComPost2 PPC v1.0b4, Virtual Gibbs 3.23
Comment: Modified per fax.
Deleted tool offset cancel on Home lines.
Jim Radcliffe}

{2/18/97
Initial: Fanuc 0TC [Gimbel] L461.85.1m
Created: Fanuc 0TC [Gimbel] L461.85.2m
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Changed SetMaxRPM from 2000 to 6000
Jim Radcliffe}

{1Sep97
Original: Fanuc 0TC [Gimbel] L461.85.2m
Created: Seimens 805 [Gimbel] Lxxx.85m
For: Gimbel
Changes made per: Kim Vind Andersen
Deleted version literals e.g. {.72}, {.62} and {commands}, {literals} etc.
Added formatting for Thread# and DIV# at Prog Numeric Format Definitions
Changed G32 threading command to G33 in Toolpath and AutoFinish
Deleted ThrdLead in Toolpath and AutoFinish, replaced with a literal 'K' followed by the inverse of Thread#
Added Literal 'MPD' Program# in FirstOperation
Added Literal 'D' before LatheOffset in FirstOperation, NewTool and CheckOffset
Changed Arc Label from 'R' to 'B' in MachSpec
Changed Prestet from G50 to G92 in MachSpec
Added ProgStop before each process at FirstOperation, NewTool, CheckOffset and at the End of Prog
NOTE: This Lathe has a manual ToolChange.
Deleted EOR after 'M30' at end of Prog.
Charles Winston}

{18Nov97
Original: Seimens 805 [Gimbel] L634.85m
Created: Seimens 805 [Gimbel] L634.85.1m
For: Gimbel
Changes made per: Kim Vind Andersen
Deleted ProgStop in CheckOffset ( Not required for SameTool )
Charles Winston}

{2Dec97
Original: Seimens 805 [Gimbel] L634.85.1m
Created: Seimens 805 [Gimbel] L634.85.2m
For: Gimbel
Changes made per: Kim Vind Andersen
Deleted ProgStop in FirstOperation and End of Program ( Not required )
Added Literal 'M50' at Common point IF NOT SameTool
Charles Winston}

{9Dec97
Original: Seimens 805 [Gimbel] L634.85.2m
Created: Seimens 805 [Gimbel] L634.85.3m
For: Gimbel
Changes made per: Kim Vind Andersen
Deleted ProgStop in FirstOperation and End of Program ( Not required )
Moved Literal 'M50' from Common point to ApproachSP
Charles Winston}

{4/14/98
Updated & Modified: Seimens 805 [Gimbel] L634.85.3m
Created: Siemens 805 [Gimbel] L634.85.4m
For: Gimbel
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Kim Vind Andersen of Gimbel
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85m Format.
Customer requested that G4P2000 be output at G4F2.
Changed FORMAT#4 from #####^##0 to #####.###;0. at Prog Numeric Format Definitions.
Added FORMAT#8, #####^##0 at Prog Numeric Format Definitions.
Changed Retract# from FORMAT#4 to FORMAT#8 at Prog Numeric Format Definitions.
Changed Peck# from FORMAT#4 to FORMAT#8 at Prog Numeric Format Definitions.
Changed G4P2000 to G4F2. at ToolPath.
Changed G4P to G4F at ToolPath.
Changed G4P to G4F at CannedCycle Drilling.
Changed G4P2000 to G4F2. at end of EachTool/NextTool Loop.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.###;0.'
#3 = '#######0'
#4 = '#####.###;0.'
#5 = '#.######;0.'
#6 = '##00'
#7 = '#'
#8 = '#####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(DIV#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(CutDepth#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(InFeedAngle#,6)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Retract#,8)
FORMAT(Peck#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NOT SameTool?
SeqLabC 'M50' EOL
END
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NOT SameTool?
SeqLabC 'M50' EOL
END
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF NewToolOffset?
SeqLabC LOfstOff 'D00' EOL
SeqLabC OpToolID 'D' LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
CSSOn
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G96' Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
'G96' Speed
END
ELSE
CSSOff
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
IF NOT EmptyLine?
SeqLabC {SpeedC} SpinOn EOL
END
SeqLabC CoolOn EOL
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4F2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4F' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid
END
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC 'K' DIV# Num#('1') Thread# EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('6000')
IF Metric?
SetMaxFeed('200')
ELSE
SetMaxFeed('7.8740157480314')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR 'MPF ' Program# EOL
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC CSSOn 'G96'
ELSE
SeqLab CSSOff 'G97'
END
Speed OpToolID 'D' LatheOffset SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome SpinOff EOL
SeqLabC 'M0' EOL

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC CSSOn 'G96'
ELSE
SeqLab CSSOff 'G97'
END
Speed OpToolID 'D' LatheOffset SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R' CutDepth# EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {1 finish passes}
ELSE
'01'
END
'00' { Thread Ending Angle }
InFeedAngle# { Thread Lead Angle = SingleEdgeCut/Thread Angle; Balanced = 0 }
IF ConstantVolumeCut?
'Q20' {.0020 minimum cut depth}
ELSE
'Q' CutDepth# {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
'R0' {using zero for no finish stock allowance, need XStckLeft# command}
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
ELSE
IF Drilling?
IF PeckChipBreaker?
SeqLabC LCycle 'R' Retract# EOL
SeqLabC LCycle ZDepth 'Q' Peck# 'R0' FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC FeedC ZDepth EOL
IF Dwell?
SeqLabC 'G4F' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
ELSE
SeqLabC 'G98' EOL
SeqLabC LCycle XSP 'C0' ZDepth 'R0'
IF Peck?
'Q' Peck#
END
Dwell FeedRate
IF AutoFinish?
'K2'
ELSE
'K1'
END
EOL
SeqLabC DrillOff EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ 'K' DIV# Num#('1') Thread# EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4F2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
SeqLabC FirstHome SpinOff EOL
SeqLabC EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END