{Change Comments ***********************************************************}

{9/10/90
Copied & modified: Fanuc 6M M001.76.1
For: University of Munkton
Machine: VMC100?
Control: EmcoTronic TM02
Made required changes per review of the manual.
DWB}

{11/15/90
Modified: EmcoTron VMC100 M339.76.1
Added Program# to EOR at beginning of output.
Deleted ProgID at beginning of output.
Added a blank space following sequence line numbers in form.
Added a blank space in front of all words in form and prog.
Deleted EOR EOL at end of output.
DWB}

{1/30/91
Modified: EmcoTron VMC100 M339.76.2
Changes made per customers request.
Modified format for Seq(C) to output leading zeros in form.
Modified format for all G-codes and M-codes to output leading zeros in form.
Modified format for all X, Y, Z, I, J and K moves to output trailing zeros in prog and form.
Modified format for SubID to output leading zeros and two trailing spaces in form.
Modified format for Program# to output leading zeros and two trailing spaces in prog.
DWB}

{7/7/92
Modified: EmcoTron VMC100 M339.76.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
KLM}

{8/25/93
Modified: EmcoTron VMC100 M339.81
For: Gibbs & Associates
Updated to .81.2 format per Fanuc 6M M001.81.2
Jim Radcliffe}

{8/25/93
Copied & modified: EmcoTron VMC100 M339.81.2
For: Auburn High School
Control: Emcotronic M1
Machine: Emco F1P-CNC
Modified WFOs:
Set up for standard G54 thru G59, same line as StrtPos.
Control can use WFOs G54 thru G55 (group 3) and G57 thru G59 (group 5),
G53 cancels (negates) group 3 & G56 cancels (negates) group 5,
also a same group call negates the current same group in effect, and then activates.
They do not work the same as Fanuc, but set as as though they do.
The only bummer would be MultipleParts using WFOs, but that could be disabled.
They are offset values from the current origin and not from machine home as in a Fanuc
Plane has no output, G17 is allways active and cannot be changed.
CRC is allways in XY plane and arcs are in plane as addresses I,J or K are used.
Output is in absolute, SetAbs. AutoCycles are incremental, U,V & W axes labels, SetInc.
Manual tool change, using M00 at tool changes.
CRCOff on LastFeat.
Using Tag# for sub numbers to start with #81.
Presets, G92, actually set the value of WFO G59, and must be followed by G59.
Using incremental origin shift values, they are summed with the current values in the control.
Added TCZ# for Full Up and Tool Changes if ToolChangeAtHome is true.
Jim Radcliffe}

{Made: Emcotronic M1 F1P-CNC M655.81.3, modified label in form for RLevel in FIRO drill cycle,
it contained an invisible character that was causing the string to exceed the allowable limit ot Three
characters, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^0;'
#7 = '00'
#8 = '###^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(OriginUnshiftRX#,4)
FORMAT(OriginUnshiftRY#,4)
FORMAT(OriginUnshiftRZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnshiftPX#,4)
FORMAT(OriginUnshiftPY#,4)
FORMAT(OriginUnshiftPZ#,4)
FORMAT(TCZ#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(ToolOffset#,7)
FORMAT(Parts#,7)
FORMAT(Repeats#,7)
FORMAT(Tag#,7)
FORMAT(Peck#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoZIn:
IF AutoCycle?
' W' EPZ#
ELSE
ZIn
END
RETURN

DoMove:
IF AutoCycle?
IF XMove?
' U' EPX#
END
IF YMove?
' V' EPY#
END
IF ZMove?
' W' EPZ#
END
ELSE
MoveXYZC
END
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed DoZIn FeedEnt EOL
ELSE
SeqC RapidC DoZIn EOL
END
RETURN

StartSub:
OpenSub
'O' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall ' L' Tag# Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ' U' RepeatX# ' V' RepeatY# ' W' RepeatZ# EOL
SeqC ' G59' EOL
SeqC EndSub EOL
CloseSub
SeqC Preset ' U' OriginUnshiftRX#('0') ' V' OriginUnshiftRY#('0') ' W' OriginUnshiftRZ#('0') EOL
SeqC ' G59' EOL
RETURN

OpenMP:
TagInc
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall ' L' Tag# '01' EOL
IncWFO
NextWFO
ELSE
SeqC SubCall ' L' Tag# Parts# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ' U' PartShiftX# ' V' PartShiftY# ' W' PartShiftZ# EOL
SeqC ' G59' EOL
SeqC EndSub EOL
CloseSub
SeqC Preset ' U' OriginUnshiftPX#('0') ' V' OriginUnshiftPY#('0') ' W' OriginUnshiftPZ#('0') EOL
SeqC ' G59' EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
DoMove ArcIJC
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC DoMove FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC DoMove DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC DoMove FeedRateC EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall ' L' Tag# '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC RapidC DoMove EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC DoMove EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC DoMove FeedRateC EOL
ELSE
IF AutoCycle? AND ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC DoMove FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
' G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
' G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall ' L' Tag# '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall ' L' Tag# '01' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetAbs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('4000')
SetMaxFeed('400') {?}
SetTCZ('5.0')
{call TagInc 80 times to set initial value of Tag# to 80}
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' ToolChangeZ(5), TCZ(5) -' EOL
' The number in parenthese specifies the Z level for Tool Changes and "Full Up".' EOL
' For Tool Changes, it will only be output if the "No Home" box is not checked.' EOL
' "Full Up" is a choice for retracting when doing Multiple Parts.' EOL
' Defaulted to 5", use to change the default value. Remains Modal.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
ProgID1 EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES)' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqC ' G53 G56 G70 G94' EOL {cancle WFO group#3, cancle WFO group#5, Inch, IPM}
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane {no output}
SeqC Rapid OpToolID ToolOffset# EOL
DoOpComments
DoPostScript
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC WFOStuff Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC Rapid ' Z' TCZ# EOL
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home ' Z' TCZ# ' M00' EOL
ELSE
SeqC ' M00' EOL
END

{Start new Operation}

Plane {no output}
SeqC Rapid OpToolID ToolOffset# EOL
DoOpComments
DoPostScript
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC WFOStuff Rapid StrtPos EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
Plane {no output}
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid OpToolID ToolOffset# EOL
SeqC WFOStuff Rapid StrtPos SpeedC SpinOn EOL
SeqC ZCP1 EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC Rapid OpToolID ToolOffset# EOL
SeqC WFOStuff Rapid StrtPos SpeedC EOL
SeqC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC WFOStuff Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqC Rapid StrtPos EOL
END
GetCycle
SeqC Cycle StrtPos ZDepth ' P3=' ClearancePlane2#
IF Peck?
' D3=' Peck#
END
IF Dwell?
' D4=' Dwell#
END
FeedEnt FromCP EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
SeqC Rapid EOL
FinishSubG92
END
SeqC Rapid ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC Rapid ' Z' TCZ# EOL
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome ' Z' TCZ#
ELSE
SeqC
END
IF MultipleParts? AND AllToolsOnePart?
' M00' EOL
CloseMP
SeqC
END
EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END