{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/21/90, Updated: Fanuc 6T MS [+] L016.53 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{4/1/91
Modified: Fanuc 6T MS [+] L016.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{4/5/91
Copied & modified: Fanuc 6T MS [+] L016.80
For: CS Draper Labs
Added lines to beginning and end of program.
Change StrtPos to StrtPosC in canned cycles.
Added GearRange.
Jim Radcliffe}

{7/8/91
Modified: Fanuc 6T HS [CSD] L208.80
For: CS Draper Labs
Added OpToolID to beginning of program after M21 line.
Updated to .81 format.
Jim Radcliffe}

{08/05/91
Updated: Fanuc 6T HS [CSD] L208.81
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{8/31/95, Updated Fanuc 6T HS [CSD] L208.82 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{11/21/96
Initial: Fanuc 6T HS [CSD] L208.85
Created: Fanuc 6T HS [CSD] L208.85.1
ForUser: CS Draper Labs
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per marked up readout.
Added G99 for IPR, using flag#1 to control.
Modified RoughContour canned cycle to output only X or Z start position based on approach.
Jim Radcliffe}

{23Mar98
Original: Fanuc 6T HS [CSD] L208.85.1
Created: Fanuc 6T HS [CSD] L208.85.2
For: CS Draper Labs
Changes made per: John Mahoney
Added IF ApproachID? Boolean to flip the XStkLeft polarity in ID rough cycle (G71).
The polarity of the U & W stock values must be reversed when roughing an ID.
Charles Winston}

{7/30/98,
Initial : Fanuc 6T HS [CSD] L208.85.2
Created: Fanuc 6T HS [SP] L756.85
Customer: Stanko Products, Gary or James 724/834-8080

Changes to "Form":

1. Under Default Formats, changed G and M to 00
2. Under Edit Tabels, changed numbers to 366 780 and 1840

Changes to "Prog":

1. Changed SetMaxRPM to 1840.
2. Changed FirstOperation, NewTool, and End per customer spec.
JHE}

{8/4/98,
Initial : Fanuc 6T HS [SP] L756.85
Created: Fanuc 6T HS [SP] L756.85.1
Customer: Stanko Products, Gary or James 724/834-8080

Changes to "Prog":

1. Removed the output of RPM if CSS is in affect (moved CSSOn from common point to
FirstOperation and NewTool).
2. Under Approach sub, Removed Rapid and added Feed. Also added F4. to AppMove sub.
3. Under NewTool, removed CheckRapid call and force G01 and Feed of 4.0 IPR.
4. Same change at end (force G01 and F4.).
5. Added G99 to the first motion block under FirstOperation.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
IF NOT Flag?('1')
'G99' SetFlag('1')
END
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP 'F4.' OpToolID LatheOffset CoolOn {Added F4. - JHE 8/4}
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# reset FeedRate }
{Rapid} {Removed - JHE 8/4}
IF ApproachOD?
SeqLabC Feed ThisOpEntryXCP AppMove EOL {Added Feed - JHE 8/4}
ELSE
IF ApproachID?
SeqLabC Feed XOpCD AppMove EOL {Added Feed - JHE 8/4}
ELSE {ApproachFace}
SeqLabC Feed StockOnNoCan XSP AppMove EOL {Added Feed - JHE 8/4}
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC LOfstOff '00' SpinOff EOL
SeqLabC OpToolID LatheOffset GearRange EOL
ELSE
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
SeqLabC SpeedC
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
ELSE
SeqLabC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NewGear?
SpinOn EOL
ELSE
EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF NOT Flag?('1')
'G99' SetFlag('1')
END
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC
IF NOT Flag?('1')
'G99' SetFlag('1')
END
CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('1840') {Changed from 10000 - JHE}
SetMaxFeed('500')
SetFlagF('1') { G99 }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
SetFlagF('1') { G99 }
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
Plane
SeqLab Feed 'G99' Home 'F4.' EOL {Added G99 - JHE 8/4}
SeqLabC OpToolID '00' EOL
DoOpComments
DoPostScript
SeqLabC Preset Home MaxRPM GearRange EOL
IF ConstantSurfaceFeed? {Moved to here - JHE 8/4}
SeqLabC CSSOn 'G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G97'Speed SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
{CheckRapid} {Removed - JHE 8/4}
IF LAST ApproachOD?
SeqLabC Feed CRCOffC LAST OpExitXCPC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
SeqLabC LAST OpExitZCPC EOL {Moved this line to here - JHE 8/4}
ELSE
IF LAST ApproachID?
SeqLabC Feed CRCOffC LAST XOpECDC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
SeqLabC LAST OpExitZCPC EOL {Moved this line to here - JHE 8/4}
ELSE {implies ApproachFace & drilling}
SeqLabC Feed CRCOffC LAST OpExitZCPC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
END
END
DoEndOpPS
{*** Removed - JHE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END ***}
SeqLabC NewHome LOfstOff '00' {Removed Feed and 'F5.' - JHE 8/4}
IF NewGear?
SpinOff
END
EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation, NewTool}

DoOpComments
DoPostScript
SeqLab OpToolID '00' EOL
SeqLabC Preset Home MaxRPM GearRange EOL
IF ConstantSurfaceFeed? {Moved to here - JHE 8/4}
SeqLabC CSSOn 'G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G97'Speed SpinOn EOL
END
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
IF NOT Flag?('1')
SeqLabC 'G99' SetFlag('1') FeedRate EOL
END
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag#
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZSP EOL
SeqLabC FeedC XSP EOL {Added this line - JHE}
ELSE {implies OD or ID}
SeqLab StepMove XSP EOL
SeqLabC FeedC ZSP EOL {Added this line - JHE}
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPosC EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead
IF SingleEdgeCut?
'A' InFeedAngle#
ELSE
'A0'
END
EOL
IF Chamfer?
SeqLabC 'M24' EOL
END
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
{*** Removed - JHE 8/4
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END ***}
IF ApproachOD?
SeqLabC Feed CRCOffC OpExitXCPC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
SeqLabC OpExitZCPC EOL {Moved this line to here - JHE 8/4}
ELSE
IF ApproachID?
SeqLabC Feed CRCOffC XOpECDC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
SeqLabC OpExitZCPC EOL {Moved this line to here - JHE 8/4}
ELSE {implies ApproachFace & drilling}
SeqLabC Feed CRCOffC OpExitZCPC 'F4.' EOL {Added Feed CRCOffC and F4. - JHE 8/4}
END
END
DoEndOpPS
{*** Removed - JHE
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END ***}
SeqLabC FirstHome OpToolID '00' EOL {Removed Feed and 'F5.' - JHE 8/4}
{*** Removed - JHE
SeqLabC UnTool '00' EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC Preset FirstHome EOL
SeqLabC 'G27X0Z0' EOL ***}
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END