{6/1/89
Modified; Cincinnati 900V2 (1) M099.54, for C G Richter.
Change "RapidC" to "Rapid" after Drilling.
Add "NullFoot" twice to beginning and twice to end of prog.
Changed "'( MSG" to "'(MSG".
Checked "Use Absolute Drill Depths" in Booleans.
Jim Radcliffe}

{9/6/89
Copied & modified: Cincinnati 900V2 (1) M099.55
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 5VC-750
Control: Acramatic 900 V2
New processer from Manual and Customer requests.
Jim Radcliffe}
{9/15/89, add PostScript, JR}

{9/21/89
Copied & modified: Cin 5VC Acr 900V2 M238.56
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added Probing Operation utilizing PostScript commands SetZSurf & OptCyc1.
Probing and setting of Z axis should be OK.
Needs method for X an Y axis.
Jim Radcliffe}
{10/11/89, modified operation comments, JR}

{12/5/89
Modified: Cin 10VC Acr 900MC M245.62
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added PostScript for Coolant, Program Stop & Index.
Jim Radcliffe}

{3/29/90, Updated: Cin 10VC Acr 900MC M245.63 to .70.3 format, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{7/24/90, Deleted SetZSurf command at start of prog, DWB}
{12/14/90, Updated: Cin 10VC Acr 900MC M245.71 to .76.1 format, JR}

{12/20/90
Copied & modified: Cin 10VC Acr 900MC M245.76.1
For: Precision Machine
Control: Acramatic CNC-MC (Big Blue)
Machine: Cincinnati 10VC
Standard comments.
Deleted Probing.
Standard tool identification.
Deleted ToolOfst, automaticaly called & used when the tool is loaded.
Deleted CRC stuff, this processor requires vectors.
Jim Radcliffe}

{4/03/91
Modified: Cin 10VC (Big Blue) M381.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{01/03/92
Copied & Modified: Cin 10VC Big Blue M381.79
For: Gibbs & Associates
Added P & Q vectoring for cutter compensation.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{5/19/92
Copied & Modified: Cin 10VC Big Blue M381.81.1
For: Precision Machine (Irv Eden)
Removed the SeqC from the comments.
Changed the post to output longhand, removing sub calls. (Followed
the Fanuc 5M M015.79 Format)

Kim Michelman}

{7/14/93
Modified: Cin 10VC Big Blue M381.81.2
For: PME
Misc Update corrections
Jim Radcliffe}

{1/31/94
Copied & modified: Cin 10VC Big Blue M381.81.3
For: Braden Eng / O&F Manufacturing Co., per Mike Cowan
Changed Plane to DoPlane sub to suppress output of control defaulted G17.
Deleted G70, not desired.
Forced output to Absolute and deleted redundant AbsOrInc commands.
Added program stop to first operation.
Changed EOP from M30 to M2.
Deleted aaded ProgramComment$ from beginning before EOR.
Changed O sequence numbers to N sequence numbers, therefore, ReTag not needed and
changed SeqLab to Seq, deleted ReTag and changed MachSpec N? to N.
Jim Radcliffe}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{2/14/97
Modified: Cin 10VC Big Blue O&F M641.87
NewPost: Cin 10VC Big Blue [TC] Mxxx.87
For: Tomkins Corps
fixed message blocks so a line number will preceed the MSG block.
added ToolOfst command in First, New, and Same Tool sections.
removed PreTool support.
modified to use the Retag command, changed Seq to SeqLab and changed MachSpec N to N?.
WS}

#1 = '#.00'
#2 = '###^##0'
#3 = '*###^##0'
#4 = '###^###0'
#5 = '#0'
#6 = '#.0000'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CalcZSurf#,4)
FORMAT(XSPVec#,4)
FORMAT(YSPVec#,4)
FORMAT(XEPVec#,4)
FORMAT(YEPVec#,4)
FORMAT(XVector#,4)
FORMAT(YVector#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Tool#,5)
FORMAT(ToolDiameter#,6)
FORMAT(NewWFO#,7)

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '(MSG, CYCLE START )' EOL
END
RETURN

DoPartSubComment:
IF UseComments? AND SubComment?
TagInc
SeqLab '(MSG, Part Number: ' Tag# ' )' EOL
IF LastPart?
TagInit
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLab '(MSG, ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
{see CheckIndexer for rotate stuff}
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

GetVector:
IF CutterRadiusCompensation?
IF FirstFeat?
MoveX MoveY MoveZC 'P' XVector# 'Q' YVector# {unconditional to set up proper vectors, cannot have an axis vector without a call to that axis}
ELSE
IF LastFeat?
IF XMove?
IF YMove?
MoveXYZC 'P' XEPVec# 'Q' YEPVec#
ELSE
MoveXYZC 'P' XEPVec#
END
ELSE
MoveXYZC 'Q' YEPVec#
END
ELSE
IF XMove?
IF YMove?
MoveXYZC 'P' XVector# 'Q' YVector#
ELSE
MoveXYZC 'P' XVector#
END
ELSE
MoveXYZC 'Q' YVector#
END
END
END
ELSE
MoveXYZC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
GetVector
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC GetVector EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FeedC GetVector FeedRateC EOL
DecelMove2
END
SeqLabC FeedC GetVector DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC FeedC GetVector FeedRateC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqLabC RapidC MoveXYZC EOL
ELSE
StdRapid
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqLabC FeedC ZInC FeedEntC EOL
ELSE
SeqLabC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqLabC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqLabC RapidC PRIME ZCP2 EOL
END
NextRep
SeqLabC AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC MoveSXYC EOL
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

Approach:
IF Drilling? AND NOT Peck?
GetCycle
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
StrtPos ZDepth RLevelCin FeedEnt
ELSE {milling or pecking}
Rapid StrtPos
IF Peck?
ZCP2
ELSE {milling}
IF NOT SameTool?
ZCP1
END
END
END
RETURN

CheckSpinOn: {turns on spindle and coolant}
IF CoolOff?
IF CWSpindle?
'M03'
ELSE
'M04'
END
ELSE
IF Mist?
IF CWSpindle?
'M17'
ELSE
'M18'
END
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
END
RETURN

CheckIndexer:
IF FourthCW?
FORMAT(FourthDegree#,2)
'B' FourthDegree#
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'B' FourthDegree#
FourthCCWF {reset flag}
END
RETURN

DoPlane:
Plane { no output }
IF XYPlane?
IF FirstOperation? OR LAST XYPlane?
{ G17 not needed, its the defaulted plane }
ELSE
'G17'
END
ELSE
IF XZPlane?
'G18'
ELSE
'G19'
END
END
RETURN

{************************ Set-Up ***************************************}

InitProg
SetMaxVec('3.2767')
ReverseXZArcs
SetFlood
SetAbs
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Use Literals to specify a Spindle Rotate for probing operations.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' MistCoolant, MCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with mist coolant.' EOL
' SetMist, SM' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with mist coolant.' EOL
' FloodCoolant, FCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with mist coolant.' EOL
' Flood is the default setting.' EOL
' SetFlood, SF' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with flood coolant.' EOL
' This is the default setting.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a - B move of the value you specify' EOL
END
EACHOp
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
SeqLab '(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLab '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab '(MSG, OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF PartsComment?
SeqLab '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLab '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
EACHPart
DoPartSubComment
END
SeqLab Rapid OpToolID ToolChng EOL
DoOpComments
SeqLabC 'M0' EOL
SeqLabC DoPlane EOL
DoPostScript
CheckPass
SeqLabC Approach CheckIndexer Speed ToolOfst CheckSpinOn EOL
IF MultipleParts? AND OneToolAllParts?
EACHPart
DoPartSubComment
IF NOT FirstPart?
DoOpComments
SeqLabC Rapid StrtPos EOL
END
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts?
NEXTPart
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC RapidC Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{************* Beginning of a new tool ******************}

SeqLab Rapid OpToolID ToolChng EOL
DoOpComments
SeqLabC DoPlane EOL
DoPostScript
CheckPass
SeqLabC Approach CheckIndexer Speed ToolOfst CheckSpinOn EOL
IF MultipleParts? AND OneToolAllParts?
EACHPart
DoPartSubComment
IF NOT FirstPart?
DoOpComments
SeqLabC Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
IF ToolChangeAtHome?
SeqLabC Rapid Home EOL
END
SeqLabC 'M00' EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END

{************* Beginning of a new operation with same tool ******************}

DoOpComments
SeqLabC DoPlane EOL
DoPostScript
CheckPass
SeqLabC Approach CheckIndexer Speed ToolOfst CheckSpinOn EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END {Common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
IF NOT FeedConnect?
SeqLabC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqLabC CRCOffC
IF NOT FeedConnect?
RapidC PRIME ZCP3C
END
EOL
NEXTRep
END
END
SeqLabC RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
IF Peck?
PeckManual
EACHFeat
IF NOT FirstFeat?
SeqLabC MoveSXYC EOL
PeckManual
END
NEXTFeat
ELSE
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqLabC DrillOff EOL
END
IF Repeats?
NEXTRep
END
SeqLabC Rapid ZCP3 EOL
END
END
{NEXTOp} {modified to prevent endless looping in ncPOST}

IF MultipleParts?
IF LastOp?
IF MultipleParts? AND OneToolAllParts?
NEXTPart
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
NEXTPart
END
ELSE
NEXTOp
END
ELSE
NEXTOp
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome EOL
END
END
IF ProgStop?
SeqLabC 'M00' EOL
END

SeqLabC EOP EOL
CloseSub
Post2
EOR EOL
IF UseComments?
SetScale('1')
IF FileBytesComment?
SeqLab '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLab '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLab '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close
Retag