{Change Comments ***********************************************************}

{9/12/95, M174.81.2, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{1/17/96 - Updated .85 to .86 format, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{3/6/97
Initial: BP Boss 9 M174.89
Created: BP EZ-Track DX M000.89
ForUser: Braden Engineering / Quality Mold
Control: Bridgeport EZ-Track 2 Axis
Machine: Bridgeport EZ-Track DX
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout and conversation with Paul Lovelace.
Changed format G codes to suppress leading zeros.
Changed ProgID1 to ':' Program# to remove decimal point from output.
Deleted sequnce number from macro call lines.
Changed Program Loops for Multiple Parts and Repeats to sub programs looping the sub call!
Changed ToolChng from M26 to M6.
Added Home to ToolChng line.
Commented out WFOStuff calls.
Replaced special Bridgeport Cutter Comp handling with standard stuff.
This gives control to the programmer!!
Corrected loop calls:
Changed RepLab to '/'
Changed Parts to Parts#
Changed RepCycs to Repeats#
Jim Radcliffe}

{5/8/97,
Intial: BP EZ-Trak DX MY78.89
Created: BP EZ-Trak DX MY78.89.1
Changed SaveMasterProg to SaveMasterTag, was causing incorrest output of program #s, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###^#0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
ASCII('39') ' SUB NUMBER: ' Tag# ' ' ASCII('39') EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
ASCII('39') ' OPERATION ' Operation# ': ' OperationType$ ' ' ASCII('39') EOL
END
IF OperationComment?
ASCII('39') ' ' OperationComment$ ' ' ASCII('39') EOL
END
IF WorkGroupComment?
ASCII('39') ' ' WorkGroupComment$ ' ' ASCII('39') EOL
END
IF ToolTypeComment?
ASCII('39') ' TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ' ASCII('39') EOL
END
IF ToolComment?
ASCII('39') ' ' ToolComment$ ' ' ASCII('39') EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'#' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
ASCII('39') ' ' ASCII('39') EOL
ASCII('39') ' ( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ) ' ASCII('39') EOL
ASCII('39') ' ' ASCII('39') EOL
END
END
RETURN

StdSub:
TagInc
'=Nł' Tag# '/' Repeats# EOL
'=#' Tag# EOL
'>' Tag# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC EOL
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
'$' EOL
CloseSub
SeqLab Preset ShiftRC EOL
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF WorkFixtureOffsets?
' ' EOL
' ( Note - Post does not support MultipleParts with WorkFixtureOffsets. )' EOL
' ( Please change to EquallySpacedOffsets. )' EOL
' ' EOL
ELSE
TagInc
'=Nł' Tag# '/' Parts# EOL
'=#' Tag# EOL
'>' Tag# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
'$' EOL
CloseSub
SeqLab Preset ShiftPC EOL
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not supported }
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
'=#' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
IF NOT XYPlane?
SeqLabC Plane EOL
END
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
ASCII('39') '*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' ASCII('39') EOL
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
'$' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
TagInc
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'=#' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
'$' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
TagInc
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
'=#' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
IF CutterRadiusCompensation?
SeqLabC Feed CRCOn StrtPos FeedRate EOL
END
ToolPath
FinishSub1
'$' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
SeqLabC {WFOStuff} EOL
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseYZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
':' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
ASCII('39') ' PROGRAM: ' ProgramName$ ' ' ASCII('39') EOL
END
IF ProgramComment?
ASCII('39') ' ' ProgramComment$ ' ' ASCII('39') EOL
END
IF FormatNameComment?
ASCII('39') ' FORMAT: ' FormatName$ ' ' ASCII('39') EOL
END
IF TimeComment?
ASCII('39') ' ' Date$ ' AT ' Time$ ' ' ASCII('39') EOL
END
IF MovesComment?
ASCII('39') ' OUTPUT IN ' MoveType$ ' INCHES ' ASCII('39') EOL
END
IF PartsComment?
ASCII('39') ' PARTS PROGRAMMED: ' Parts# ' ' ASCII('39') EOL
END
IF StartToolComment?
ASCII('39') ' FIRST TOOL NOT IN SPINDLE ' ASCII('39') EOL
END
END
OpenSub
RestoreScale
SeqLab Plane 'G80' AbsValue EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLabC Rapid {WFOStuff}
IF ToolChangeAtHome?
Home
END
OpToolID ToolChng EOL
SeqLabC Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC AbsOrInc EOL
END
CheckPass
SeqLabC RapidC StrtPos ZCP1 CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab Rapid PlaneC {WFOStuff}
IF ToolChangeAtHome?
Home
END
OpToolID ToolChng EOL
SeqLabC Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC AbsOrInc EOL
END
CheckPass
SeqLabC RapidC StrtPos ZCP1 CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC Speed SpinOn EOL
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC ToolOfst EOL
END
SeqLabC PlaneC AbsOrInc Rapid StrtPos ZCP1 CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END

{Start new Operation}

GetStartOfSameTool
SeqLabC SpeedC EOL
IF NewToolOffset?
SeqLabC ToolOfst EOL
END
SeqLabC PlaneC AbsOrInc Rapid StrtPos ZCP1 EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC CRCOffC EOL
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC ZCP2C EOL
GetCycle
IF Dwell?
SeqLabC 'G04/' Dwell# EOL
END
SeqLabC Cycle StrtPos ZDepthAbs Peck Retract FeedEnt EOL
IF CallMasterOp?
'=#' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
'=#' Tag# EOL
StartSub
ToolPath
'$' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' EOL
SeqLabC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid
IF ProgStop?
'M00' EOL
SeqLabC
END
IF MultipleParts? AND AllToolsOnePart?
EOL
CloseMP
SeqLabC
END
EOP EOL
CloseSub
Post2 {organize Subs into one program}
ASCII('19') EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
ASCII('39') ' FILE LENGTH: ' FileBytes# ' CHARACTERS ' ASCII('39') EOL
END
IF FileFeetComment?
ASCII('39') ' FILE LENGTH: ' FileFeet# ' FEET ' ASCII('39') EOL
END
IF FileMetersComment?
ASCII('39') ' FILE LENGTH: ' FileMeters# ' METERS ' ASCII('39') EOL
END
Close
END