{Change Comments ***********************************************************}

{8/2/91
Modified: Fanuc 10T MS [-] L001.81
For: Gibbs & Associates
Deleted StockOff form Approach sub, it's called from all operations.
Broke up Approach sub for all operations for improved readability and less nested decisions.
Combined and modified CheckRapid subs.
Moved XOpECDC for IDExit from end of operation to NewTool, SameTool and end of Prog.
This was to ensure that all operations end at the LAST Features EndPoint.
Added LAST to XOpECDC and ZOpECPC commands at SameTool.
DWB}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{10/24/94
Copied & modified: Fanuc 10T MS [-] L001.82ż
For: Braden Eng / Advanced Machine Products, Inc.
Control: ATI/Bendix 5M CNC
Machine: American Tool Eagle 2000 Turning Center Model 2010
Created new Processor per manual and sample outputs.
No Canned Cycles
Using manual Threading routine for single edge and taper threads.
Dwell is output as number of revolutions in G95 mode.
G95 = Inches Per Revolution
M82 = Turret Index Clockwise
M80 = Disable CSFM
M81 = Disable CSFM Reset
Jim Radcliffe}

{10/28/94
Modified GearRange change over RPM to 350 and 2000 max
Changed output of X to radius values.
Modified CheckOffset to use boolean statement instead of SpeedC command which seems to not work!
Jim Radcliffe}

{10/5/95, Updated Bendix 5M Eagle 2000 L316.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##.####;0'
#3 = '#######0'
#4 = '#0'
#5 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2) { Non-Canned Threading AutoFinish }
FORMAT(StartPosX#,2)
FORMAT(SUB#,2)
FORMAT(ABS#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

IndexDwell:
'G04X30'
RETURN

StockOnNoCan: { there are no canned cycles }
StockOn {need stock for SP positioning, if not a canned cycle}
RETURN

FeedNoCan: { there are no canned cycles }
IF NOT Threading?
FeedC
END
RETURN

FeedRateNoCan: { there are no canned cycles }
IF NOT Threading?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF NewGear?
SeqC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC IndexDwell 'T00' LatheOffset EOL
END
IF NewGear?
SeqC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
SeqC
IF NotEqual? SpeedSFPM# LAST SpeedSFPM#
Speed
END
ELSE
SeqC Preset MaxRPM EOL
SeqC { G96 set in main after start position }
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed
ELSE
SeqC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NewGear?
SpinOn EOL
ELSE
EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

GetSingleEdgeCut: { For Manual Thread Cycle }
IF Threading? AND SingleEdgeCut?
IF NOT FirstFeat?
IF ZMove?
IF LastFeat?
TrackZNO# SPZ#
ELSE
TrackZNO# EPZ#
END
END
IF NEXT ThreadFeat?
Save# Num#('3') MUL# DIV# ABS# SUB# FirstMoveEPX# EPX# NumSc#('2') TAN# Num#('30')
SeqC 'Z' SUB# FirstMoveEPZ# Recall# Num#('3') EOL
IF Taper?
TrackXNO# EPX#
Save# Num#('5') MUL# MUL# Recall# Num#('3') Recall# Num#('4') NumSc#('4')
SeqC 'X' SUB# FirstMoveEPX# Recall# Num#('5') EOL
END
END
END
END
RETURN

ThreadTaper: { For Manual Thread Cycle }
IF Taper?
Save# Num#('4') DIV# DIV# Taper# NumSc#('2') FinishZInc#
'I' ABS# MUL# Recall# Num#('4') FeedIPR#
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X20' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
GetSingleEdgeCut
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThreadTaper ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC RapidC
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbsOrInc
PosSideLathe
XsAreRadii
SetMaxRPM('2000')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq CoolOn EOL
SeqC AbsOrInc GearRange EOL
SeqC 'G95' SpinOn EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqC IndexDwell OpToolID LatheOffset 'M82' EOL
SeqC Preset Home MaxRPM EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'M80' EOL
END
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC NewHome EOL
SeqC IndexDwell 'T0000' EOL
IF NewGear?
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq CoolOn EOL
SeqC AbsOrInc GearRange EOL
SeqC 'G95' SpinOn EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqC IndexDwell OpToolID LatheOffset 'M82' EOL
SeqC Preset Home MaxRPM EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST NOT ConstantSurfaceFeed?
SeqC CSSOn 'G96' Speed 'R' StartPosX# 'M81' EOL
END
ELSE
SeqC CSSOn 'G96' Speed 'R' StartPosX# 'M81' EOL
END
END
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' ADD# FinishXRadius# Taper# EOL
SeqC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X20' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ConstantSurfaceFeed?
SeqC CSSOff 'M80' EOL
END
CRCOffC RapidC
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC FirstHome EOL
SeqC IndexDwell 'T0000' EOL
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END