{7/24/90, Added InitProg globally to posts with this remark, DWB}
{11/2/90, Updated: Fanuc 3000C M013.54 to .76.1 format, JR}
{9/9/91, Updated: Fanuc 3000C M013.76.1 to .80 format, JR}
{7/21/95, Updated Fanuc 3000C M013.80 to .85 format, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{2/10/97
Initial: Fanuc 3000C M013.89
Created: Fanuc 3000C Matsuura M000.14
ForUser: CIM Solutions / Weldex
Control: Fanuc 3000C
Machine: Matsuura MC1000V
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout and conversation with John Gruber.
Changed OfstOn from G43 to G46.
Changed OfstOff from G91 G28 Z0 to G46 TCZ# with ToolOfst if CRC was used.
Changed EOP from M30 to M02.
Changed Speed to TABLE.
Updated to .14 format without subroutine or Multiple Parts support!
Jim Radcliffe}

{5/12/98
Initial: Fanuc 3000C Mat [WI] MY45.14
Created: Fanuc 3000C Mat [PMW] Mxxx.14
ForUser: Plainville Machine Works
Control: Fanuc 3000C
Machine: Matsuura MC-1500V
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: New processor per marked up readout from Cory Stevens
Changed OfstOn to DoOfstOn.
Changed OfstOff to G91G28Z0
Added IncValue and 'M19' to OfstOff line.
Deleted ToolOfstC sub and flags 3 and 4 as they is no longer needed!
Deleted SpinOff from end of tool, it is not needed now that we are using 'M19'.
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####^##0'
#3 = '*#####^##0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###^###0'
#8 = '#;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(CRCNormalVectorX#,7)
FORMAT(CRCNormalVectorY#,7)
FORMAT(RapidF#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
RotateF
OptCyc1F
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

ckCRC: { must be first command on line }
IF LastFeat?
CRCOffC
ELSE
IF LineFeat? AND NOT ZMove?
CRCOnC
IF NOT EmptyLine?
SetFlag('2')
END
END
END
RETURN

ckCRCNum:
IF Flag?('2')
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
SetFlagF('2')
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC EOL
END
RETURN

StdLine:
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC FeedC MoveXYZC ckCRCNum FeedRateC EOL
DecelMove2
END
SeqC ckCRC FeedC MoveXYZC ckCRCNum DecelFeed EOL
ELSE
SeqC ckCRC FeedC MoveXYZC ckCRCNum FeedRateC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqC FeedC StrtPosC EOL
ELSE
SeqC RapidC StrtPosC EOL
END
END
END
EntryMove
ToolPath2
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP2 ExitFeed
END
EOL
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc CRCOffC ExitType ZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

doSpeed:
TABLE(4001,SpeedRPM#,1)
RETURN

doSpeedC:
IF NotEqual? SpeedRPM# LAST SpeedRPM#
doSpeed
END
RETURN

OpGuts:
RapidF# {forces the output of a conditional feedrate for each operation}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP3C ExitFeed
END
EOL
NEXTRep
END
ELSE
IF NOT AutoCycle?
EntryMove
END
ToolPath
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC CRCOffC ExitType ZCP3C ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ#
ToolPath
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC 'G80' EOL
IF Repeats?
NEXTRep
END
SeqC RapidC ZCP3C EOL
END
END
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
SetFlood
SetFlagF('1') { not used }
SetFlagF('2') { output CRCOffset }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

DoOfstOn:
SeqC 'M98P9999' EOL
SeqC Rapid 'G46Z0' ToolOfst EOL
SeqC Preset ZCP1 EOL
RETURN

BeginTool:
Seq Plane 'G80' CRCOff EOL
SeqC OpToolID EOL
SeqC ToolChng EOL
DoOpComments
DoPostScript
SeqC doSpeed SpinOn EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC DoOfstOn EOL
SeqC CoolOn EOL
RETURN

EndTool:
SeqC CoolOff EOL
SeqC IncValue OfstOff 'M19' EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

SameTool:
IF LAST ProgStop?
SeqC CoolOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF LAST ProgStop? OR NewToolOffset?
SeqC IncValue OfstOff EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC 'M00' EOL
END
DoOpComments
DoPostScript
CheckPass
SeqC PlaneC AbsOrInc Rapid StrtPos doSpeedC
IF LAST ProgStop?
SpinOn
END
EOL
IF LAST ProgStop? OR NewToolOffset?
SeqC DoOfstOn EOL
END
IF LAST ProgStop?
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

EndProgram:
SeqC CoolOff EOL
SeqC IncValue OfstOff 'M19' EOL
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

NoMPs:
EachOp
IF FirstOperation?
InitOp
BeginTool
ELSE
IF NewTool?
EndTool
BeginTool
ELSE
SameTool
END
END
OpGuts
NextOp
EndProgram
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
ASCII('13') EOL
ASCII('13') EOL
'This Processor does not' EOL
'Support Multiple Part Output' EOL
ASCII('13') EOL
ASCII('13') EOL
ELSE
NoMPs
END