{Change Comments ***********************************************************}

{8/18/89
Modified: Fanuc 0M (G54) M107.54
For: Pete
Modified SubCall FORMAT.
JR}

{10/13/89, Updated: Fanuc OM (G54) M107.55, P.S. & SepSubs commented out, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/14/91, Updated Fanuc 0M G54 M107.57 to .80 format, JR}

{10/29/91
Updated: Fanuc 0M G54 M107.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
KM}

{10/20/92
Updated: Fanuc 0M G54 M107.81
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
DWB}

{8/18/95, Updated Fanuc 0M G54 M107.81.2 to .85 format, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{5/30/96
Initial: Fanuc 0M G54 M107.89
Created: Fanuc 0M Robodrill Mxxx.89
ForUser: Aavid
Control: Fanuc 0MB
Machine: Robodrill
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New processor per marked up readout
Moved WFOStuff to StrtPos line.
Moved CoolOn to StrtPos line.
Moved Speed & SpinOn to OfstOn line.
Added StrtPos to SetWFO line for OneToolAllParts AND ExitClearancePlane.
Deleted WFO1 from CloseMP.
Added IncValue OfstOff to begin program.
Added 'G49' to tool change line.
Moved ProgStop to after tool change.
Changed Program ID label to a colon.
Changed 'M98P1' to 'M98P'.
Added Rigid Tapping.
Jim Radcliffe}

{6/24/96
Initial: Fanuc 0M Robodrill ATT M219.89
Created: Fanuc 0M Robodrill ATT C219.12
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Created Advanced Mill version per Bob Winchester.
Changed to First Tool In Spindle format.
Deleted G91G28Z0M9 from tool change positions.
Added extended WFOs G54 thru G59 then G54P1 thru G54P48.
Jim Radcliffe}

{7/9/96
Initial: Fanuc 0M Robodrill ATT C219.12
Created: Fanuc 0M Robodrill ATT C219.121
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Modificatons per Steve Wood
Commented out CSWFOComment
Changed CRC label from H to D
Changed D and H default formats to leading zeros
Removed IncValue OfstOff output from SameTool and ChangeCS.
Jim Radcliffe}

{8/12/96
Initial: Fanuc 0M Robodrill ATT C219.121
Created: Fanuc 0M Robodrill ATT C219.122
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Modified per marked up readout from Bob Winchester.
Corrections per Fanuc 6M (FW) B001.12.08
Jim Radcliffe}

{8/12/96
Initial: Fanuc 0M Robodrill ATT C219.122
Created: Fanuc 0M Robodrill ATT C219.123
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Added 'G91G30X0Y0' to EOP.
Jim Radcliffe}

{9/4/96
Initial: Fanuc 0M Robodrill ATT C219.123
Created: Fanuc 0M Robodrill ATT C219.124
Comment: Changed literal colons in comments to spaces.
Jim Radcliffe}

{12/2/96
Initial: Fanuc 0M Robodrill ATT C219.124
Created: Fanuc 0M Robodrill ATT C219.125
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per conversation with Steve Wood
Suppressed output of redundant WFO output when posting multiple parts.
Changed SetFlag('4') to SetFlagF('4') to prevent toggling of Inc/Dec WFO MPs.
Jim Radcliffe}

{1/31/97
Initial: Fanuc 0M Robdrill ATT C219.12.5
Created: Fanuc 0M Robdrill ATT C219.12.6
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Modified per fax from Bob Winchester at Acam
Deleted CoolOff commands and created ckCoolOff sub and called from OpGuts.
Jim Radcliffe}

{2/5/97
Initial: Fanuc 0M Robdrill ATT C219.12.6
Created: Fanuc 0M Kitamura ATT Cxxx.12
ForUser: Aavid Thermal Techmology
Control: Fanuc 0M
Machine: Kitamura
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout from Bib Winchester
Changed CoolOn and SpinOn commands to combined comand with DoSpinOn.
Added PreTool.
Deleted 'G49'.
Output OfstOff regardless of ToolChangeAtHome
was only being output if ToolChangeAtHome was true.
Added subs and calls AbsValueC, IncValueC & AbsOrIncC to simplify prog.
Modified RigidTap handling.
Deleted Saftey Start Block between tools.
Jim Radcliffe}

{2/13/97
Initial: Fanuc 0M Kitamura ATT CY22.12
Created: Fanuc 0M Kitamura ATT CY22.12.1
Comment: Modified per marked up readout
Moved spindle from ofstOn line to StrtPos line.
Modified Pretooling:
M106 puts tool from magazine, called with PreTool, into ready position.
Moved PreTool to OfstOn line.
Moved M106 line to ToolPath so it is called after machine starts its operation.
Jim Radcliffe}

{2/20/97
Initial: Fanuc 0M Kitamura ATT CY22.12.1
Created: Fanuc 0M Kitamura ATT CY22.12.2
Comment: Commented out CoolOff commands per marked up readout.
Jim Radcliffe}

{3/25/97
Initial: Fanuc 0M Kitamura ATT CY22.12.2
Created: Yasnac i80 Mat RAIIIF Cxxx.12
ForUser: Aavid Thermal Techmology
Control: Yasnac i80
Machine: Matsuura RAIIIF
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.31 PPC
Comment: New Processor per marked up readout from Steve Wood
Changed program label from ':' to 'O'.
Modified spindle commands:
Changed DoSpinOn to SpinOn.
Moved Speed & SpinOn commands to OfstOn line.
Modified coolant:
Added CoolOn to StrtPos line.
Un-commented out ckCoolOff.
Modified RigidTap:
Suppress output of Speed & SpinOn at beginning of operation.
G93 is output just before Cycle line.
Speed is on output Cycle line.
Feed is output in IPR.
G93 is output just after DrillOff line.
Deleted M106 line.
Changed 'G91G30X0Y0' EOP at end of program to 'M99'.
Jim Radcliffe}

{4/10/97
Initial: Yasnac I80 Mat [ATT] CY59.12
Created: Yasnac I80 Mat [ATT] CY59.12.1
Comment: Modified per marked up readout from Steve Wood.
Changed CoolOff handling to standard format.
Jim Radcliffe}

{12/17/97,
Initial : Yasnac I80 Mat [ATT] CY59.12.1
Created: Yasnac I80 Mat [LM] CW76.12
Customer: Liberty Machine

Changes to "Form":

1. Under Arcs, changed I-J Max Arc Radius from 100 to 0.
2. Under Default Formats, changed D & H format to #0.

Changes to "Prog":

1. Changed to FIRST TOOL NOT IN SPINDLE Comment and removed first block in InitOp sub.
2. Changed FirstOp1, 2 & 3 sub's to match the customer output.
3. Changed SetMaxRPM to 15000.
4. Changed NewToolOp1, 3, 4, & 5 sub's to match the customer output.
5. Changed SameToolOp3 sub to match the customer output.
6. Changed End1 & 2 sub's to match the customer output.
7. Removed Speed from RigidTap block.
8. Added Var 1 & 2 to output the rotaries as Incremental values.
9. Enable DoCSWFOComment back.
JHE}

{1/5/98,
Initial : Yasnac I80 Mat [LM] CW76.12
Created: Yasnac I80 Mat [LM] CW76.12.1
Customer: Liberty Machine

Changes to "Prog":

1. Changed SUB# FORMAT to 3.
2. Switched CSOffsetA# & B# order in SUB#.
3. Added IncValue to rotary motion in SameToolOp3.
4. Added Var 3 & 4 to move the rotaries, at tape END, to the start position.
JHE}

{1/15/98,
Initial : Yasnac I80 Mat [LM] CW76.12.1
Created: Yasnac I80 Mat [LM] CW76.12.2
Customer: Liberty Machine

Changes to "Form":

1. Under Arcs, un-checked Allow R-format Arcs.

Changes to "Prog":

1. Added Plane to first block & PlaneC to restart blocks.
JHE}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(Program#,7) {.72}
FORMAT(CallMasterNum#,7)
FORMAT(CSSubID#,7)
FORMAT(SUB#,3) {Added - JHE}

{Special WFO Subroutines ***************************************************}

CalcCSWFO#:
ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') CS#
RETURN

CSWFO:
IF GreaterThan? CalcCSWFO# Num#('6')
'G54P' ADD# CalcCSWFO# Num#('-6')
ELSE
'G' ADD# CalcCSWFO# Num#('53')
END
RETURN

WFO:
IF GreaterThan? PartNum# Num#('6')
'G54P' ADD# PartNum# Num#('-6')
ELSE
'G' ADD# PartNum# Num#('53')
END
RETURN

DoCSG52:
'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ#
RETURN

G52Stuff:
IF NOT MultipleParts?
IF NOT WFOCS?
IF ChangeCS?
SeqC DoCSG52 EOL
ELSE
IF NOT SameTool?
SeqC DoCSG52 EOL
END
END
END
ClearCSOffset
END
RETURN

WFOStuff:
IF Flag?('2')
IF WFOCS?
IF NOT SameTool?
CSWFO
ELSE
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is hadled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
ELSE
IF NOT SameTool?
WFO
END
END
SetFlagF('2')
END
RETURN

{Command Subroutines *******************************************************}

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

{Standard Prog Subroutines *************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )'
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

DoCSG52Comment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

OffsetComments:
IF NOT MultipleParts?
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
END
ELSE
IF ChangeCS?
DoCSG52Comment
ELSE
IF NOT SameTool?
DoCSG52Comment
END
END
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
OffsetComments
RETURN

CSAngleA:
IF AAxisAvail?
{'A' CSOffsetA#} {Abs Output, removed - JHE}
'A' SUB# CSOffsetA# Recall# Num#('1') {Inc Output, added - JHE}
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
{'B' CSOffsetB#} {Abs Output, removed - JHE}
'B' SUB# CSOffsetB# Recall# Num#('2') {Inc Output, added - JHE}
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'O' Program# DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLabB Repeats# Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
SeqC SubCall CallLabB Parts# Program# EOL
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSWFOComment
ClearCSOffset
IF Flag?('3') AND FirstPart? AND OneToolAllParts? AND ExitClearancePlane? AND NOT SameTool?
{skip redundant WFO output}
ELSE
IF NOT Flag?('3') AND LastPart? AND OneToolAllParts? AND ExitClearancePlane? AND NOT SameTool?
{skip redundant WFO output}
ELSE
SeqC CSWFO EOL
END
END
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
RETURN

DoCSG52Ops:
EachCSOp
DoCSG52Comment
ClearCSOffset
SeqC DoCSG52 EOL
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
RETURN

CloseMP:
SeqC AbsOrIncC EOL
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
IF Flag?('4')
DecWFO
ELSE
NewWFO
END
ELSE
LastWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
IF Flag?('4')
IncWFO
ELSE
LastWFO
END
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WorkFixtureOffsets?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLabB Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLabB Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLabB Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF RigidTap?
SeqC 'G93' EOL
END
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF RigidTap?
'F' FeedTapIPR#('1') {Removed Speed - JHE}
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLabB Program# EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
IF RigidTap?
SeqC 'G94' EOL
END
END
END
Save# Num#('1') CSOffsetA# {Rotary Abs Location - JHE}
Save# Num#('2') CSOffsetB# {Rotary Abs Location - JHE}
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('2') {WFO needs to be output}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlagF('4') {True = toggle between incrementing/decrementing WFO's }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('15000') {Changed from 10000 - JHE}
SetMaxFeed('800') {Changed from 500 - JHE}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('54')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('54') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

InitOp:
EOR EOL
'O' Program#
IF UseComments? AND ProgramNameComment?
'( PROGRAM ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL {Added NOT - JHE}
END
END
OpenSub
RestoreScale
{SeqC IncValue OfstOff EOL} {Removed this line - JHE}
RETURN

FirstOp1:
DoOpComments
SeqC 'G10Q2P1J1X0.Y0.Z0.' EOL {Added this line - JHE}
'N' Tool# Plane AbsOrInc 'G80G49' CRCOff OpToolID EOL {Added Plane - JHE 1/15}
SeqC ToolChng EOL {Added this line - JHE}
IF NOT LastTool? {Moved PreTool to here - JHE}
SeqC PreTool EOL
END
DoPostScript
G52Stuff
RETURN

FirstOp2:
CheckPass
SeqC AbsOrInc WFOStuff Rapid StrtPos Speed SpinOn EOL {Moved Speed SpinOn to here - JHE}
Save# Num#('3') CSOffsetA# {Rotary Location @ Start - JHE}
Save# Num#('4') CSOffsetB# {Rotary Location @ Start - JHE}
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
{IF NOT RigidTap? {Removed - JHE}
Speed SpinOn
END}
RETURN

NewToolOp1:
SeqC CoolOff EOL
SeqC IncValueC OfstOff 'Y0.' SpinOff EOL {Removed M19 and added Y0 SpinOff - JHE}
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrIncC Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
'N' Tool# PlaneC AbsOrInc 'G80G49' CRCOff OpToolID EOL {PlaneC - JHE 1/15}
SeqC ToolChng EOL
SeqC PreTool EOL {Moved PreTool to here - JHE}
DoOpComments
DoPostScript
G52Stuff
RETURN

NewToolOp4:
CheckPass
IF AChange? OR BChange?
SeqC 'M22' EOL {Unclamp Rotary - JHE}
SeqC Rapid IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M21' EOL {Clamp Rotary - JHE}
END
SeqC AbsOrInc WFOStuff Rapid StrtPos Speed SpinOn EOL {Moved Speed SpinOn to here - JHE}
RETURN

NewToolOp5:
SeqC OfstOn CoolOn EOL {Moved CoolOn to here - JHE}
{IF NOT RigidTap? {Removed - JHE}
Speed SpinOn
END}
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValueC OfstOff EOL
SeqC AbsOrInc 'G49' EOL {Added this line - JHE}
SeqC 'M0' EOL
ELSE
IF NewToolOffset?
SeqC IncValueC OfstOff EOL
SeqC AbsOrInc 'G49' EOL {Added this line - JHE}
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
G52Stuff
IF LAST ProgStop?
IF AChange? OR BChange?
SeqC 'M22' EOL {Unclamp Rotary - JHE}
SeqC Rapid IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M21' EOL {Clamp Rotary - JHE}
END
SeqC PlaneC AbsOrInc WFOStuff Rapid StrtPos Speed SpinOn EOL {Added PlaneC - JHE 1/15}
SeqC OfstOn CoolOn EOL
ELSE
IF AChange? OR BChange?
SeqC RapidC IncValue OfstOff EOL {Added this line - JHE}
SeqC 'M22' EOL {Unclamp Rotary - JHE}
SeqC RapidC IncValue CSAngleA CSAngleB EOL {Moved B before X & Y - JHE}
SeqC 'M21' EOL {Clamp Rotary - JHE}
SeqC PlaneC AbsOrInc WFOStuff Rapid StrtPos {Added PlaneC - JHE 1/15}
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
ELSE
SeqC PlaneC AbsOrInc WFOStuff Rapid StrtPos {Added PlaneC - JHE 1/15}
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
IF NewToolOffset?
SeqC OfstOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
SeqC RapidC IncValueC OfstOff 'Y0.' SpinOff EOL {Removed M19 and added Y0 SpinOff - JHE}
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC AbsOrIncC Rapid FirstHome EOL
END
{Move Rotary to First Location - JHE}
{'*** ' Recall# Num#('1') ' recall 1' EOL Use for Testing - JHE
'*** ' Recall# Num#('2') ' recall 2' EOL
'*** ' Recall# Num#('3') ' recall 3' EOL
'*** ' Recall# Num#('4') ' recall 4' EOL}
IF NOT Equal? Recall# Num#('2') Recall# Num#('4') {OR NOT Equal? Recall# Num#('1') Recall# Num#('3')}
SeqC 'M22' EOL
IF AAxisAvail?
SeqC RapidC IncValue 'A' SUB# Recall# Num#('3') Recall# Num#('1') EOL
END
IF BAxisAvail?
SeqC RapidC IncValue 'B' SUB# Recall# Num#('4') Recall# Num#('2') EOL
END
SeqC 'M21' EOL
END
IF ProgStop?
SeqC 'M0' EOL
{ELSE {Removed - JHE}
SeqC ProgStop EOL}
END
{SeqC UnTool ToolChng EOL} {Removed - JHE}
RETURN

End3:
SeqC AbsOrInc 'G80G49' CRCOff EOL {Added this line - JHE}
SeqC 'M99' EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
SetFlagF('2')
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
SetFlagF('2')
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ************************************}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END