{Change Comments ***********************************************************}

{6/5/89, changed tool path to force feed on first TP move after a tool change,added Metric, WFG}
{.62,1/24/90, added OP clearances for v3.2, WFG}

{1/29/90
Modified: Fanuc 10T MS [-] L001.69
Deleted ClearancePlane1# & FirstMoveEPX# prog format, they are not being used.
Deleted extra 4 lines not needed from fall thru if not canned cycle.
Added SetHome command, enables incremental ouput.
Deleted ZeroPosReg command, has no effect.
Jim Radcliffe}

{2/16/90
Modified: Fanuc 10T MS [-] L001.69.1
Added Feedrate to Approach sub.
Deleted FirstFeed sub & changed FirstFeed command to Feedrate in ToolPath.
Jim Radcliffe}

{2/20/90
Modified: Fanuc 10T MS [-] L001.69.2
Deleted extra StockOnNoCan command from Approach sub.
Added missing CheckOffset commands to Sametool.
Added FeedrateC commands to SameTool Feed lines.
Jim Radcliffe}

{3/9/90
Copied & modified: Fanuc 10T MS [-] L001.69.3
For: H&B
Machine: Takasawa
Control: Fanuc 2000C
Added descrimination for front or back turret
Deleted coolant
SpinOff at all index positions
M02 at end of prog.
No decimals, 4 trailing zeros.
Only canned cycles are RoughSimple & Threading.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{8/3/90
Copied & modified: Fanuc 2000C Taka L138.70
For: Quality Machine
Machine: Mazak
Control: Fanuc 2000C
Formatted N to 0000 in form.
Formatted S to 0000 in form.
Added Speed to SpinOn line and moved to after Preset MaxRPM line.
Replaced ToolOver20? with ToolOver?('20').
Added DoTool sub to handle complexity of ToolOver?('20').
Moved OpToolID LatheOffset to before Approach call.
Modified formats of canned cycles to trailing zeros in form.
Added offset cancel after return to Home.
Deleted 'M02' at end of prog.
Added CoolOn to Prog on approach move.
Added CoolOff before return to Home.
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format
DWB}

{9/25/90, Further update to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/26/91
Modified: Fanuc 2000C Mazak L168.71.4
For: Quality Machine
Machine is a single turret, deleted DoTool sub & ToolOver? stuff.
Added and corected CSS capability.
Added Rapid to Tool call line.
Modified Approach sub to move X & turn on coolant, then move Z on line by itself.
Added logic and moved CoolOff to turn off coolant with 1st move away from part.
Deleted SpinOff from program.
Changed NewHome & FirstHome lines to 'G28' and home values less .200.
Jim Radcliffe}

{5/24/95, .82, Updated per Fanuc 10T MS [-] L001.82ż, JR}

{5/24/95
Initial: Fanuc 2000C Mazak L168.82
ForUser: Kempsmith Machine Company
Contact: Tom Klismet 414/256-8170
Control: Fanuc 2000C
Machine: Mazak M5
Develop: ComPost 4.21.26, Catalyst v2.14.40C
Comment: New Processor per sample readouts and manual.
Added GearRange.
Changed G28 positioning to Home commands.
Added RoughContour canned cycles, G71 & G72, per Fanuc 10T MS [-] L001.83
Added spaces between codes.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##^###0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF CannedCycle? AND RoughContour?
Save# Num#('1') CycleStartX#
END
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF CannedCycle? AND RoughContour?
Save# Num#('1') CycleStartX#
END
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF CannedCycle? AND RoughContour?
Save# Num#('1') CycleStartZ#
END
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckGear:
IF NewGear?
GearRange
END
RETURN

CheckOffset: {without gear ranges}
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqLabC
IF NotEqual? MaxRPM# LAST MaxRPM#
Preset MaxRPM
END
CheckGear EOL
SeqLabC SpeedC
ELSE
SeqLabC Preset MaxRPM CheckGear EOL
SeqLabC CSSOn ' G96' Speed
END
ELSE
SeqLabC CheckGear EOL
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
ELSE
SeqLabC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqLabC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G04 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G04 P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
IF RoughContour?
IF ApproachFace?
IF Equal? Recall# Num#('1') EPZ# { true on Gibbs Sys and false on Virtual }
SeqLab { needed for Gibbs Sys }
END
ELSE
IF Equal? Recall# Num#('1') EPX#
SeqLab
END
END
ELSE
SeqLab
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
StandardXZArcs
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab Preset Home MaxRPM GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOn ' G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff ' G97' Speed SpinOn EOL
END
SeqLabC Rapid OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC CoolOff EOL
SeqLabC ZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CoolOff EOL
SeqLabC ZCPC EOL
ELSE
SeqLabC ZCPC CoolOff EOL
END
END
DoEndOpPS
SeqLabC NewHome LOfstOff '00' EOL
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab Preset Home MaxRPM GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOn ' G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff ' G97' Speed SpinOn EOL
END
SeqLabC Rapid OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle ' Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ToolPath
SetPass1
IF ApproachFace?
SeqLab RapidC ZSPC EOL { Virtual will output here }
ELSE
SeqLab RapidC XSPC EOL
END
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
StockOn
SetPass1
ToolPath
END
END
END
ELSE
IF Threading?
SeqLabC LCycle ' X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
IF Drilling?
StockOn
SetPass1
ToolPath
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC StrtPos EOL
END
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G04 P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC CoolOff EOL
SeqLabC ZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CoolOff EOL
SeqLabC ZCPC EOL
ELSE
SeqLabC ZCPC CoolOff EOL
END
END
DoEndOpPS
SeqLabC FirstHome LOfstOff '00' EOL
SeqLabC EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END