{6/1/89
Modified; Cincinnati 900V2 (1) M099.54, for C G Richter.
Change "RapidC" to "Rapid" after Drilling.
Add "NullFoot" twice to beginning and twice to end of prog.
Changed "'( MSG" to "'(MSG".
Checked "Use Absolute Drill Depths" in Booleans.
Jim Radcliffe}

{9/6/89
Copied & modified: Cincinnati 900V2 (1) M099.55
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 5VC-750
Control: Acramatic 900 V2
New processer from Manual and Customer requests.
Jim Radcliffe}
{9/15/89, add PostScript, JR}

{9/21/89
Copied & modified: Cin 5VC Acr 900V2 M238.56
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added Probing Operation utilizing PostScript commands SetZSurf & OptCyc1.
Probing and setting of Z axis should be OK.
Needs method for X an Y axis.
Jim Radcliffe}
{10/11/89, modified operation comments, JR}

{12/5/89
Modified: Cin 10VC Acr 900MC M245.62
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added PostScript for Coolant, Program Stop & Index.
Jim Radcliffe}

{3/29/90, Updated: Cin 10VC Acr 900MC M245.63 to .70.3 format, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{7/24/90, Deleted SetZSurf command at start of prog, DWB}
{12/14/90, Updated: Cin 10VC Acr 900MC M245.71 to .76.1 format, JR}

{12/20/90
Copied & modified: Cin 10VC Acr 900MC M245.76.1
For: Precision Machine
Control: Acramatic CNC-MC (Big Blue)
Machine: Cincinnati 10VC
Standard comments.
Deleted Probing.
Standard tool identification.
Deleted ToolOfst, automaticaly called & used when the tool is loaded.
Deleted CRC stuff, this processor requires vectors.
Jim Radcliffe}

{4/03/91
Modified: Cin 10VC (Big Blue) M381.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{01/03/92
Copied & Modified: Cin 10VC Big Blue M381.79
For: Gibbs & Associates
Added P & Q vectoring for cutter compensation.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{5/19/92
Copied & Modified: Cin 10VC Big Blue M381.81.1
For: Precision Machine (Irv Eden)
Removed the SeqC from the comments.
Changed the post to output longhand, removing sub calls. (Followed
the Fanuc 5M M015.79 Format)

Kim Michelman}

{7/14/93
Modified: Cin 10VC Big Blue M381.81.2
For: PME
Misc Update corrections
Jim Radcliffe}

{1/31/94
Copied & modified: Cin 10VC Big Blue M381.81.3
For: Braden Eng / O&F Manufacturing Co., per Mike Cowan
Changed Plane to DoPlane sub to suppress output of control defaulted G17.
Deleted G70, not desired.
Forced output to Absolute and deleted redundant AbsOrInc commands.
Added program stop to first operation.
Changed EOP from M30 to M2.
Deleted aaded ProgramComment$ from beginning before EOR.
Changed O sequence numbers to N sequence numbers, therefore, ReTag not needed and
changed SeqLab to Seq, deleted ReTag and changed MachSpec N? to N.
Jim Radcliffe}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{29Jun98
Original: Cin 10VC Big Blue O&F M641.87
Created: Cin 10VC Big Blue [SP] Mxxx.87
For: Svedala
Changes made per: Bill Pruin
Added Literals 'G70', 'G90' at the Start of FirstOperation and NewTool
Split up the Approach Line into 3 lines, at FirstOperation and NewTool
Original:
SeqC Approach CheckIndexer Speed CheckPreTool CheckSpinOn EOL
Changed to
SeqC CheckPreTool EOL
SeqC Approach CheckIndexer EOL
SeqC Speed CheckSpinOn EOL
Charles Winston}

{6Jul98
Original: Cin 10VC Big Blue O&F Mxxx.87
Created: Cin 10VC Big Blue [SP] MU38.87.1
For: Svedala
Changes made per: Bill Pruin
Reversed CheckIndexer and CheckSpinOn lines, at FirstOperation, NewTool and SameTool
Charles Winston}

{7/21/98,
Initial : Cin 10VC Big Blue SP MU38.87.1
Created: Cin 10VC Big Blue SP MU38.87.2
Customer: Svedala Pumps, Bill Pruitt 719/386-0443

Changes to "Prog":

1. Added CoolOff before tool change and end.
JHE}

{Prog Numeric Format Definitions ***************************}

#1 = '#.00'
#2 = '###^##0'
#3 = '*###^##0'
#4 = '###^###0'
#5 = '#0'
#6 = '#.0000'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CalcZSurf#,4)
FORMAT(XSPVec#,4)
FORMAT(YSPVec#,4)
FORMAT(XEPVec#,4)
FORMAT(YEPVec#,4)
FORMAT(XVector#,4)
FORMAT(YVector#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Parts#,5)
FORMAT(Tool#,5)
FORMAT(ToolDiameter#,6)
FORMAT(NewWFO#,7)

{Prog Subroutines ****}

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoPartSubComment:
IF UseComments? AND SubComment?
TagInc
'( Part Number: ' Tag# ' )' EOL
IF LastPart?
TagInit
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
{see CheckIndexer for rotate stuff}
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

GetVector:
IF CutterRadiusCompensation?
IF FirstFeat?
MoveX MoveY MoveZC 'P' XVector# 'Q' YVector# {unconditional to set up proper vectors, cannot have an axis vector without a call to that axis}
ELSE
IF LastFeat?
IF XMove?
IF YMove?
MoveXYZC 'P' XEPVec# 'Q' YEPVec#
ELSE
MoveXYZC 'P' XEPVec#
END
ELSE
MoveXYZC 'Q' YEPVec#
END
ELSE
IF XMove?
IF YMove?
MoveXYZC 'P' XVector# 'Q' YVector#
ELSE
MoveXYZC 'P' XVector#
END
ELSE
MoveXYZC 'Q' YVector#
END
END
END
ELSE
MoveXYZC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
GetVector
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC RapidC GetVector EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC GetVector FeedRateC EOL
DecelMove2
END
SeqC FeedC GetVector DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC GetVector FeedRateC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC RapidC MoveXYZC EOL
ELSE
StdRapid
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC RapidC PRIME ZCP2 EOL
END
NextRep
SeqC AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYC EOL
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

Approach:
IF Drilling? AND NOT Peck?
GetCycle
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
StrtPos ZDepth RLevelCin FeedEnt
ELSE {milling or pecking}
Rapid StrtPos
IF Peck?
ZCP2
ELSE {milling}
IF NOT SameTool?
ZCP1
END
END
END
RETURN

CheckPreTool:
IF NOT LastTool?
PreTool
END
RETURN

CheckSpinOn: {turns on spindle and coolant}
IF CoolOff?
IF CWSpindle?
'M03'
ELSE
'M04'
END
ELSE
IF Mist?
IF CWSpindle?
'M17'
ELSE
'M18'
END
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
END
RETURN

CheckIndexer:
IF FourthCW?
FORMAT(FourthDegree#,2)
'B' FourthDegree#
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'B' FourthDegree#
FourthCCWF {reset flag}
END
RETURN

DoPlane:
Plane { no output }
IF XYPlane?
IF FirstOperation? OR LAST XYPlane?
{ G17 not needed, its the defaulted plane }
ELSE
'G17'
END
ELSE
IF XZPlane?
'G18'
ELSE
'G19'
END
END
RETURN

{************************ Set-Up ***************************************}

InitProg
SetMaxVec('3.2767')
ReverseXZArcs
SetFlood
SetAbs
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Use Literals to specify a Spindle Rotate for probing operations.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' MistCoolant, MCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with mist coolant.' EOL
' SetMist, SM' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with mist coolant.' EOL
' FloodCoolant, FCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with mist coolant.' EOL
' Flood is the default setting.' EOL
' SetFlood, SF' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with flood coolant.' EOL
' This is the default setting.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a - B move of the value you specify' EOL
END
EACHOp
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
SeqC 'G70' EOL
SeqC AbsOrInc EOL
IF MultipleParts? AND AllToolsOnePart?
EACHPart
DoPartSubComment
END
Seq Rapid OpToolID ToolChng EOL
DoOpComments
SeqC 'M0' EOL
SeqC DoPlane EOL
DoPostScript
CheckPass
SeqC CheckPreTool EOL
SeqC Speed CheckSpinOn EOL
SeqC Approach CheckIndexer EOL
IF MultipleParts? AND OneToolAllParts?
EACHPart
DoPartSubComment
IF NOT FirstPart?
DoOpComments
SeqC Rapid StrtPos EOL
END
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts?
NEXTPart
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC RapidC Home CoolOff EOL {Added CoolOff - JHE}
ELSE
SeqC CoolOff EOL {Added CoolOff - JHE}
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
SeqC 'G70' EOL
SeqC AbsOrInc EOL

{************* Beginning of a new tool ******************}

Seq Rapid OpToolID ToolChng EOL
DoOpComments
SeqC DoPlane EOL
DoPostScript
CheckPass
SeqC CheckPreTool EOL
SeqC Speed CheckSpinOn EOL
SeqC Approach CheckIndexer EOL
IF MultipleParts? AND OneToolAllParts?
EACHPart
DoPartSubComment
IF NOT FirstPart?
DoOpComments
SeqC Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
SeqC 'M00' EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END

{************* Beginning of a new operation with same tool ******************}

DoOpComments
SeqC DoPlane EOL
DoPostScript
CheckPass
SeqC Speed CheckSpinOn EOL
SeqC Approach CheckIndexer EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END {Common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
RapidC PRIME ZCP3C
END
EOL
NEXTRep
END
END
SeqC RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
IF Peck?
PeckManual
EACHFeat
IF NOT FirstFeat?
SeqC MoveSXYC EOL
PeckManual
END
NEXTFeat
ELSE
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
END
IF Repeats?
NEXTRep
END
SeqC Rapid ZCP3 EOL
END
END
{NEXTOp} {modified to prevent endless looping in ncPOST}

IF MultipleParts?
IF LastOp?
IF MultipleParts? AND OneToolAllParts?
NEXTPart
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
NEXTPart
END
ELSE
NEXTOp
END
ELSE
NEXTOp
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FirstHome CoolOff EOL {Added CoolOff - JHE}
ELSE
SeqC CoolOff EOL {Added CoolOff - JHE}
END
END
IF ProgStop?
SeqC 'M00' EOL
END

SeqC EOP EOL
CloseSub
Post2
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END