{Change Comments ***********************************************************}

{8/29/95, L155.82.1, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85 Format, DWB}
{
Format: Siemens 810T EM Lxxx.85.1
10/16/95
Changed G55 to G54
Removed M51 from tool change
Added 'L1P1' to tool change
TH}

{
Format: Siemens 810T EM Lxxx.85.2
10/17/95
Added 'H1030R1=' HomeX# 'R2=' HomeZ# to first operation
TH}

{
Format: Siemens 810T [TCR] EM L390.85.3
For: TCR Corp
Per: Bill Mattson
1/15/95
Removed Home and NewHome lines. Handled by R1 and R2
Implemented canned threading based on L330.85.3 (Hyundai control made by Siemens uses same parameters)
Changed start-up block codes per customer's fax 1-15-95
TH}

{
Format: Siemens 810T [TCR] EM L390.85.4
For: TCR Corp
Per: Bill Mattson
1/18/95
Changed OpToolID 'D' ToolOffset# to T1D1 in FirstOp
Added OpToolID 'D' ToolOffset# after M0.
TH}

{2/2/96
Modified: Siemens 810T [TCR] EM L390.85.4
For: TCR Corp
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v2.28.08/Compost 4.21.34/1.0a
Changes made per Bill Mattson, fax, vnc/ncf files and phone conversations.
Customer reported problems with the tool going to bad XCP.
Customer wants programs to start with a blank tool for macro reasons.
Post was using XCP ZCP values to control this tool, but post is set up to use these values
whenever moving between operations.
Customer has agreed to program a pseudo drill operation at the start.
Post will use XSP ZSP values.
Post can now correctly use ThisOpEntryXCP, ThisOpEntryZCP, OpExitXCPC and OpExitZCPC commands.
Post bypasses any call to Toolpath and exit clearance moves for FirstOperation only.
Customer must program a ToolChng at SecondOperation.
Commented out DoOpComments at FirstOperation.
Changed XCP ZCP to XSP ZSP at FirstOperation.
Deleted all blocks following literal M0 at FirstOperation.
Added condition to bypass exit clearance move at NewTool.
Bypass occurs for FirstOperation to NewTool transition only.
Added condtion to bypass entire source code between common point and NextOp command.
Bypass occurs for FirstOperation only.
Added EOR EOL at end of prog.
DWB}

{2/5/96
Modified: Siemens 810T [TCR] EM L390.85.5
For: TCR Corp
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v2.28.08/Compost 4.21.34/1.0a
Changes made per Bill Mattson via phone conversation.
Reversed order of Formulas for outputting R21 and R31 parameters at Canned Cycle Threading.
Deleted reporting blocks left in by previous developer at Canned Cycle Threading.
Added # to CalcNumCuts at Canned Cycle Threading.
DWB}

{2/13/96
Modified: Siemens 810T [TCR] EM L390.85.6
For: TCR Corp
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.0/Compost 4.21.34/1.0a
Changes made per Bill Mattson via faxes, sample files and phone conversations.
Moved SpinOn from OpToolID block to Speed Block at NewTool.
DWB}

{4/8/96
Modified: Siemens 810T [TCR] EM L390.85.7
For: TCR Corp
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.07/Compost 4.21.34.1/1.0a
Changes made per Bill Mattson via via phone conversation.
Deleted EOR EOL at end of prog.
DWB}

{7/3/96
Modified: Siemens 810T [TCR] EM L390.85.8
Created: Siemens 810T [TCR] EM L390.85.9
For: TCR Corp
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Bill Mattson via via phone conversation.
Modified 2/2/96 handling of BarStop at FirstOperation.
Post now outputs based on FirstOperation Tool.
If Tool#=1, BarStop code is output.
Any other and normal G-Code is output.
Added Tool#1 Test at FirstOperation.
Added Flag(1) for easier support.
Changed all FirstOperation Booleans related to BarStock to Flag(1) booleans at NewTool, common
point, and end of Prog.
Added Flag(1) boolean at SameTool.
Allows user to machine with BarStop Tool.
DWB}

