FINISH !Konczy wszystkie zadania
/CLEAR !Wyczyszecznie bazy danych
/PREP7 !Otwiera Preprocesing, po to by zdefiniowac elemetn geometrie

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!GEOMETRIA WYMIARYSTART

!Belka
Db=100
Sb=100
Wb=3

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!GEOMETRIA WYMIARY STOP

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!MATERIAL START

!!MATERIAŁ PIEZZO NR1!!
!c matrix- macierz sztywnosci
c11=12.97e7
c12=8.64e7
c13=8.31e7
c33=11.69e7
c44=2.88e7
c66=(c11-c12)/2

!Definicja Stałych piezoelektrycznych

e31=-3.84e-6 !pierwszy indeks to polaryzacja, drugi to stopoien po stronie mechanicznej
e33=16.5e-6
e15=15.1e-6

!przenikalnosc piezo
PrzXY=1250
PrzZ=750

!Gestosc piezo
Ro1=7800e-9


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!MATERIAL STOP

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!DEFINICJA MATERIALOW
!Wygenerowanie macierzy do elemetnów

tb,ANEL,1
tbdata,1,c11,c12,c13
tbdata,7,c11,c13
tbdata,12,c33
tbdata,16,c66
tbdata,19,c44
tbdata,21,c44

tb,PIEZ,1
tbdata,3,e31
tbdata,6,e31
tbdata,9,e33
tbdata,14,e15
tbdata,16,e15


mp,PERX,1,PrzXY
mp,PERY,1,PrzXY
mp,PERZ,1,PrzZ


mp,dens,1,Ro1 !kg/m3 !Gesotsc
!procent rezystancji w rzeczywistym kondesatorze- zespolona przenikalnosc
!tangens kata stratnosci
mp,LSST,1,0.013


!!!!!!!!!!!!!********************GEOMETRIA****************!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


! utworzenie 2 prostopadloscianow (1-belka, 2- piezo)
! block- tworzy prostopadlosciach ktrego wierzcholki dewiniujemy
block, 0,Sb,0,Db,0,Wb



!definicja ES - NR1 - piezo

ET,1,solid5,3

!definicja ES - NR2 - elektryka

ET,2,CIRCU94,0
r,2,1000

!! SIATKA

LESIZE,ALL,5, , , ,1, , ,1,

!!piezo

mat,1
type,1
vsweep,1

!utwierdzenie

asel,s,areas,,1
DA,ALL,ALL

ASEL,ALL


!!!!!!!!!!!!!!!!!!!!!!!!!!!Dewiniowanie elektrod!!!!!!!!!!!!!!!!!!!!!!!!

!!elektroda gorna

asel,s,areas,,2
nsla,r,1

*GET,ELE_G,NODE,0,num,min
cp,1,volt,all !definiowanie szprzerzonych stopni swobody

nsel,all
asel,all

!!elektroda dolna

asel,s,areas,,1
nsla,r,1

*GET,ELE_D,NODE,0,num,min
cp,2,volt,all

asel,all
nsel,all

! wstawanie rezystora
type,2
real,2
e, ELE_G,ELE_D

!nadawanie ocisnie

asel,s,areas,,2
SFA,all,,PRES,10e4
asel,all

!analiza Harmoniczna
subnr=10 !l kroków
startA=10 !start sym
stopA=100 !stop sym

/solu
antyp,harmonic,new
harfrq,startA,stopA
nsubs,subnr
D,ele_g,volt,10e6



solve
fini