{8/19/96
Copied: Siemens 810T [TCR] EM L390.85.9
Created: Siemens 3T4C [LTV] L505.85
For: LTV Steel Company
Machine: Niles
Control: Siemens 3T/4C
Versions: Catalyst v3.05.03C/Compost 4.21.37/v1.0b1
Changes made per Joe Yurkus of LTV Steel Company, faxes and phone calls.
Changed FORMAT#2 from ####.####;0 to #####.####;0 at Prog Numeric Format Definitions.
Changed FORMAT#6 from 0000 to 00 at Prog Numeric Format Definitions.
Added Program2# to FORMAT#3 at Prog Numeric Format Definitions.
Changed ToolOffset# from FORMAT#3 to FORMAT#5 at Prog Numeric Format Definitions.
Added support for Tailstock Approach at AppMove.
Added ChipOn sub called from Approach sub.
Outputs M69, Chip Conveyor On code for FirstOperation Approach.
Added GetSpinOn sub called from CheckOffset, FirstOperation and NewTool.
Outputs M13/M14, CoolOn/SpinOn code.
Outputs M03/M04 for CoolOff/Spind code.
Changed format for G and M codes to output leading zero in form and prog.
Changed all literal 'G95' codes to 'G97' for NOT ConstantSurfaceFeed Operations.
Deleted support of Flag(1) for BarStock operations.
Modified safe start and other codes at FirstOperation, NewTool, SameTool and end of Prog.
Program2# is reserved for ToolChange sub.
Added output of ToolChange sub following EOP and prior to Post commands at end of Prog.
Modified parameters for Canned RoughContour, Threading and PeckChipBreaker Cycles.
DWB}

{7/31/97
Initial: Siemens 3T4C [LTV] L505.85
Created: Siemens 3T4C [LTV] L505.85.1
modified ckCRC to make output of CRCOnC conditional upon CannedCycle? being false, Canned
cycle definitions include CRC info already,
modified canned roughing cycle:
deleted SeqC StepMove StrtPos EOL from cycle subroutine,
moved SetPass2 to before output of cycle parameters R21 & R22 (these are the X and Z startpos)
so that the coords are for the finished shape,
deleted literal '=' from all cycle defs,
MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.####;0'
#3 = '#######0'
#4 = '#####.###;0'
#5 = '00'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(SUB#,2)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(StockXRadius#,2)
FORMAT(StockZ#,2)
FORMAT(CutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(Retract#,2)
FORMAT(Peck#,2)
FORMAT(HomeX#,2)
FORMAT(HomeZ#,2)
FORMAT(SpringPasses#,2)
FORMAT(RunInZ#,2)
FORMAT(RunOutZ#,2)
FORMAT(InFeedAngle#,2)
FORMAT(TrackX#,2)
FORMAT(TrackZ#,2)
FORMAT(CalcNumCuts#,3)
FORMAT(Program2#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ToolOffset#,5)
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
IF NOT FirstOperation? { FOR TAILSTOCK, .82 }
EOL
SeqC
END
RETURN

ChipOn:
IF FirstOperation?
'M69' { Chip Conveyor On }
END
RETURN

Approach: { FOR TAILSTOCK, .82 }
Rapid AbsOrInc RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC AppMove ThisOpEntryXCP ChipOn EOL
ELSE
IF ApproachID?
SeqC AppMove XOpCD ChipOn EOL
ELSE {ApproachFace}
SeqC AppMove StockOnNoCan XSP ChipOn EOL
END
END
ApproachSP
RETURN

GetSpinOn:
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID ToolOffset# EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn 'G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn 'G96' Speed
END
END
ELSE
SeqC Preset MaxRPM EOL
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqC {SpeedC} GetSpinOn EOL
ELSE
SeqC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT CannedCycle?
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC FeedRateC EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
Seq 'G70' AbsOrInc 'G54M40' EOL { Inch, Select Zero Offset 1, Speed Range Low }
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96' FeedRate Speed GetSpinOn EOL
SeqC Preset MaxRPM EOL
ELSE
IF Threading?
'G95' { FeedRate Inches Per Minute }
END
SeqC CSSOff 'G97' FeedRate Speed GetSpinOn EOL
END
NewProg
SaveProgNum2
SeqC OpToolID '00L' Program2# EOL
SeqC OpToolID ToolOffset# EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpToolID '00L' Program2# EOL
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
Seq CSSOn 'G96' FeedRate Speed GetSpinOn EOL
SeqC Preset MaxRPM EOL
ELSE
IF Threading?
'G95' { FeedRate Inches Per Minute }
END
Seq CSSOff 'G97' FeedRate Speed GetSpinOn EOL
END
SeqC OpToolID ToolOffset# EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass1
NewProg
SetPass1
SeqC
IF ApproachOD?
'R29 31'
ELSE
IF ApproachID?
'R29 33'
ELSE {OD ApproachFace}
'R29 32' { R29 34 is for ID ApproachFace }
END
END
FORMAT(Program#,6)
'R20 ' Program#
'R27 '
IF CutterRadiusCompensation?
IF CutterLeft?
'41'
ELSE
'42'
END
ELSE
'40'
END
SetPass2
'R21 ' TrackX# CycleStartXDia# { StartPoint of Contour X }
EOL
SeqC
'R22 '
TrackZ# CycleStartZ# { StartPoint of Contour Z }
'R24 ' StockXRadius# { X Finish Cut Depth }
'R25 ' StockZ# { Z Finish Cut Depth }
'R26 ' CutDepth#
EOL
SeqC 'L9501' EOL
OpenSub
'L' Program# '00' EOL
DoSubComment
{SeqC StepMove StrtPos EOL}
ToolPath
SeqC 'M17' EOL
CloseSub
IF AutoFinish?
SeqC
IF ApproachID?
'R29 23'
ELSE
'R29 21'
END
'R24 0' { StockXRadius }
'R25 0' { StockZ }
EOL
SeqC 'L9501' EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqC
'R21 ' { StartPoint X }
IF ApproachID?
ADD# CycleStartXDia# DiaDistanceToThread#
ELSE
SUB# CycleStartXDia# DiaDistanceToThread#
END
'R22 '{ StartPoint Z }
IF ZMinusCutDir?
SUB# CycleStartZ# RunInZ#
ELSE
ADD# CycleStartZ# RunInZ#
END
'R31 ' { End Point X }
IF Taper?
Save# Num#('1') SUB# FinishZ# CycleStartZ# { Z Delta }
Save# Num#('2') DIV# Taper# Recall# Num#('1') { Slope of Taper }
Save# Num#('3') MUL# Recall# Num#('1') Recall# Num#('2')
IF ApproachID?
ADD# FinishXDia# Recall# Num#('3')
ELSE
SUB# FinishXDia# Recall# Num#('3')
END
ELSE
IF ApproachID?
ADD# CycleStartXDia# DiaDistanceToThread#
ELSE
SUB# CycleStartXDia# DiaDistanceToThread#
END
END
EOL
SeqC
'R32 ' { End Point Z }
IF ZMinusCutDir?
ADD# FinishZ# RunOutZ#
ELSE
SUB# FinishZ# RunOutZ#
END
'R26 ' RunInZ# { Approach Path }
'R27 ' RunOutZ# { Run Out Path }
IF ApproachID?
'R24 ' ThreadXInc#
ELSE
'R24 -' ThreadXInc#
END
EOL
SeqC
'R20 ' FeedIPR#
'R25 ' StockXRadius#
'R28 ' CalcNumCuts#
'R29 ' InFeedAngle#
EOL
SeqC 'R23 ' SpringPasses# EOL
SeqC 'L9701' EOL
ELSE
IF Drilling?
IF PeckChipBreaker?
SeqC
'R22 ' CycleStartZ#
'R24 ' Retract# { Peck decrease amount }
'R25 ' Peck#
'R26 ' FinishZ#
'R27 ' Dwell# { Dwell at start }
'R28 ' Dwell# { Dwell at end }
EOL
SeqC 'L9801' EOL
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqC 'G33'
IF Taper?
'X' MUL# Num#('2') FinishXRadius#
END
'Z' FinishZ# EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
SeqC OpToolID '00L' Program2# EOL
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
SeqC EOR 'SP' EOL
SeqC 'L' Program2# '00' EOL
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program2# ' )' EOL
END
SeqC 'G53' AbsOrInc Rapid 'X' FIRST HomeX# EOL { Suppress X Zero Offset }
SeqC 'G53' Rapid 'Z' FIRST HomeZ# EOL { Suppress Z Zero Offset }
SeqC EndSub EOL
Post
Close
Reopen
SeqC 'M02' EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END